强制删除文件

userlong

FileDelete  来删除系统垃圾  还有 没办法删除掉的！1  有什么法子强制删除掉？

baikaifang

如果是使用中的文件,应该删不掉,我想如果可以关掉引用该文件的其它所有程序的句柄.应该就可以删除了.

sensel

这个，，，你要先搞清楚为何文件无法删除。是文件正在使用？还是文件属性未去除？还是NTFS权限不足？

llztt

楼上回复的，让我们都没意思回复了。。唉

提醒个：WINDOWS有个写注册表的办法，可以让系统启动后删除文件，不知道有用没。。

sensel

4# llztt


你是说这个东东？这是很暴力的，在Windows启动过程中，仅加载基本驱动(总线，硬盘等)，运行过磁盘扫描后就开始删除。这时还删不掉的文件估计只有十几个吧。

;===============================================================================
; 说明:   在系统重启后移动/删除文件
; 语法:   _FileMoveAtReboot($sSFile[, $sTFile = ""])
; 参数:   $sSFile - 源文件
;         $sTFile - [可选] 目标文件。如果不指定，文件将在重启后被删除
; 需要:   无
; 返回:   成功 - 1
;         失败 - 0, 并设置 @error 到
;            1 - 源文件不存在
;            2 - 权限不足。需要管理员组或 LocalSystem 帐户权限
;            3 - API 调用失败
; 备注:   源文件和目标文件必须在同一卷
;===============================================================================
Func _FileMoveAtReboot($sSFile, $sTFile = "")
        Local $sRegTmp, $iDel, $aResult
        $iDel = 0x5   ; MOVEFILE_REPLACE_EXISTING + MOVEFILE_DELAY_UNTIL_REBOOT
        If NOT FileExists($sSFile) Then Return SetError(1, 0, 0)

        $sRegTmp = "PendingFileRenameOperations" & Random(1000, 9999, 1)
        RegWrite("HKLM\SYSTEM\CurrentControlSet\Control\Session Manager", $sRegTmp, "REG_MULTI_SZ", "Test")
        If @error Then Return SetError(2, 0, 0)
        RegDelete("HKLM\SYSTEM\CurrentControlSet\Control\Session Manager", $sRegTmp)
        RegWrite("HKLM\SYSTEM\CurrentControlSet\Control\Session Manager", "AllowProtectedRenames", "REG_DWORD", 1)

        If $sTFile = "" Then
                $aResult = DllCall("kernel32.dll", "int", "MoveFileEx", "str", $sSFile, "ptr", "", "dword", $iDel)
        Else
                $aResult = DllCall("kernel32.dll", "int", "MoveFileEx", "str", $sSFile, "str", $sTFile, "dword", $iDel)
        EndIf
        If @error OR $aResult[0] = 0 Then
                Return SetError(3, 0, 0)
        Else
                Return 1
        EndIf
EndFunc   ;==>_FileMoveAtReboot

llztt

我只见过，还真没实际应用过，还真不知道这么暴力，学习了，哈哈

netegg

太狠点了，这个东东搞出来就基本能回dos了

风雨网络

这个貌似很厉害！ 不知道设置权限的文件重启是否能删除？

sensel

这个貌似很厉害！ 不知道设置权限的文件重启是否能删除？
风雨网络 发表于 2009-4-26 16:43

PendingFileRenameOperations在启动过程中由smss.exe处理，smss.exe登录用户是SYSTEM。所以从理论上来说，如果SYSTEM也没删除那个文件的权限，这是删不掉的。
另外，这还是有局限的，比如，用这个肯定删不掉smss.exe本身及其调用的ntdll.dll文件。