函数参考

_Net_Share_StatisticsGetSvr

检索服务器操作统计

#Include <NetShare.au3>
_Net_Share_StatisticsGetSvr([$sServer = ""])

参数

$sServer [可选参数] 指定 DNS 或 NetBIOS 远程服务器上执行函数的名称
如果此参数为空, 在本地计算机上使用.

返回值

成功: 返回以下格式的数组:
[ 0] - 开始收集统计数据时间(秒).
从 00:00:00 开始消逝的时间, 1970年1月1日,格林尼治标准时间.
[ 1] - 文件在服务器上打开的次数
[ 2] - 服务器设备打开的次数
[ 3] - 服务器后台处理打印作业次数
[ 4] - 服务器会话启动次数
[ 5] - 服务器会话断开次数
[ 6] - 服务器会话失败错误次数
[ 7] - 服务器密码违规次数
[ 8] - 服务器访问权限错误次数
[ 9] - 服务器系统错误次数
[10] - 服务器发送到网络的字节数
[11] - 服务器从网络接收的字节数
[12] - 服务器平均响应时间(毫秒)
[13] - 服务器需要缓冲区, 但因未能分配而请求的次数
[14] - 服务器需要大的缓冲区, 但因未能分配而请求的次数
失败: 设置@error:

注意/说明

获取工作站的统计数字不必是特殊组成员
系统管理员或服务器操作员本地组成员, 才能成功地在远程服务器上执行此函数.

相关

_Net_Share_StatisticsGetWrk

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $aInfo

    ; 创建 GUI
    GUICreate("NetShare", 400, 300)

    ; 创建 memo 控件
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 获取服务器统计信息
    $aInfo = _Net_Share_StatisticsGetSvr(@ComputerName)
    MemoWrite("Statistics started ......: " & $aInfo[0])
    MemoWrite("Times file opened .......: " & $aInfo[1])
    MemoWrite("Times device opened .....: " & $aInfo[2])
    MemoWrite("Print jobs spooled ......: " & $aInfo[3])
    MemoWrite("Sessions started ........: " & $aInfo[4])
    MemoWrite("Sessions disconnected ...: " & $aInfo[5])
    MemoWrite("Session errors ..........: " & $aInfo[6])
    MemoWrite("Password violations .....: " & $aInfo[7])
    MemoWrite("Permission errors .......: " & $aInfo[8])
    MemoWrite("Server system errors ....: " & $aInfo[9])
    MemoWrite("Network bytes sent ......: " & $aInfo[10])
    MemoWrite("Network bytes recv ......: " & $aInfo[11])
    MemoWrite("Average response time ...: " & $aInfo[12])
    MemoWrite("Req buffer failures .....: " & $aInfo[13])
    MemoWrite("Big buffer failures .....: " & $aInfo[14])

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite