函数参考

_Net_Share_SessionDel

结束服务器和工作站之间的网络会话

#Include <NetShare.au3>
_Net_Share_SessionDel([$sServer = "" [, $sClientName = "" [, $sUserName = ""]]])

参数

$sServer [可选参数] 指定 DNS 或 NetBIOS 远程服务器上执行函数的名称
如果此参数为空, 在本地计算机上使用.
$sClientName [可选参数] 指定断开连接的客户端计算机名. 如果为空,
删除 $sServer 参数标识的服务器上所有用户对话.
$sUserName [可选参数] 指定会话被终止的用户名称.如果此参数为空,
$sClientName 参数指定的客户端所有用户会话将被终止.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

系统管理员,服务器操作员或本地组成员才能执行此功能.
必须通过调用 $sClientName 或 $sUserName(或两者)使这个函数工作.

相关

_Net_Share_ShareDel

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $sServer

    ; 创建 GUI
    GUICreate("NetShare", 400, 300)

    ; 创建 memo 控件
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 获取服务器和共享信息
    $sServer = InputBox("NetWork Demo", "Enter Server Name:", "\\MyServer", "", 200, 130)
    If @error Then Exit

    ; 删除我们在服务器上的所有会话
    _Net_Share_SessionDel($sServer, @ComputerName)
    MemoWrite("Error ...................: " & @error)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite