函数参考

_GUIImageList_DrawEx

在指定的设备环境中绘制图像列表项目

#Include <GuiImageList.au3>
_GUIImageList_DrawEx($hWnd, $iIndex, $hDC, $iX, $iY[, $iDX = 0[, $iDY = 0[, $iRGBBk = 0xFFFFFFFF[, $iRGBFg = 0xFFFFFFFF[, $iStyle=0]]]]])

参数

$hWnd 控件句柄
$iIndex 绘制图像的 0 基索引
$hDC 目标设备环境句柄
$iX 图像绘制位置的 X 坐标
$iY 图像绘制位置的 Y 坐标
$iDX [可选参数] 图像的绘制宽度.(相对于图像左上角).
如 $iDX 与 $iDY 为 0, 函数绘制整个图像. 函数不保证该参数是有效的.
$iDY [可选参数] 图像的绘制高度(相对于图像左上角).
如 $iDX 与 $iDY 为 0, 函数绘制整个图像. 函数不保证该参数是有效的.
$iRGBBk [可选参数] 图像的背景颜色. 参数可以是应用程序定义的 RGB 值或以下值之一:
返回 $CLR_NONE - 无背景颜色.绘制透明图像.
$CLR_DEFAULT - 默认背景颜色.使用图像列表的背景颜色.
$iRGBFg [可选参数] 图像的前景颜色.参数可以是应用程序定义的 RGB 值或以下值之一:
返回 $CLR_NONE - 没有混合色.图像与目标设备环境的颜色混合.
$CLR_DEFAULT - 默认前景色.使用系统高亮颜色作为前景色.
$iStyle [可选参数] 绘制样式和覆盖图像:
1 - 使用透明蒙板,不涉及背景颜色
2 - 混合系统高亮颜色 25%
4 - 混合系统高亮颜色 50%
8 - 绘制蒙板

返回值

成功: True
失败: False

注意/说明

None.

相关

_GUIImageList_Draw

示例/演示


#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <GuiImageList.au3>

_Main()

Func _Main()
    Local $hImage, $hGUI, $hDC

    $hGUI = GUICreate("ImageList DrawEx", 400, 300)
    GUISetState()

    ; 加载图像
    $hImage = _GUIImageList_Create(32, 24)
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 32, 24))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 32, 24))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 32, 24))

    ; 描绘图像
    $hDC = _WinAPI_GetDC($hGUI)
    _GUIImageList_DrawEx($hImage, 0, $hDC, 4, 4)
    _GUIImageList_DrawEx($hImage, 1, $hDC, 40, 4)
    _GUIImageList_DrawEx($hImage, 2, $hDC, 76, 4)

    _WinAPI_ReleaseDC($hGUI, $hDC)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main