如何 表示 数组 中的数组【已解决】

fenhanxue

Local $a[2] = [1,2]
Local $b[2] = [3,4]

Local $c[2]

$c[0] = $a
$c[1] = $b

Local $d = $a



;以        $a[1] = 2 为例子
;要表示  $a[1] = 2 
;        1）如果用d来表示，可以这样写,即 
        MsgBox(0,' $a[1]的值为',$d[1])

;        2）如何用c来表示？这样写好像是错误的
        MsgBox(0,' $a[1]的值为',$c[0][1])

答案：
需要一个（）   即

MsgBox(0,' $a[1]的值为',（$c[0]）[1])

afan

较高版本的Au3支持直接引用表达式的元素，因此可以直接写为 MsgBox(0,' $a[1]的值为',($c[0])[1])

否则Au3版本不支持则需再转一次
Local $c1 = $c[0]
MsgBox(0,' $a[1]的值为',$c1[1])

heroxianf

回复 2# afan

也许楼主想 转换成二维数组，  至少我看到我就想这么做。

heroxianf

回复 1# fenhanxue

还有一种冷门用法

Local $a[2] = [1, 2]
Local $b[2] = [3, 4]
Local $c[2]

$c[0] = $a
$c[1] = $b

Local $d = $a

MsgBox(0, ' $a[1]的值为', $d[1])
MsgBox(0, ' $a[1]的值为', ($c[0])[1])

afan

回复  afan

也许楼主想 转换成二维数组，  至少我看到我就想这么做。
heroxianf 发表于 2017-4-1 13:16

    这跟二维数组是两回事…

heroxianf

回复 5# afan


    其实是我想这么做，自己还不知道怎么弄

afan

回复  afan


     其实是我想这么做，自己还不知道怎么弄
heroxianf 发表于 2017-4-1 13:49

    循环填充

#Include <Array.au3>

Local $a[2] = ['a1', 'a2']
Local $b[3] = ['b1', 'b2', 'b3']

Local $c = _2dArr($a, $b)
_ArrayDisplay($c)

Func _2dArr($a, $b)
        If Not IsArray($a) Or Not IsArray($b) Then Return SetError(1)
        Local $iMax = UBound($a), $c = $a
        If UBound($b) > $iMax Then $iMax = UBound($b)
        ReDim $c[$iMax][2], $a[$iMax], $b[$iMax]
        For $i = 0 To $iMax - 1
                $c[$i][0] = $a[$i]
                $c[$i][1] = $b[$i]
        Next
        Return $c
EndFunc   ;==>_2dArr

heroxianf

回复 7# afan


    谢谢A大  下来认真学习

kk_lee69

回复 8# heroxianf

二維也行吧  舊版的 無法支援這個表示法

但是新版的 可以呀!!

DIM $a[2][2]
$a[0][0]="A0"
$a[0][1]="A1"
$a[1][0]="B0"
$a[1][1]="B1"
_ArrayDisplay($a)

DIM $b[2][2]

$b[0][0]="Y0"
$b[0][1]=$a
$b[1][0]="Z0"
$b[1][1]="Z1"
_ArrayDisplay($b)

MsgBox(0,0, ($b[0][1])[1][1]) 

fenhanxue

回复 4# heroxianf


原来加个()就能用c来正确表示了，学到了新技能。。。

heroxianf

回复 9# kk_lee69

是的 新版才可以，不过我用3.3.12可以执行、也是自己那个时候想这么输出

帆船

回复 2# afan
我发现用这种表示方法可以显示但是不能赋值啊？？

Global $aArray[2] = [0, 1]
$aArray[1] = $aArray
MsgBox(0, "", ($aArray[1])[0] & @CRLF & ($aArray[1])[1])
($aArray[1])[0] = 1
($aArray[1])[1] = 2
MsgBox(0, "", ($aArray[1])[0] & @CRLF & ($aArray[1])[1])

afan

回复  afan
我发现用这种表示方法可以显示但是不能赋值啊？？
帆船 发表于 2017-4-2 22:51

    应该是的，只能引用，不能变更

dingcool

我想把C++代码转成autoit代码
    c代码如下：
        byte M[] = {0,1};
        char* Zfc[] = {"zifuchuan1","zifuchuan2"};
        bool = func(M, Zfc);



func函数是dll中的，我想用dllcall调用，怎么把两个字符串传递到func中

dingcool

回复 13# afan


    我想把C++代码转成autoit代码
   
        byte M[] = {0,1};
        char* Zfc[] = {"zifuchuan1","zifuchuan2"};
        bool = func(M, Zfc);



func函数是dll中的，不能重写。
我想用dllcall调用，怎么把两个字符串传递到func中