[已解决]请教 <GuiListView.au3> UDF里面的HotItem函数用途...看不懂其翻译

kk_lee69

请教 <GuiListView.au3> UDF里面的HotItem函数用途...看不懂其翻译….
翻譯是 翻譯為 熱項....... 老實說 從翻譯上 我無法理解 可以運用在什麼時候.....
跑了範例....也時在看不出 熱項的用途 可以用在哪裡......

可能是因為我是對岸的同胞.....所以用語上 搞不太懂.....有人可以解釋一下
_GUICtrlListView_SetHotItem
_GUICtrlListView_GetHotItem
者兩個函數的意義 跟 可以運用在哪邊嗎??

感謝幫忙^^

netegg

hotitem是当前的激活项

kk_lee69

回复 2# netegg
意思就是  當前被選定的對象嗎??

那他 跟 _GUICtrlListView_GetItemSelected  這個的差異在哪呢...??

我實際跑範例程式  好像也沒看到 有出現被選定的狀態??

netegg

回复 3# kk_lee69

不是选定项，是激活项(待选定项)

happytc

回复 1# kk_lee69

根本不是翻译的问题，更不是两岸用语的问题，而是你的知识面太窄了。
在那个程序或语言里都会有这个“热项”或什么“热按纽”等等，英语表达就是：hot item，hot button


也许下面的由帮助代码，我修改了点，你用鼠标在上面移动或点击选中一个item，看看输出，你就明白了
   

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work

_Main()

Func _Main()
        Local $exStyles = BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_GRIDLINES), $hListView

        GUICreate("ListView Set Hot Item", 400, 300)

        $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
        $hListView = GUICtrlGetHandle($hListView)
        _GUICtrlListView_SetExtendedListViewStyle($hListView, $exStyles)
        GUISetState()

        ; Add columns
        _GUICtrlListView_AddColumn($hListView, "Column 1", 100)
        _GUICtrlListView_AddColumn($hListView, "Column 2", 100)
        _GUICtrlListView_AddColumn($hListView, "Column 3", 100)

        ; Add items
        _GUICtrlListView_AddItem($hListView, "Row 1: Col 1")
        _GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 2", 1)
        _GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 3", 2)
        _GUICtrlListView_AddItem($hListView, "Row 2: Col 1")
        _GUICtrlListView_AddSubItem($hListView, 1, "Row 2: Col 2", 1)
        _GUICtrlListView_AddItem($hListView, "Row 3: Col 1")

        ; Loop until user exits
        Local $iHotItem, $iHotItemOri = 0, $iSelectItem, $iSelectItemOri = 0
        Do
                $iHotItem = _GUICtrlListView_GetHotItem($hListView)
                $iSelectItem = _GUICtrlListView_GetItemSelected($hListView, 1)
                If $iHotItem <> $iHotItemOri Or $iSelectItem <> $iSelectItemOri Then
                        ConsoleWrite("Hot Item: " & $iHotItem & "           " & $iSelectItem & @CRLF)
                        $iHotItemOri = $iHotItem
                        $iSelectItemOri = $iSelectItem
                EndIf
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>_Main

kk_lee69

回复 5# happytc

感謝幫助  果然一看就懂.....多謝啦 解決我的疑問