论坛 › 已解决问题区 › 请求帮助关于窗口限制大小问题!

≈※爖※≈ 发表于 2009-2-16 15:03:54

请求帮助关于窗口限制大小问题!

有没有哪位朋友能帮我把以下这段VB转成AU3的呀?先谢谢啦~
Private Const GWL_WNDPROC = -4
      Private Const WM_GETMINMAXINFO = &H24

      Private Type POINTAPI
          x As Long
          y As Long
      End Type

      Private Type MINMAXINFO
          ptReserved As POINTAPI
          ptMaxSize As POINTAPI
          ptMaxPosition As POINTAPI
          ptMinTrackSize As POINTAPI
          ptMaxTrackSize As POINTAPI
      End Type

      Global lpPrevWndProc As Long
      Global gHW As Long

      Private Declare Function DefWindowProc Lib "user32" Alias _
         "DefWindowProcA" (ByVal hwnd As Long, ByVal wMsg As Long, _
          ByVal wParam As Long, ByVal lParam As Long) As Long
      Private Declare Function CallWindowProc Lib "user32" Alias _
         "CallWindowProcA" (ByVal lpPrevWndFunc As Long, _
          ByVal hwnd As Long, ByVal Msg As Long, _
          ByVal wParam As Long, ByVal lParam As Long) As Long
      Private Declare Function SetWindowLong Lib "user32" Alias _
         "SetWindowLongA" (ByVal hwnd As Long, _
          ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
      Private Declare Sub CopyMemoryToMinMaxInfo Lib "KERNEL32" Alias _
         "RtlMoveMemory" (hpvDest As MINMAXINFO, ByVal hpvSource As Long, _
          ByVal cbCopy As Long)
      Private Declare Sub CopyMemoryFromMinMaxInfo Lib "KERNEL32" Alias _
         "RtlMoveMemory" (ByVal hpvDest As Long, hpvSource As MINMAXINFO, _
          ByVal cbCopy As Long)

      Public Sub Hook()
          'Start subclassing.
          lpPrevWndProc = SetWindowLong(gHW, GWL_WNDPROC, _
             AddressOf WindowProc)
      End Sub

      Public Sub Unhook()
          Dim temp As Long

          'Cease subclassing.
          temp = SetWindowLong(gHW, GWL_WNDPROC, lpPrevWndProc)
      End Sub

      Function WindowProc(ByVal hw As Long, ByVal uMsg As Long, _
         ByVal wParam As Long, ByVal lParam As Long) As Long
          Dim MinMax As MINMAXINFO

          'Check for request for min/max window sizes.
          If uMsg = WM_GETMINMAXINFO Then
            'Retrieve default MinMax settings
            CopyMemoryToMinMaxInfo MinMax, lParam, Len(MinMax)

            'Specify new minimum size for window.
            MinMax.ptMinTrackSize.x = 200
            MinMax.ptMinTrackSize.y = 200

            'Specify new maximum size for window.
            MinMax.ptMaxTrackSize.x = 500
            MinMax.ptMaxTrackSize.y = 500

            'Copy local structure back.
            CopyMemoryFromMinMaxInfo lParam, MinMax, Len(MinMax)

            WindowProc = DefWindowProc(hw, uMsg, wParam, lParam)
          Else
            WindowProc = CallWindowProc(lpPrevWndProc, hw, uMsg, _
               wParam, lParam)
          End If
      End Function

[ 本帖最后由 ≈※爖※≈ 于 2009-2-16 17:30 编辑 ]

sanhen 发表于 2009-2-16 17:03:40

VB看起来好复杂，看AU3的^_^


#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

GUICreate("测试窗口",500,300,-1,-1,BitOR($WS_MINIMIZEBOX, $WS_MAXIMIZEBOX, $WS_SIZEBOX))
GUISetState()
GUIRegisterMsg($WM_GETMINMAXINFO, "WM_GETMINMAXINFO")
Do
        $msg = GUIGetMsg()
        Until $msg=-3

Func WM_GETMINMAXINFO($hWnd, $Msg, $wParam, $lParam)
        Local $minmaxinfo
        $minmaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
        DllStructSetData($minmaxinfo, 7,500) ; min X
        DllStructSetData($minmaxinfo, 8, 300) ; min Y
        DllStructSetData($minmaxinfo,9,500) ; max X
        DllStructSetData($minmaxinfo,10,300) ; max Y
        Return 0
EndFunc   ;==>WM_GETMINMAXINFO

≈※爖※≈ 发表于 2009-2-16 17:30:18

厉害啊!居士,我爱死你了,谢谢哈~:face (29):

查看完整版本: 请求帮助关于窗口限制大小问题!