想把程序做成服务
本帖最后由 xsjtxy 于 2010-2-10 22:54 编辑想把程序做成服务。(不依赖外部程序)。找了半天找不到办法。看到有个BOSS发个贴子。又没阅读权限。请问要怎么才能达到30的阅读权限啊？或者哪个有这个权限的把里面的东西发给我下191148964@qq.com
万分感谢！！！！！！！！！！！！！！
http://www.autoitx.com/forum.php?mod=viewthread&tid=12490&highlight=%B7%FE%CE%F1 那一个只是单纯演示服务程序的编写，以下这个是服务程序的实例，功能是清理内存。#NoTrayIcon
#include <LocalSecurityAuthority.au3>
Const $SERVICE_WIN32_OWN_PROCESS = 0x0010
Const $SERVICE_WIN32_SHARE_PROCESS = 0x0020
Const $SERVICE_INTERACTIVE_PROCESS = 0x0100
Const $SERVICE_STOPPED = 1
Const $SERVICE_RUNNING = 4
Const $SERVICE_CONTINUE_PENDING = 5
Const $SERVICE_PAUSED = 7
Const $SERVICE_ACCEPT_STOP = 1
Const $SERVICE_ACCEPT_PAUSE_CONTINUE = 2
Const $SERVICE_CONTROL_STOP = 1
Const $SERVICE_CONTROL_PAUSE = 2
Const $SERVICE_CONTROL_CONTINUE = 3
Const $SERVICE_CONTROL_INTERROGATE = 4
Const $tagSERVICE_STATUS = "dword ServiceType;dword CurrentState;dword ControlsAccepted;dword Win32ExitCode;dword ServiceSpecificExitCode;dword CheckPoint;dword WaitHint"
If Not @Compiled Then Exit(Msgbox(48, "Error", "Compile first."))
; SCM - 服务控制器 (Service Control Manager)。
; 此服务程序的名称。
Global $sServiceName = "Au3MemCleaner"
; 判断此服务程序是否由SCM启动。
Local $tProcessBasic = DllStructCreate("dword;ptr;ulong_ptr;ulong")
_NtQueryInformationProcess(-1, 0, DllStructGetPtr($tProcessBasic), 24)
If DllStructGetData($tProcessBasic, 4, 3) <> ProcessExists("Services.exe") Then
$hService = _LsaOpenService($sServiceName, 0xF01FF)
If ($hService = 0) Then $hService = _CreateService($sServiceName, $sServiceName, _
bitOr($SERVICE_WIN32_OWN_PROCESS, $SERVICE_INTERACTIVE_PROCESS), _
2, 0, @ScriptFullPath, "", 0)
_StartService($hService)
_LsaCloseServiceHandle($hService)
exit
EndIf
; 定义几个全局变量，以便在多个函数中共享它们的值。
Global $hServiceMain, $hHandlerEx, $tServiceTable
Global $tServiceStatus, $pServiceStatus, $hServiceStatus
; 注册服务入口点函数，用于在SCM启动服务时，向SCM报告自己的状态。
$hServiceMain = DllCallbackRegister("_ServiceMain", "none", "dword;ptr")
; 子控制请求函数，用于接收SCM发来的请求，并报告自己的状态。
$hHandlerEx = DllCallbackRegister("_HandlerEx", "dword", "dword;dword;ptr;ptr")
$tServiceTable = DllStructCreate("ptr;ptr;ptr;ptr;char")
DllStructSetData($tServiceTable, 1, DllStructGetPtr($tServiceTable, 5)) ; 服务名称。
DllStructSetData($tServiceTable, 2, DllCallbackGetPtr($hServiceMain)) ; 入口点函数地址。
DllStructSetData($tServiceTable, 5, $sServiceName)
$tServiceStatus = DllStructCreate($tagSERVICE_STATUS)
$pServiceStatus = DllStructGetPtr($tServiceStatus)
DllStructSetData($tServiceStatus, "ServiceType", _ ; 服务类型
bitOr($SERVICE_WIN32_OWN_PROCESS, _ ; 独享进程。
$SERVICE_INTERACTIVE_PROCESS)) ; 允许与桌面交互。
DllStructSetData($tServiceStatus, "ControlsAccepted", _ ; 指定允许接收的后续控制请求。
bitOr($SERVICE_ACCEPT_STOP, _ ; 服务可以停止。
$SERVICE_ACCEPT_PAUSE_CONTINUE)) ; 服务可以暂停和继续。
; 启动服务的控制调度分派线程。
; 当SCM启动某个服务时，服务进程的主线程必须在30秒内调用此函数。
; SCM将分派表传递给StartServiceCtrlDispatcher，这将把调用进程的主线程转换为控制分派器，
; 该分派器启动一个新线程，该线程运行分派表中每个服务的 ServiceMain 入口点函数。
; 如果 StartServiceCtrlDispatcher 函数30秒没有被调用, 便会出现1053的错误(服务没有及时响应控制请求)。
_StartServiceCtrlDispatcher(DllStructGetPtr($tServiceTable))
Func _ServiceMain($iNumberofArgs, $pArguments)
Local $aProcess, $hProcess, $hToken, $aPriv = [[$SE_DEBUG_NAME, 2]]
; 注册服务的“控制处理器”，以用于接收停止、暂停等请求操作，应在ServiceMain函数中尽早调用。
$hServiceStatus = _RegisterServiceCtrlHandlerEx($sServiceName, DllCallbackGetPtr($hHandlerEx))
; 向SCM报告自己的状态。
DllStructSetData($tServiceStatus, "CurrentState", $SERVICE_RUNNING)
_SetServiceStatus($hServiceStatus, $pServiceStatus)
Msgbox(4, "Bingo~!!", "I am running as a service~~")
$hToken = _OpenProcessToken(-1)
If Not _IsPrivilegeEnabled($hToken, $SE_DEBUG_NAME) Then
_AdjustTokenPrivileges($hToken, $aPriv)
EndIf
_LsaCloseHandle($hToken)
; 在服务的主函数中循环清理内存。
While 1
$aProcess = ProcessList()
For $i = 1 To $aProcess
$hProcess = _OpenProcess($aProcess[$i])
_EmptyWorkingSet($hProcess)
_LsaCloseHandle($hProcess)
Sleep(50)
Next
WEnd
EndFunc ;==>_ServiceMain
; 服务的“控制处理器”，用于处理SCM发出的各种请求。
Func _HandlerEx($iRequest, $iEventType, $pEventData, $pContext)
Switch $iRequest
Case $SERVICE_CONTROL_STOP ; 服务需停止。
; 如果30秒内没有向SCM报告自己的状态，将会出现1053的错误。
DllStructSetData($tServiceStatus, "CurrentState", $SERVICE_STOPPED)
_SetServiceStatus($hServiceStatus, $pServiceStatus)
Return 0
Case $SERVICE_CONTROL_PAUSE ; 服务需暂停。
; 同上，必须在30秒调用，否则出错。
DllStructSetData($tServiceStatus, "CurrentState", $SERVICE_PAUSED)
_SetServiceStatus($hServiceStatus, $pServiceStatus)
Return 0
Case $SERVICE_CONTROL_CONTINUE ; 服务需要继续。
; 同上。
DllStructSetData($tServiceStatus, "CurrentState", $SERVICE_RUNNING)
_SetServiceStatus($hServiceStatus, $pServiceStatus)
Return 0
Case $SERVICE_CONTROL_INTERROGATE ; 服务需要向SCM报告自己的状态。
_SetServiceStatus($hServiceStatus, $pServiceStatus)
Return 0
EndSwitch
EndFunc ;==>_HandlerEx
Func _SetServiceStatus($hServiceStatus, $pServiceStatus)
Local $iResult
$iResult = DllCall("AdvApi32.dll", "int", "SetServiceStatus", _
"hWnd", $hServiceStatus, "ptr", $pServiceStatus)
Return SetError(_GetLastError(), 0, $iResult)
EndFunc ;==>_SetServiceStatus
Func _StartService($hService, $iNumberofArgs = 0, $pArguments = 0)
Local $iResult
$iResult = DllCall("AdvApi32.dll", "int", "StartService", "hWnd", $hService, _
"dword", $iNumberofArgs, "ptr", $pArguments)
Return SetError(_GetLastError(), 0, $iResult)
EndFunc ;==>_StartService
Func _RegisterServiceCtrlHandlerEx($sServiceName, $pHandlerEx, $pContext = 0)
Local $iResult
$iResult = DllCall("AdvApi32.dll", "hWnd", "RegisterServiceCtrlHandlerEx", _
"str", $sServiceName, "ptr", $pHandlerEx, "ptr", $pContext)
Return SetError(_GetLastError(), 0, $iResult)
EndFunc ;==>_RegisterServiceCtrlHandlerEx
Func _StartServiceCtrlDispatcher($pServiceTable)
Local $iResult
$iResult = DllCall("AdvApi32.dll", "int", "StartServiceCtrlDispatcher", _
"ptr", $pServiceTable)
Return SetError(_GetLastError(), 0, $iResult)
EndFunc ;==>_StartServiceCtrlDispatcher
Func _CreateService($sServiceName, $sDisplayName, $iServiceType, $iStartType, _
$iErrorControl, $sBinaryPath, $sLoadOrderGroup, $aDependencies, _
$sStartName = "", $sPassword = "", $iDesiredAccess = 0xF01FF)
Local $iResult, $tServiceName, $tDisplayName, $tBinaryPath, $hSC
Local $tLoadOrder, $tDependencies, $tStartName, $tPassword, $sBuffer
$tServiceName = DllStructCreate("wchar ServiceName[" & StringLen($sServiceName) + 1 & "]")
DllStructSetData($tServiceName, "ServiceName", $sServiceName)
If $sDisplayName <> "" Then
$tDisplayName = DllStructCreate("wchar DisplayName[" & StringLen($sDisplayName) + 1 & "]")
DllStructSetData($tDisplayName, "DisplayName", $sDisplayName)
EndIf
If $sBinaryPath <> "" Then
$tBinaryPath = DllStructCreate("wchar BinaryPath[" & StringLen($sBinaryPath) + 1 & "]")
DllStructSetData($tBinaryPath, "BinaryPath", $sBinaryPath)
EndIf
If $sLoadOrderGroup <> "" Then
$tLoadOrder = DllStructCreate("wchar LoadOrder[" & StringLen($sLoadOrderGroup) + 1 & "]")
DllStructSetData($tLoadOrder, "LoadOrder", $sLoadOrderGroup)
EndIf
If $sStartName <> "" Then
$tStartName = DllStructCreate("wchar StartName[" & StringLen($sStartName) + 1 & "]")
DllStructSetData($tStartName, "StartName", $sStartName)
EndIf
If $sPassword <> "" Then
$tPassword = DllStructCreate("wchar Password[" & StringLen($sPassword) + 1 & "]")
DllStructSetData($tPassword, "Password", $sPassword)
EndIf
If IsArray($aDependencies) And UBound($aDependencies, 0) = 1 Then
For $i = 0 To UBound($aDependencies) - 1
$sBuffer &= "wchar[" & StringLen($aDependencies[$i]) + 1 & "];")
Next
$tDependencies = DllStructCreate($sBuffer & ";wchar")
For $i =0 To UBound($aDependencies) - 1
DllStructSetData($tDependencies, ($i + 1), $aDependencies[$i])
Next
EndIf
$hSC = _LsaOpenSCManager("", 2)
$iResult = DllCall("AdvApi32.dll", "hWnd", "CreateServiceW", _
"hWnd", $hSC, _
"ptr", DllStructGetPtr($tServiceName), _
"ptr", DllStructGetPtr($tDisplayName), _
"dword", $iDesiredAccess, _
"dword", $iServiceType, _
"dword", $iStartType, _
"dword", $iErrorControl, _
"ptr", DllStructGetPtr($tBinaryPath), _
"ptr", DllStructGetPtr($tLoadOrder), _
"ptr", 0, _
"ptr", DllStructGetPtr($tDependencies), _
"ptr", DllStructGetPtr($tStartName), _
"ptr", DllStructGetPtr($tPassword))
Return SetError(_GetLastError(), _LsaCloseServiceHandle($hSC), $iResult)
EndFunc ;==>_CreateService
Func _EmptyWorkingSet($hProcess)
Local $iResult
$iResult = DllCall("psapi.dll", "int", "EmptyWorkingSet", "hWnd", $hProcess)
Return SetError(_GetLastError(), 0, $iResult)
EndFunc ;==>_EmptyWorkingSet
Func _NtQueryInformationProcess($hProcess, $iClass, $pBuffer, $iSizeofBuffer)
Local $iResult
$iResult = DllCall("Ntdll.dll", "dword", "NtQueryInformationProcess", "hWnd", $hProcess, _
"int", $iClass, "ptr", $pBuffer, "ulong", $iSizeofBuffer, "ulong*", 0)
Return SetError($iResult, $iResult, $iResult = 0)
EndFunc ;==>_NtQueryInformationProcess<LocalSecurityAuthority.au3>, 02/05/2010更新 - http://www.autoitx.com/thread-7080-1-1.html pusofalse 老大的码 咱现在很难看懂 拿来直接用 呵呵 :face (15):"sc" 快一点 清理内存这个经典。。 今天一看，原来我的权限也是一直不够 路过:face (12): 好长的代码，都看不怎么懂. 看不懂..不知道怎么用 好强的代码，看不懂 LocalSecurityAuthority.au3有更新通知一下哈 检测了一下 我的权限也不够 注册服务 可以试试直接用自带的SC工具添加
描述:
在注册表和服务数据库中创建服务项。
用法:
sc <server> create <option1> <option2>...
选项:
注意: 选项名称包括等号。
type= <own|share|interact|kernel|filesys|rec>
(默认 = own)
start= <boot|system|auto|demand|disabled>
(默认 = demand)
error= <normal|severe|critical|ignore>
(默认 = normal)
binPath= <BinaryPathName>
group= <LoadOrderGroup>
tag= <yes|no>
depend= <依存关系(以 / (斜杠) 分隔)>
obj= <AccountName|ObjectName>
(默认 = LocalSystem)
DisplayName= <显示名称>
password= <密码> 我得阅读权限也不到30:face (37): :face (26):标记一下。 强悍~~顶P大~~~
页:
[1]
2