[已解决]搜了半天也没找到简单有效的发送邮件的代码！

fybhwsx

我想把软件的启动结果（成功或失败）发送到139邮箱，但怎么也弄不成。哪位老师能提供自动交易发送邮件的代码，谢谢！

haijie1223

http://www.autoitx.com/forum.php ... =%B7%A2%D3%CA%BC%FE

qq82015930

不会吧，我一直都用AU3记录密码 发邮件没问题啊

fybhwsx

不会吧，我一直都用AU3记录密码 发邮件没问题啊
qq82015930 发表于 2013-1-11 21:52

   能给一下代码吗，我是新手，只会简单修改一些代码。

fybhwsx

haijie1223 发表于 2013-1-11 21:20

    谢谢，正在研究。。

fybhwsx

谁还有更简单的发送邮件代码吗？

xms77

回复 1# fybhwsx
自己修改一下邮件地址等信息，我测试代码是没有问题的，有时会发送不成功。

#include<file.au3>

Global $SmtpServer, $FromName, $FromAddress, $ToAddress, $CcAddress, $Subject, $Body, $AttachFiles, $Importance, $Username, $Password, $IPPort, $ssl, $BccAddress
Global $oMyRet[2]
Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")


        $SmtpServer = "smtp.gmail.com" ; address for the smtp-server to use - REQUIRED
        $FromName = "xxxxx" ; 名字来自谁是电子邮件的发送
        $FromAddress = "xxxxx@gmail.com" ; address from where the mail should come
        $ToAddress = "xxxxx@139.com" ; destination address of the email - REQUIRED
        $Subject = "testing" ; 从电子邮件的主题 - 可以是任何你希望它是
        $Body = "have you received this email？" ; 从邮件消息内容 - 可留空，但你得到一个空白邮件
        $AttachFiles = "" ; the file(s) you want to attach seperated with a ; (Semicolon) - 如果不需要留空白
        $CcAddress = "" ; 为抄送地址 - 如果不需要留空白
        $BccAddress = "" ; bcc的地址 - 如果不需要留空白
        $Importance = "Normal" ; 发送消息的优先级：“高”，“正常”，“低”
        $Username = "username" ; 从使用的用户名的帐户发送邮件获取 - 需
        $Password = "123456" ; 从使用密码的帐户发送邮件获取 - 需
        ;$IPPort = 25 ; 端口用于发送邮件
        ;$ssl = 0 ; 启用/禁用安全套接字层发送 - 如果把使用https 1
         $IPPort=465                          ; GMAIL port used for sending the mail
         $ssl=1                               ; GMAILenables/disables secure socket layer sending - put to 1 if using httpS


$rc = _INetSmtpMailCom($SmtpServer, $FromName, $FromAddress, $ToAddress, $Subject, $Body, $AttachFiles, $CcAddress, $BccAddress, $Importance, $Username, $Password, $IPPort, $ssl)
                        If @error Then
                                MsgBox(0, "Error sending message", "Error code:" & @error & "  Description:" & $rc)
                        EndIf

; The UDF
Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Importance = "Normal", $s_Username = "", $s_Password = "", $IPPort = 25, $ssl = 0)
        Local $objEmail = ObjCreate("CDO.Message")
        $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
        $objEmail.To = $s_ToAddress
        Local $i_Error = 0
        Local $i_Error_desciption = ""
        If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
        If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
        $objEmail.Subject = $s_Subject
        If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
                $objEmail.HTMLBody = $as_Body
        Else
                $objEmail.Textbody = $as_Body & @CRLF
        EndIf
        If $s_AttachFiles <> "" Then
                Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
                For $x = 1 To $S_Files2Attach[0]
                        $S_Files2Attach[$x] = _PathFull($S_Files2Attach[$x])
;~          ConsoleWrite('@@ Debug : $S_Files2Attach[$x] = ' & $S_Files2Attach[$x] & @LF & '>Error code: ' & @error & @LF) ;### Debug Console
                        If FileExists($S_Files2Attach[$x]) Then
                                ConsoleWrite('+> File attachment added: ' & $S_Files2Attach[$x] & @LF)
                                $objEmail.AddAttachment($S_Files2Attach[$x])
                        Else
                                ConsoleWrite('!> File not found to attach: ' & $S_Files2Attach[$x] & @LF)
                                SetError(1)
                                Return 0
                        EndIf
                Next
        EndIf
        $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
        $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
        If Number($IPPort) = 0 Then $IPPort = 25
        $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
        ;Authenticated SMTP
        If $s_Username <> "" Then
                $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
                $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
                $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
        EndIf
        If $ssl Then
                $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
        EndIf
        ;Update settings
        $objEmail.Configuration.Fields.Update
        ; Set Email Importance
        Switch $s_Importance
                Case "High"
                        $objEmail.Fields.Item("urn:schemas:mailheader:Importance") = "High"
                Case "Normal"
                        $objEmail.Fields.Item("urn:schemas:mailheader:Importance") = "Normal"
                Case "Low"
                        $objEmail.Fields.Item("urn:schemas:mailheader:Importance") = "Low"
        EndSwitch
        $objEmail.Fields.Update
        ; Sent the Message
        $objEmail.Send
        If @error Then
                SetError(2)
                Return $oMyRet[1]
        EndIf
        $objEmail = ""
EndFunc   ;==>_INetSmtpMailCom

; Com Error Handler
Func MyErrFunc()
        $HexNumber = Hex($oMyError.number, 8)
        $oMyRet[0] = $HexNumber
        $oMyRet[1] = StringStripWS($oMyError.description, 3)
        ConsoleWrite("### COM Error !  Number: " & $HexNumber & "   ScriptLine: " & $oMyError.scriptline & "   Description:" & $oMyRet[1] & @LF)
        SetError(1); something to check for when this function returns
        Return
EndFunc   ;==>MyErrFunc

fybhwsx

回复  fybhwsx
自己修改一下邮件地址等信息，我测试代码是没有问题的，有时会发送不成功。
xms77 发表于 2013-1-12 14:11

    谢谢，我终于可以发送邮件了！学习中。。。

whitehead

谢谢，我ye学习!

linnsky

这个貌似不支持中文

txxdhnt

不玩伊妹儿好多年。。。。现在流行“飞猪流”。。

gzguolei

学习中。。。。。。。。。

user030

已使用，确实有效