函数参考

_Net_Share_ShareGetInfo

检索特定服务器上共享资源的信息

#Include <NetShare.au3>
_Net_Share_ShareGetInfo($sServer, $sShare)

参数

$sServer 指定函数将操作远程服务器的 DNS 或 NetBIOS 名称字符串
如果参数为空, 则使用本地计算机.
$sShare 返回信息的共享名称

返回值

成功: 返回以下格式的数组:
[0] - 资源共享名
[1] - 共享资源类型．可以是一个组合:
$STYPE_磁盘TREE - 打印队列
$STYPE_PRINTQ - 磁盘驱动器
$STYPE_DEVICE - 通讯设备
$STYPE_IPC - IPC (工控机)
$STYPE_SPECIAL - 为 IPC$ 或服务器的远程管理保留的专用共享(那 $ 号反没反,不知道)
$STYPE_TEMPORARY - 临时共享
[2] - 共享资源的可选注释
[3] - 共享资源的权限:
1 - 读取数据, 并执行资源
2 - 将数据写入到资源
4 - 创建资源实例
8 - 执行资源
16 - 删除资源
32 - 修改资源的属性
64 - 修改分配给资源的权限
[4] - 显示资源可以连接的最大数
[5] - 当前资源连接数
[6] - 共享资源本地路径
[7] - 共享资源的使用密码
失败: 设置@error:

注意/说明

系统管理员,服务器操作员,或Power Users本地组成员,
或打印操作员,或服务器操作员组的成员,可以成功地执行这个函数.

相关

_Net_Share_FileGetInfo, _Net_Share_SessionGetInfo, _Net_Share_ShareSetInfo

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $aInfo
    Local Const $sShareName = "AutoIt Share"

    ; 创建 GUI
    GUICreate("NetShare", 400, 300)

    ; 创建 memo 控件
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; See if the share exists
    If _Net_Share_ShareCheck(@ComputerName, $sShareName) = -1 Then
        ; Create a share on the local computer
        _Net_Share_ShareAdd(@ComputerName, $sShareName, 0, "C:\", "AutoIt Share Comment")
        If @error Then MsgBox(4096, "信息", "Share add error : " & @error)
        MemoWrite("Share added")
    Else
        MemoWrite("Share exists")
    EndIf

    ; Show information about the share we added
    $aInfo = _Net_Share_ShareGetInfo(@ComputerName, $sShareName)
    MemoWrite("Share name ..............: " & $aInfo[0])
    MemoWrite("Share type...............: " & _Net_Share_ResourceStr($aInfo[1]))
    MemoWrite("Comment .................: " & $aInfo[2])
    MemoWrite("Permissions .............: " & _Net_Share_PermStr($aInfo[3]))
    MemoWrite("Maximum connections .....: " & $aInfo[4])
    MemoWrite("Current connections .....: " & $aInfo[5])
    MemoWrite("Local path ..............: " & $aInfo[6])
    MemoWrite("Password ................: " & $aInfo[7])

    ; Delete the share
    _Net_Share_ShareDel(@ComputerName, $sShareName)
    If @error Then MsgBox(4096, "信息", "Share delete error : " & @error)
    MemoWrite("Share deleted")

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite