淘宝登陆时的input控件提示是怎么做的？

李岸

像这种input控件提示在AU3中要怎么写？

lanfengc

回复 1# 李岸

给你个例子吧.
   

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

;定义全局  默认字串
Global $defaultText="手机号/会员号/邮箱"
;创建窗口
$hGUI = GUICreate("测试", 300, 22)
;创建输入框
$idInput = GUICtrlCreateInput($defaultText, 0, 0, 300, 20)
;设置背景颜色为灰色
GUICtrlSetColor($idInput, 0xC0C0C0)
;注册 事件触发的函数
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
;显示窗口
GUISetState(@SW_SHOW, $hGUI)

While 1
        Switch GUIGetMsg()
                ;当窗口关闭时 退出
                Case $GUI_EVENT_CLOSE
                        Exit
        EndSwitch
WEnd

;事件处理函数
Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
        ;从wParam中提取低字节  
        Switch _WinAPI_LoWord($wParam)
                ;如果是输入框的ID
                Case $idInput
                        ;再取wParam 高位
                        Switch _WinAPI_HiWord($wParam)
                                ;如果消息是  输入框改变的消息
                                Case $EN_CHANGE
                                        ;当输入框内容为空 时候, 设置默认内容  否则只改变颜色
                                        If GUICtrlRead($idInput) = "" Then
                                                GUICtrlSetData($idInput, $defaultText)
                                                GUICtrlSetColor($idInput, 0xC0C0C0)
                                        Else
                                                GUICtrlSetColor($idInput, 0x000000)
                                        EndIf
                        EndSwitch
        EndSwitch
EndFunc