[转贴] 关于对话框的例子,带超链接 [基础知识]

#include <WindowsConstants.au3>
#include <GUIConstantsex.au3>
#include <GuiButton.au3>


Opt("GUICloseOnESC",1)
Opt("GUIOnEventMode",1)


$about = GuiCreate("About",215,150,-1,-1,$WS_CAPTION + $WS_SYSMENU)
GUISetOnEvent ($GUI_EVENT_CLOSE, "AboutOK" )
GUICtrlCreateIcon (@AutoItExe,-1,11,11)
GUICtrlCreateLabel ("App name 1.0",59,11,135,20)
GUICtrlSetFont (-1,10, 800, 0, "Arial") ; bold
GUICtrlCreateLabel ("(c) 2005" & @CRLF & @CRLF & "Zedna",59,30,135,40)
$email = GUICtrlCreateLabel ("author@somewhere.com",59,70,135,15)
GuiCtrlSetFont($email, 8.5, -1, 4) ; underlined
GuiCtrlSetColor($email,0x0000ff)
GuiCtrlSetCursor($email,0)
GUICtrlSetOnEvent(-1, "OnEmail")
$www = GUICtrlCreateLabel ("www.autoitscript.com/forum/",59,85,140,15)
GuiCtrlSetFont($www, 8.5, -1, 4) ; underlined
GuiCtrlSetColor($www,0x0000ff)
GuiCtrlSetCursor($www,0)
GUICtrlSetOnEvent(-1, "OnWWW")
GUICtrlCreateButton ("OK",65,115,75,23,$GUI_SS_DEFAULT_BUTTON + $BS_DEFPUSHBUTTON)
GUICtrlSetState (-1, $GUI_FOCUS)
GUICtrlSetOnEvent(-1, "AboutOK")
GUISetState()

While 1 
        Sleep(100)
WEnd

Func OnEmail()
        Run(@ComSpec & " /c " & 'start mailto:author@somewhere.com?subject=Something', "", @SW_HIDE)
EndFunc

Func OnWWW()
        Run(@ComSpec & " /c " & 'start http://www.autoitscript.com/forum/', "", @SW_HIDE)
EndFunc

Func AboutOK()
        Exit
EndFunc