jyjuse 发表于 2010-1-2 14:41:10

GUICtrlCreateListView如何能响影双击事件

本帖最后由 jyjuse 于 2010-1-2 23:27 编辑

如题,在GUICtrlCreateListView的项目上双击,出现窗口同时显示双击项目的内容.

ceoguang 发表于 2010-1-2 23:00:04

伸手党.......
昨天才有人问过#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>

$Form1 = GUICreate("Form1", 410, 310)
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

$ListView1 = GUICtrlCreateListView("||", 8, 8, 400, 300)
GUISetState(@SW_SHOW)
For $I = 1 To 10
        GUICtrlCreateListViewItem($I, $ListView1)
Next

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func WM_NOTIFY($hWndGUI, $MsgID, $WParam, $LParam)

        Local $tagNMHDR, $Event, $hWndFrom, $IDFrom
        Local $tagNMHDR = DllStructCreate("int;int;int", $LParam)
        If @error Then Return $GUI_RUNDEFMSG
        $IDFrom = DllStructGetData($tagNMHDR, 2)
        $Event = DllStructGetData($tagNMHDR, 3)
        $tagNMHDR = 0
        Switch $IDFrom;选择产生事件的控件

                Case $ListView1

                        Switch $Event; 选择产生的事件

                                Case $NM_CLICK ; 左击
;~                                       ...

                                Case $NM_DBLCLK ; 双击
                                        $Index = _GUICtrlListView_GetSelectedIndices($ListView1)
                                        If Not StringLen($Index) Then; 这里用以判断是否选定了ListViewItem
                                                MsgBox(0, "", "未选定")
                                                Return
                                        EndIf
                                        MsgBox(0, 0, _GUICtrlListView_GetItemText($ListView1, Number($Index), 0))

                                Case $NM_RCLICK ; 右击
;~                                       ...
                        EndSwitch

        EndSwitch

        Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

jyjuse 发表于 2010-1-2 23:23:52

太好了。感谢ceoguang 问题解决了。

xpboy 发表于 2010-1-3 01:19:43

彩，不错，采纳了

liyi-softs 发表于 2011-7-1 20:17:54

不错,就想找这东西.

49666684 发表于 2011-11-29 11:34:02

不错,就想找这东西.

zldfsz 发表于 2012-3-9 13:08:39

回复 2# ceoguang


    太感谢了，我要的就是这效果

xms77 发表于 2012-3-10 07:05:52

学习了，3Q

xms77 发表于 2012-3-10 07:06:03

学习了，3Q

超级死人 发表于 2012-4-4 20:40:00

mark正想找这个...

好好锻炼 发表于 2012-4-15 08:53:36

不错,我也想找这东西.

xlj310 发表于 2012-5-22 18:35:55

哎呀，终于找到了，非常感谢
页: [1]
查看完整版本: GUICtrlCreateListView如何能响影双击事件