woku2538 发表于 2011-12-4 16:47:43

问题已解决

本帖最后由 woku2538 于 2011-12-11 21:36 编辑

怎么样AU3 写出 年月日 和星期几 和时分秒 那位大侠帮我写一写

nivisde 发表于 2011-12-4 17:21:07

本帖最后由 nivisde 于 2011-12-4 17:36 编辑

记得下次好帮助手册。

msgbox(0,"",@YEAR&"年"&@MON&"月"&@MDAY&"日"&@HOUR&"时"&@MIN&"分"&@SEC&"秒")

Switch @WDAY
case 1
msgbox(0,"","星期天")
case 2
msgbox(0,"","星期一")
case 3
msgbox(0,"","星期二")
case 4
msgbox(0,"","星期三")
case 5
msgbox(0,"","星期四")
case 6
msgbox(0,"","星期五")
case 7
msgbox(0,"","星期六")
EndSwitch

lxz 发表于 2011-12-4 21:38:01

帮助里有例子......

mtvtop 发表于 2011-12-4 22:25:31

记得下次好帮助手册。

msgbox(0,"",@YEAR&"年"&@MON&"月"&@MDAY&"日"&@HOUR&"时"&@MIN&"分"&@SEC&"秒")
...
nivisde 发表于 2011-12-4 17:21 http://www.autoitx.com/images/common/back.gif

这个正解

gto250 发表于 2011-12-5 18:21:30

我有更精简的
Dim $day=["","星期天","星期一","星期二","星期三","星期四","星期五","星期六"]
msgbox(0,"",@YEAR&"年"&@MON&"月"&@MDAY&"日"&$day[@wday]&@HOUR&"时"&@MIN&"分"&@SEC&"秒")

skyfree 发表于 2011-12-5 20:08:57


#cs ＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿
      
      Au3 版本:      3.3.6.1
      脚本作者:         Skyfree
      Email:         165718402@qq.com
      QQ/TM:         165718402
      脚本版本:         1.0.0.1
      脚本功能: 显示日期时间
      
#ce ＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿脚本开始＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿

#NoTrayIcon

#Region
#AutoIt3Wrapper_Compression=4
#AutoIt3Wrapper_UseX64=n
#AutoIt3Wrapper_Res_Description=Sky123.Org - Clock
#AutoIt3Wrapper_Res_FileVersion=1.0.0.1
#AutoIt3Wrapper_Res_FileVersion_AutoIncrement=y
#AutoIt3Wrapper_Res_LegalCopyright=Skyfree
#AutoIt3Wrapper_Run_Tidy=y
#AutoIt3Wrapper_Run_Obfuscator=y
#Obfuscator_Parameters=/striponly
#EndRegion

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

;变量必须先声明后使用
Opt("MustDeclareVars", 1)

;创建GUI
Global $gu_Form1 = GUICreate("时间日期", 220, 52, -1, -1)
Global $gu_Label1 = GUICtrlCreateLabel("", 0, 16, 220, 17, $SS_CENTER)

;运行主函数
_Clock_Main()
Exit 1

;程序主函数
Func _Clock_Main()
      ;初始化日期、周几、时间值
      _Clock_RefeshClock()
      
      ;显示GUI
      GUISetState(@SW_SHOW)
      
      ;每隔一秒刷新日期、周几、时间值
      AdlibRegister("_Clock_RefeshClock", 1000)
      
      Local $nMsg
      While 1
                $nMsg = GUIGetMsg()
                Switch $nMsg
                        Case $GUI_EVENT_CLOSE
                              Exit

                EndSwitch
      WEnd
EndFunc   ;==>_Clock_Main

;刷新日期、周几、时间值
Func _Clock_RefeshClock()
      Local $Data = _Clock_Date() ;获取日期
      Local $Time = _Clock_Time() ;获取时间
      Local $Wday = _Clock_Wday() ;获取周几
      
      ;显示时钟信息
      GUICtrlSetData($gu_Label1, $Data & " " & $Wday & " " & $Time)
EndFunc   ;==>_Clock_RefeshClock

;获取日期
Func _Clock_Date()
      Return @YEAR & "年" & @MON & "月" & @MDAY & "日"
EndFunc   ;==>_Clock_Date

;获取时间
Func _Clock_Time()
      Return @HOUR & ":" & @MIN & ":" & @SEC
EndFunc   ;==>_Clock_Time

;获取周几
Func _Clock_Wday()
      Local $a_Wday
      ;根据@WDAY的值（1~7）获取“星期x”的值
      Switch @WDAY
                Case 1
                        $a_Wday = "星期天"
                Case 2
                        $a_Wday = "星期一"
                Case 3
                        $a_Wday = "星期二"
                Case 4
                        $a_Wday = "星期三"
                Case 5
                        $a_Wday = "星期四"
                Case 6
                        $a_Wday = "星期五"
                Case 7
                        $a_Wday = "星期六"
      EndSwitch
      Return $a_Wday
EndFunc   ;==>_Clock_Wday

lpxx 发表于 2011-12-5 20:29:44

skyfree，我是看着你的教程成长的

hzxymkb 发表于 2011-12-5 20:56:58

回复 7# lpxx


    我也是，他是我的偶像！

nis 发表于 2011-12-5 23:29:20

喜欢，喜欢

jsgh1983 发表于 2011-12-6 09:32:51

都是高手呀！又学习了！

weeks1 发表于 2011-12-6 09:34:47

，谢谢分享！..

mydead2001 发表于 2011-12-6 13:44:02

昨天就想这个了，可是做不出来，今天就看到SKY了，难道是。。。。

au3x 发表于 2011-12-6 16:51:43

sky 高手中的高手

chenbaker 发表于 2011-12-6 17:42:50

非常好的代码，感谢了

xms77 发表于 2011-12-6 20:47:47

果然都是高手学习求星期几的函数用法，感谢@！
页: [1] 2
查看完整版本: 问题已解决