托盘图标[已解决]

xiaogou5852 · 发表于 2011-12-16 22:37:27

本帖最后由 xiaogou5852 于 2011-12-19 01:15 编辑

能否强制隐藏其他软件的托盘图标呢？？

happytc · 发表于 2011-12-16 22:52:13

理论上来说可以！

xiaogou5852 · 发表于 2011-12-16 23:01:14

回复 2# happytc

要怎样做呀？

happytc · 发表于 2011-12-16 23:48:48

本帖最后由 happytc 于 2011-12-17 00:05 编辑

回复 3# xiaogou5852
闲得无聊，帮你写个了，你试试用用。



#include <SendMessage.au3>
#include <Memory.au3>

Global Const $_WM_USER = 0X400

TrayIconState("联众大厅", 0)

Func TrayIconState($sTrayName, $iState)
        Local $hTray, $hToolbar, $iCnt, $iCmdApp, $sText, $iCmd
                
        $hTray = WinGetHandle("[CLASS:Shell_TrayWnd]")
        $hToolbar = ControlGetHandle($hTray, "", "[CLASSNN:ToolbarWindow321]")
        $iCnt = _SendMessage($hToolbar, $_WM_USER + 24, 0, 0)
        $iCmdApp = -1
        For $i = 0 To $iCnt - 1
                $iCmd = _getCommand($hToolbar, $i)
                $sText = _getText($hToolbar, $iCmd)
                If StringInStr($sText, $sTrayName) Then
                        $iCmdApp = $iCmd
                        ExitLoop
                EndIf
        Next
        
        If $iCmdApp > -1 Then                
                If $iState Then
                        _SendMessage($hToolbar, $_WM_USER + 17, $iCmdApp, 0x00000004)
                Else
                        _SendMessage($hToolbar, $_WM_USER + 17, $iCmdApp, 0x00000008)
                EndIf
        EndIf
EndFunc

Func _getCommand($hWnd, $iIndex)
        Local Const $tagBUTTON = "int Bitmap;int Command;byte State;byte Style;align;dword_ptr Param;int_ptr String"
        Local $tButton, $pButton, $iButton, $tMem, $pMem
        
        $tButton = DllStructCreate($tagBUTTON)
        $pButton = DllStructGetPtr($tButton)
        $iButton = DllStructGetSize($tButton)
        $pMem = _MemInit($hWnd, $iButton, $tMem)
        _MemWrite($tMem, $pButton, $pMem, $iButton)
        _SendMessage($hWnd, $_WM_USER + 23, $iIndex, $pMem)
        _MemRead($tMem, $pMem, $pButton, $iButton)
        _MemFree($tMem)
        Return DllStructGetData($tButton, "Command")
EndFunc


Func _getText($hWnd, $iCmd)
        Local $iBuffer, $tBuffer, $pBuffer, $tMem, $pMem
        
        $iBuffer = _SendMessage($hWnd, $_WM_USER + 75, $iCmd)
        $tBuffer = DllStructCreate("wchar Text[" & $iBuffer & "]")
        $iBuffer *= 2
        $pBuffer = DllStructGetPtr($tBuffer)        
        $pMem= _MemInit($hWnd, $iBuffer, $tMem)
        _SendMessage($hWnd, $_WM_USER + 75, $iCmd, $pMem)
        _MemRead($tMem, $pMem, $pBuffer, $iBuffer)
        _MemFree($tMem)
        Return DllStructGetData($tBuffer, "Text")
EndFunc

zldfsz · 发表于 2011-12-17 12:30:40

回复 4# happytc

太感谢了，这就是我想要的

xiaogou5852 · 发表于 2011-12-17 16:32:10

回复 4# happytc
谢谢您哈，能不能加些注释呀。有些没看懂。

zxxputian1 · 发表于 2011-12-18 10:50:58

最近一直出现图标新脚本

zxxputian1 · 发表于 2011-12-18 10:59:31

已下载，谢谢共享

happytc · 发表于 2011-12-18 20:08:17

回复 happytc
谢谢您哈，能不能加些注释呀。有些没看懂。
xiaogou5852 发表于 2011-12-17 16:32

就这么几行代码，加什么注释嘛，看看函数帮助，你就懂了

49666684 · 发表于 2011-12-20 02:57:05

脚印留下脚印留下

jjf · 发表于 2013-3-15 21:48:46

回复 4# happytc

感谢大神。你确实厉害！！膜拜~~

wql8549 · 发表于 2013-3-16 02:55:59

回复 4# happytc

学习中

whuzqAI · 发表于 2013-4-23 14:55:48

大神啊，膜拜膜拜~

		自动登录	找回密码
密码			加入

[系统综合] 托盘图标[已解决]

相关帖子