论坛 › 『 提问交流 』 › 请教下，如何限制CreateGUI窗体最大化尺寸？

pushad 发表于 2011-4-6 19:56:53

请教下，如何限制CreateGUI窗体最大化尺寸？

比如限制最大化尺寸为800x600,谢谢。

小A 发表于 2011-4-6 21:14:26

回复 1# pushad


$main_GUI = GUICreate('窗口大小限制示例 bbs.wglm.net 小A', 700, 500, -1, -1, 0x00040000+0x00020000+0x00010000, 0x00000010)
GUIRegisterMsg(36, "_SetMinMax")
GUISetState(@SW_SHOW)

Do
        $Msg = GUIGetMsg()
Until $Msg = -3

;设置窗口调整大小
Func _SetMinMax($hWnd, $iMsg, $wParam, $lParam)

      If $hWnd = $main_GUI Then

                Local $tMINMAXINFO = DllStructCreate("int;int;" & _
                              "int MaxSizeX; int MaxSizeY;" & _
                              "int MaxPositionX;int MaxPositionY;" & _
                              "int MinTrackSizeX; int MinTrackSizeY;" & _
                              "int MaxTrackSizeX; int MaxTrackSizeY", _
                              $lParam)

                DllStructSetData($tMINMAXINFO, "MinTrackSizeX", 600);设置窗口宽度最小为500
                DllStructSetData($tMINMAXINFO, "MinTrackSizeY", 500);设置窗口高度最小为500

      EndIf

EndFunc   ;==>_SetMinMax

http://bbs.wglm.net/forum-viewthread-tid-119353-fromuid-206031.html

8722073 发表于 2011-4-6 21:28:38

学习了，谢谢

pushad 发表于 2011-4-6 22:06:03

精彩的回复，谢谢，以后遇到问题先查API，总以为脚本库里所有的方法都有了。

ceoguang 发表于 2011-4-6 22:16:34

Opt("GUIOnEventMode", 1)
GUICreate("限制窗口大小示例", -1, -1, -1, -1, 0x40000)
GUISetOnEvent(-3, "GuiEvent")
GUIRegisterMsg(0x24, "WM_GETMINMAXINFO")
GUISetState()
While 1
        Sleep(100)
WEnd
Func GuiEvent()
        Switch @GUI_CtrlId
                Case -3
                        GUIDelete()
                        Exit
        EndSwitch
EndFunc   ;==>GuiEvent

Func WM_GETMINMAXINFO($hWnd, $Msg, $wParam, $lparam)
        Local $tBuffer = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lparam)
        DllStructSetData($tBuffer, 7, 400);限制窗口的最小宽度为400
        DllStructSetData($tBuffer, 8, 250);限制窗口的最小高度为600
        DllStructSetData($tBuffer, 9, 600);限制窗口的最大宽度为600
        DllStructSetData($tBuffer, 10, 800);限制窗口的最大宽度为800
        Return "GUI_RUNDEFMSG"
EndFunc

guang19831217 发表于 2011-4-7 20:28:39

学习了，很好的方法。

feiye7366 发表于 2011-4-11 12:17:30

回复 5# ceoguang


    高度好像不能限制

查看完整版本: 请教下，如何限制CreateGUI窗体最大化尺寸？