怎么退出已登录系统超级用户模式？

AUFS

用_RunAsPowerUser($Name,$PWD) 登录操作完之后想不退出程序的情况下退出超级用户模式？

pusofalse

退出超级用户模式？不明白你的意思，直接exit不就行了吗？
如果再次运行要用管理员身份运行，还是用参数判断。

AUFS

_RunAsPowerUser($Name,$PWD) 进入管理员身份之后操作完想退出管理员身份。。。如果不退出管理员身份的话如果我想发一个快捷方式到桌面的话就发送到管理员的哪个桌面去了，，，所以想到取消管理员身份了。不知道_RunAsPowerUser($Name,$PWD)可以转进管理员身份有没有也有办法退出这个身份呢？

pusofalse

#NoTrayIcon
#include <LocalSecurityAuthority.au3>

$sPowerUser = "PowerUser"
$sPowerUserPswd = "PowerUserPswd"

$sAdminUser = "Administrator" ; 管理员用户名
$sAdminUserPswd = "AdminUserPswd" ; 管理员密码


_RunAsPowerUser($sPowerUser, $sPowerUserPswd)
Msgbox(0, 1, @UserName)

$hToken = _LogonUser($sAdminUser, $sAdminUserPswd, "", 2)
_ImpersonateLoggedOnUser($hToken)
Msgbox(0, 2, @UserName)

_RevertToSelf()
_LsaCloseHandle($hToken)
Msgbox(0, 3, @UserName)

Func _RunAsPowerUser($sPowerUser, $sPassword)
        Local $hProcess, $hThread, $iProcessID, $sApp = @ScriptFullPath, $sArg

        If $CmdLine[0] = 0 Or $CmdLine[$CmdLine[0]] <> "-RunAsPowerUser" Then
                If @Compiled = 0 Then $sApp = @AutoItExe
                $sArg = " " & $CmdLineRaw & " -RunAsPowerUser"
                $iProcessID = _CreateProcessWithLogon($sPowerUser, $sPassword, "", $sApp, $sArg, _
                                $hProcess, $hThread)
                If $iProcessID Then
                        _LsaCloseHandle($hProcess)
                        _LsaCloseHandle($hThread)
                        Exit
                EndIf
        EndIf
EndFunc        ;==>_RunAsPowerUser

AUFS

谢谢，问题解决了可以正常在受限用户和超级用户之间的转换了。。。不过发现一个问题就是在转了超级用户之后发觉点按钮反应很慢...点其它窗口再点回程序的时候也要等等才能反应...可能是权限之间的切换吧....
_RevertToSelf()
_LsaCloseHandle($hToken)
退出超级用户权限之后反应就正常了