论坛 › 已解决问题区 › [已解决]如何实时更新窗体中的文字？

meteor0330 发表于 2010-11-30 16:46:49

[已解决]如何实时更新窗体中的文字？

本帖最后由 meteor0330 于 2010-12-1 22:07 编辑

程序窗体上半部分是一个下拉框，下半部分是显示相关介绍

目标是：选择下拉框中的某项后，点确定，下半部分的相关介绍会更新？

请问如何写呀？？
谢谢＠＠

KLU3K 发表于 2010-11-30 19:10:01

本帖最后由 KLU3K 于 2010-11-30 19:22 编辑

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 171, 77, -1, -1)
GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
$Combo1 = GUICtrlCreateCombo("", 12, 12, 145, 25, BitOR($CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "请选择|1+1=?|2+2=?", "请选择")
GUICtrlSetOnEvent(-1, "Combo1Change")
$Label1 = GUICtrlCreateLabel("↑在上面选一个吧！", 12, 44, 146, 17, $SS_CENTER)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
        Sleep(100)
WEnd

Func Combo1Change()
        $Ver = GUICtrlRead($Combo1)
        Select
                Case $Ver = "请选择"
                        GUICtrlSetData($Label1, "别选我啊！往下选！")
                Case $Ver = "1+1=?"
                        GUICtrlSetData($Label1, "等于2")
                Case $Ver = "2+2=?"
                        GUICtrlSetData($Label1, "不会做！囧rz")
        EndSelect
EndFunc   ;==>Combo1Change

Func Form1Close()
        Exit
EndFunc   ;==>Form1Close
↑以上代码选择后文字直接发生变化，无确定按钮


↓以下代码是按下确定按钮后文字发生变化
#include <ComboConstants.au3>
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 171, 77, -1, -1)
GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
$Combo1 = GUICtrlCreateCombo("", 12, 12, 100, 25, BitOR($CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "请选择|1+1=?|2+2=?", "请选择")
$Button1 = GUICtrlCreateButton("确定", 116, 8, 47, 25)
GUICtrlSetOnEvent(-1, "Button1Click")
$Label1 = GUICtrlCreateLabel("↑在上面选一个吧！", 12, 44, 146, 17, $SS_CENTER)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
        Sleep(100)
WEnd

Func Button1Click()
        $Ver = GUICtrlRead($Combo1)
        Select
                Case $Ver = "请选择"
                        GUICtrlSetData($Label1, "别选我啊！往下选！")
                Case $Ver = "1+1=?"
                        GUICtrlSetData($Label1, "等于2")
                Case $Ver = "2+2=?"
                        GUICtrlSetData($Label1, "不会做！囧rz")
        EndSelect
EndFunc   ;==>Button1Click

Func Form1Close()
        Exit
EndFunc   ;==>Form1Close

第一个部分代码是选择后直接生效，第二部分是按确定按钮才生效。
如果有用，给个评分！{:face (355):}

lpxx 发表于 2010-11-30 20:53:55

2+2=0哈哈,

meteor0330 发表于 2010-12-1 10:21:04

回复 2# KLU3K


    谢谢！！！！！

meteor0330 发表于 2010-12-1 22:06:37

今天把程序都写好了！呵呵，早点来这里就好了！！！

872777825 发表于 2011-2-7 23:59:39

很好的东西学习了

myang 发表于 2011-2-13 13:15:35

很好的东西学习了

查看完整版本: [已解决]如何实时更新窗体中的文字？