pchome2000 发表于 2013-9-8 22:21:09

【已解决】edit文本框或richedit 文本框，如何不显示闪烁的光标？

本帖最后由 pchome2000 于 2013-9-11 20:15 编辑

edit文本框或richedit 文本框，如何不显示闪烁的光标？用键盘或鼠标点击都不显示光标，   我知道用$WS_DISABLED 这个样式是可以达到效果，但是不能拖动滚动条。

seniors 发表于 2013-9-11 07:24:01

本帖最后由 seniors 于 2013-9-11 07:26 编辑

#Include <APIConstants.au3>
#Include <EditConstants.au3>
#Include <GUIConstantsEx.au3>
#Include <WinAPIEx.au3>

Opt('MustDeclareVars', 1)

Global $hForm, $Msg, $Input, $Button

$hForm = GUICreate('MyGUI', 400, 93)
$Input = GUICtrlCreateInput('', 20, 20, 360, 20)
$Button = GUICtrlCreateButton('Exit', 165, 59, 70, 23)
GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')
GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
      Case $GUI_EVENT_CLOSE, $Button
            ExitLoop
    EndSwitch
WEnd

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
        Switch $hWnd
                Case $hForm
                        Switch _WinAPI_LoWord($wParam)
                                Case $Input
                                        Switch _WinAPI_HiWord($wParam)
                                                Case $EN_SETFOCUS
                                                        _WinAPI_HideCaret($lParam);不显示光标
                                                        _WinAPI_SetCaretBlinkTime(-1);光标不闪烁
                                        EndSwitch
                        EndSwitch
        EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

pchome2000 发表于 2013-9-11 20:12:58

谢谢二楼，已解决

pchome2000 发表于 2013-9-12 15:17:50

input框和edit 框可以隐藏光标，richedit 框是不可以隐藏光标

lomo1316 发表于 2013-9-12 15:57:03

好，看一下好了

lomo1316 发表于 2013-9-12 16:14:19

没钱啊，真是不爽
页: [1]
查看完整版本: 【已解决】edit文本框或richedit 文本框，如何不显示闪烁的光标？