函数参考

_IEImgGetCollection

返回一个文档内IMG标签的对象变量集合.

#include <IE.au3>
_IEImgGetCollection ( ByRef $o_object [, $i_index = -1] )

参数

$o_object InternetExplorer.Application, 窗口或者框架(frame)对象的对象变量
$i_index [可选参数]: 指定返回一个集合还是索引对象
0 或者正整数返回一个索引对象
-1 = (默认) 返回一个集合

返回值

成功: 返回一个文档内IMG标签的对象变量集合, @EXTENDED = img数量
失败: 返回 0 并且设置@ERROR
@Error: 0 ($_IEStatus_Success) = 无错误
3 ($_IEStatus_InvalidDataType) = 无效数据类型
5 ($_IEStatus_InvalidValue) = 无效数值
7 ($_IEStatus_NoMatch) = 不匹配
@Extended: 包含无效参数数量

注意/说明

None.

相关

_IEFormImageClick, _IEImgClick

示例/演示


; *******************************************************
; 示例 1 - 创建浏览器并打开 AutoIt 主页, 获取到
;               页面中第 6 幅图像的引用 (注意: 首幅图像索引为 0)
;               并显示其信息
; *******************************************************

#include <IE.au3>

Local $oIE = _IECreate("http://www.autoitscript.com/")
Local $oImg = _IEImgGetCollection($oIE, 5)
Local $sInfo = "Src: " & $oImg.src & @CR
$sInfo &= "FileName: " & $oImg.nameProp & @CR
$sInfo &= "Height: " & $oImg.height & @CR
$sInfo &= "Width: " & $oImg.width & @CR
$sInfo &= "Border: " & $oImg.border
MsgBox(4096, "4th Image Info", $sInfo)

; *******************************************************
; 示例 2 - 创建浏览器并打开 AutoIt 主页, 获取 Img 集合
;               并显示其中每个的源 URL
; *******************************************************

#include <IE.au3>

$oIE = _IECreate("http://www.autoitscript.com/")
Local $oImgs = _IEImgGetCollection($oIE)
Local $iNumImg = @extended
MsgBox(4096, "Img Info", "There are " & $iNumImg & " images on the page")
For $oImg In $oImgs
    MsgBox(4096, "Img Info", "src=" & $oImg.src)
Next