函数参考

_GUICtrlTreeView_SetItemHeight

设置项目高度

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetItemHeight($hWnd, $hItem, $iIntegral)

参数

$hWnd 控件句柄
$hItem 项目句柄
$iIntegral 项目高度值.这个高度值是项目标准高度的递增
默认每个项目可以有 1 个项目高度的递增.
设置为 2 项目将增加两倍的标准高度;
设置为 3 项目将增加三倍的标准高度.
控件不获取额外的区域.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查传递给函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效

_Main()

Func _Main()

    Local $hItem[6], $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Set Item Height", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To UBound($hItem) - 1
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x + 1), $hTreeView)
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    _GUICtrlTreeView_SetItemHeight($hTreeView, $hItem[2], 2)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main