如何返回读取的SQL数据？

xg911335

$uid = "123"
$pwd = "123"
$database = "pubs"
$server = "."
$conn = ObjCreate("ADODB.Connection")
$rs=ObjCreate("ADODB.Recordset")
$conn.Open ("driver={SQL Server};server=" & $server & ";uid=" & $uid & ";pwd=" & $pwd & ";database=" & $database)
$RS.ActiveConnection = $conn
$test = $RS.Open('select phone FROM authors WHere au_lname=''White''')
MsgBox(0,"",$test)；这里什么都没有显示？

$RS.close
$conn.close

llm1978

$test = $RS.Open('select phone FROM authors WHere au_lname=''White''')

这句赋值不对啊，SQL不是这么执行的。

hnzzlzj

谁会sql操作能不能好好给大家讲讲

howie530_8

$read = ReabTableDb($conn, "select phone FROM authors WHere au_lname=''White"")
;加个函数
Func ReabTableDb($conn, $Sql);读取数据
        $RS = ObjCreate("ADODB.Recordset");创建记录集对象
        $RS.ActiveConnection = $conn;设置记录集的激活链接属性来自$Conn
        $RS.Open($Sql);执行Sql语句
        Dim $Select_Db[1][1] = [[0]];定义一个数组来接收查询到的数据
        Dim $Count = 1;定义一个变量用来记录查询到的数据行数
        While Not $RS.eof And Not $RS.bof;当记录指针处于第一条记录和最后一条记录之间时，执行while循环
                If @error = 1 Then ExitLoop
                If $Select_Db[0][0] = 0 Then;当数组二维$Select_Db[0][0]为0时，重定义数组的第二维大小等于记录集查询到的字段数
                        ReDim $Select_Db[1][$RS.Fields.Count + 1];$RS.Fields.Count为记录集查询到的字段数
                        For $i = 0 To $RS.Fields.Count - 1
                                $Select_Db[0][$i + 1] = $RS.Fields($i).Name;$RS.Fields($i).Name为字段名，把字段名存入数组
                        Next
                EndIf
                ReDim $Select_Db[$Count + 1][$RS.Fields.Count + 1];数组第一维大小加1，用于存放数据
                $Select_Db[0][0] = $Count;$Select_Db[0][0]存放查询到的数据行数
                For $i = 0 To $RS.Fields.Count - 1
                        $Select_Db[$Count][$i + 1] = $RS.Fields($i).Value;$RS.Fields($i).Value字段数据
                Next
                $Count += 1;行数加1
                $RS.movenext;将记录指针从当前的位置向下移一行
        WEnd
        $RS.Close;关闭记录集对象
        Return $Select_Db
EndFunc

cf19870928

我正在找读取指定字段的数据  怎么搞啊

cf19870928

我正在找读取指定字段的数据  怎么搞啊