论坛 › 已解决问题区 › [已解决]本人初学者，希望学习一下！ 如何从记事本导入账号密码到列表框

mshuking 发表于 2014-12-10 21:29:46

[已解决]本人初学者，希望学习一下！ 如何从记事本导入账号密码到列表框

本帖最后由 mshuking 于 2014-12-12 15:45 编辑

本人初学者，希望学习一下！
如何从记事本导入账号密码到列表框
感谢user3000的无私奉献代码如下：#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("测试", 460, 244)
;$ListView1 = GUICtrlCreateListView("账号|密码|状态", 0, 0, 458, 214)
$ListView1 = GUICtrlCreateListView("账号|密码|状态", 0, 0, 458, 214)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 150);调整宽度
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 150);调整宽度
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 2, 150);调整宽度
GUICtrlSendMsg($ListView1, $LVM_SETEXTENDEDLISTVIEWSTYLE, $LVS_EX_GRIDLINES, $LVS_EX_GRIDLINES);设置表格边框
GUICtrlSetCursor(-1, 0);鼠标指针
GUISetState(@SW_SHOW)

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
   Exit
EndSwitch
WEnd右键    导入   选择记事本   导入


记事本：hh1234561---67892
hh1234562---67892
hh1234563---67892
hh1234564---67892
hh1234565---67892
hh1234567---67892
hh1234568---67892
hh1234569---67892账号密码不限多少个 !

在此感谢大家。。。。。。。。。…。。…。………

user3000 发表于 2014-12-10 21:55:58

回复 1# mshuking Func _add_lv_item()
        Local $file = FileOpenDialog('选择你的数据文件', @ScriptDir, '文本文件(*.txt)')
        If @error Then Return
        Local $sTXT = FileRead($file)
        ;$sTXT = ClipGet()
        Local $aText = StringRegExp($sTXT, '.+-{3}.+', 3)
        If @error Then Return
        For $i = 0 To UBound($aText) - 1
                GUICtrlCreateListViewItem(StringReplace($aText[$i], '---', '|'), $ListView1)
        Next
EndFunc

austere 发表于 2014-12-11 08:33:18

我感觉用记事本不如用ini存储，这样读的时候也方便~直接把--- 替换成 = 保存为ini多好~

mshuking 发表于 2014-12-11 14:30:27

我感觉用记事本不如用ini存储，这样读的时候也方便~直接把--- 替换成 = 保存为ini多好~
austere 发表于 2014-12-11 08:33 http://www.autoitx.com/images/common/back.gif


    有具体脚本吗

mshuking 发表于 2014-12-11 14:31:05

回复mshuking
user3000 发表于 2014-12-10 21:55 http://www.autoitx.com/images/common/back.gif


    不知道如何调用。。。。

austere 发表于 2014-12-11 15:16:25

人家都给你发源码了，你稍微修改一下~~ 这么一点都懒的做啊？#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("测试", 460, 244)
;$ListView1 = GUICtrlCreateListView("账号|密码|状态", 0, 0, 458, 214)
$ListView1 = GUICtrlCreateListView("账号|密码|状态", 0, 0, 458, 214)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 150);调整宽度
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 150);调整宽度
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 2, 150);调整宽度
GUICtrlSendMsg($ListView1, $LVM_SETEXTENDEDLISTVIEWSTYLE, $LVS_EX_GRIDLINES, $LVS_EX_GRIDLINES);设置表格边框
GUICtrlSetCursor(-1, 0);鼠标指针
GUISetState(@SW_SHOW)
_add_lv_item("123.txt");在这个（）内输入你的文本文件的路径

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
   Exit
EndSwitch
WEnd

Func _add_lv_item($file)
      If @error Then Return
      Local $sTXT = FileRead($file)
      ;$sTXT = ClipGet()
      Local $aText = StringRegExp($sTXT, '.+-{3}.+', 3)
      If @error Then Return
      For $i = 0 To UBound($aText) - 1
                GUICtrlCreateListViewItem(StringReplace($aText[$i], '---', '|'), $ListView1)
      Next
EndFunc

mshuking 发表于 2014-12-11 19:05:23

本帖最后由 mshuking 于 2014-12-11 19:06 编辑

人家都给你发源码了，你稍微修改一下~~ 这么一点都懒的做啊？
austere 发表于 2014-12-11 15:16 http://www.autoitx.com/images/common/back.gif


非常感谢。。。。。我才刚入门不是高手
以上代码 我试了加了 没反应应该是缺少右键$Form1 = GUICreate("测试", 460, 244)
$ListView1 = GUICtrlCreateListView("账号|密码|状态", 0, 0, 458, 214)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 150);调整宽度
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 150);调整宽度
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 2, 150);调整宽度
GUICtrlSendMsg($ListView1, $LVM_SETEXTENDEDLISTVIEWSTYLE, $LVS_EX_GRIDLINES, $LVS_EX_GRIDLINES);设置表格边框
GUICtrlSetCursor(-1, 0);鼠标指针
GUISetState(@SW_SHOW)
GUICtrlSetColor($hListView1, 0x0055ff);设置指定控件的文本颜色
GUICtrlSetResizing($hListView1, $GUI_DOCKLEFT + $GUI_DOCKRIGHT + $GUI_DOCKMENUBAR);设置某个控件的大小调整方式
$menu_C = GUICtrlCreateContextMenu($hListView1);创建上下文菜单(右键)
$menu_C1 = GUICtrlCreateMenuItem("清除信息[&Q]", $menu_C);创建一个菜单项目控件
GUICtrlCreateMenuItem("", $menu_C);创建一个菜单项目控件
$menu_C2 = GUICtrlCreateMenuItem("读取信息[&V]", $menu_C);创建一个菜单项目控件不是很会用                Case $menu_C1
                        Func _add_lv_item()
               Local $file = FileOpenDialog('选择你的数据文件', @ScriptDir, '文本文件(*.txt)')
               If @error Then Return
               Local $sTXT = FileRead($file)
                ;$sTXT = ClipGet()
               Local $aText = StringRegExp($sTXT, '.+-{3}.+', 3)
               If @error Then Return
               For $i = 0 To UBound($aText) - 1
                GUICtrlCreateListViewItem(StringReplace($aText[$i], '---', '|'), $ListView1)
      Next
EndFunc
        EndSwitch
WEnd

逆水风帆 发表于 2014-12-11 19:14:18

我也觉得还是ini方便，数据多一些可以弄成数据库

user3000 发表于 2014-12-11 21:34:44

回复 5# mshuking


    帮一下新朋友. 多多努力;多查看某函数的帮助,多实践,运行实例;坚持个把星期就会有一定水准啦.

#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Global $LastItem = -1 ; 记录最后创建的列表项目ID, 删除时用得上.
$Form1 = GUICreate("测试", 460, 244)
$ListView1 = GUICtrlCreateListView("账号|密码|状态", 0, 0, 458, 214)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 180);调整宽度
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 150);调整宽度
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 2, 110);调整宽度
GUICtrlSendMsg($ListView1, $LVM_SETEXTENDEDLISTVIEWSTYLE, $LVS_EX_GRIDLINES, $LVS_EX_GRIDLINES);设置表格边框
GUICtrlSetCursor(-1, 0);鼠标指针

$Context = GUICtrlCreateContextMenu($ListView1)
$LoadData = GUICtrlCreateMenuItem("导入数据", $Context)
GUICtrlCreateMenuItem("", $Context)
$ClearData = GUICtrlCreateMenuItem("清空数据", $Context)
GUICtrlCreateMenuItem("", $Context)
$Quit = GUICtrlCreateMenuItem("退出", $Context)

GUISetState(@SW_SHOW)
While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
                Case $GUI_EVENT_CLOSE, $Quit
                        Exit
                Case $LoadData
                        _add_lv_item()
                Case $ClearData
                        _clear_lv_item()
        EndSwitch
WEnd

Func _add_lv_item()
        Local $file = FileOpenDialog('选择你的数据文件', @ScriptDir, '文本文件(*.txt)')
        If @error Then Return SetError(1); 没选定文件,直接跳出函数
        Local $sTXT = FileRead($file)
        $sTXT = ClipGet() ;此句调试用,直接从剪贴板读数据
        Local $aText = StringRegExp($sTXT, '.+-{3}.+', 3) ;正则获取数据
        If @error Then Return SetError(2) ; 获取帐户密码数据出错,数据格式不符?
        If $LastItem <> -1 Then
                If MsgBox(1 + 32, '清除数据', '是否清空旧数据?', 5, $Form1) = 1 Then _clear_lv_item()
        EndIf
        For $i = 0 To UBound($aText) - 1
                $LastItem = GUICtrlCreateListViewItem(StringReplace($aText[$i], '---', '|'), $ListView1) ;创建列表项目
        Next
EndFunc

Func _clear_lv_item()
        If $LastItem Then
                For $i = $Quit + 1 To $LastItem
                        GUICtrlDelete($i) ; 删除所有项目的控件id
                Next
                GUICtrlSendMsg($ListView1, $LVM_DELETEALLITEMS, 0, 0) ;删除所有列表项目
                $LastItem = -1 ;重置此ID纪录
        EndIf
EndFunc

weeks5 发表于 2014-12-12 08:26:03

谢谢学习。。。。。

xfxecs 发表于 2014-12-12 11:41:24

同学习了 同是新人

mshuking 发表于 2014-12-12 13:24:47

回复mshuking


    帮一下新朋友. 多多努力;多查看某函数的帮助,多实践,运行实例;坚持个把星期就会有 ...
user3000 发表于 2014-12-11 21:34 http://www.autoitx.com/images/common/back.gif


   非常感谢 学习了

menfan1 发表于 2014-12-14 10:23:11

账户密码放在数据库里，然后加解密的就更有用了：）

vfhptuu 发表于 2014-12-14 21:53:03

我也是新手，谢谢楼上各位大大的代码！！

qddoit 发表于 2014-12-16 03:58:24

151515151551

查看完整版本: [已解决]本人初学者，希望学习一下！ 如何从记事本导入账号密码到列表框