[已解决]去掉IE“自动检测设置”的勾选

boyhong

去掉IE“自动检测设置”的勾选~如下图：


目前，我知道如何检测这个勾到底选上还是没有选上：

#Include <WinHTTP.au3>
$array=_WinHttpGetIEProxyConfigForCurrentUser()
MsgBox(64,"",$array[0])
如上：$array[0]的值是1选上，是0为没有选上。

我现在想实现：若选上了，如何去掉这个勾为不选上。

希望大家出手~感激不尽~~

boyhong

我暂时的折中解决方法，但不是长久之计：
if $array[0]=1 then
Do
$iereg=FileInstall("ie.reg",@HomeDrive&"\IExiufu.reg",1)
Until $iereg=1
$iexiufudos=_RunDOS("regedit /s "&@HomeDrive&"\IExiufu.reg")
FileDelete(@HomeDrive&"\IExiufu.reg")
Endif

boyhong

希望大家帮忙看看~感谢~~~~~~~期待更好的办法实现。。。。。那天我去看了API的东西。没有看懂。。。不知道能不能实现。。。。。

xlcwxl

判断值就行啦

bing614

_WinHttpSetDefaultProxyConfiguration

boyhong

_WinHttpSetDefaultProxyConfiguration
bing614 发表于 2010-2-4 09:27

设置默认的WinHTTP代理配置
#Include <WinHTTP.au3>
_WinHttpSetDefaultProxyConfiguration( $iAccessType, $Proxy, $ProxyBypass )
参数
$iAccessType
包含权限类型的整数值
$Proxy
包含代理服务器列表的字符串
$ProxyBypass
包含代理旁路列表的字符串


我不明白是什么意思，包含权限类型的整数值，包含代理服务器列表的字符串，包含代理旁路列表的字符串
？？？？？？？  请兄台指点一下，我只想实现一楼的想法而已~~~~应怎么写？

boyhong

判断值就行啦
xlcwxl 发表于 2010-2-4 08:54

不行的。。我在二楼的注册表文件内容：
Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections]
"DefaultConnectionSettings"=hex:3c,00,00,00,05,00,00,00,01,00,00,00,00,00,00,\
00,00,00,00,00,00,00,00,00,01,00,00,00,00,00,00,00,90,b1,e4,38,dc,92,c6,01,\
01,00,00,00,c0,a8,71,fa,00,00,00,00,00,00,00,00
"SavedLegacySettings"=hex:3c,00,00,00,85,00,00,00,01,00,00,00,00,00,00,00,00,\
00,00,00,00,00,00,00,01,00,00,00,00,00,00,00,90,b1,e4,38,dc,92,c6,01,01,00,\
00,00,c0,a8,71,fa,00,00,00,00,00,00,00,00

请问怎么判断？

qq82015930

IF    判断 注册表

78391493

ControlCommand直接发送勾选命令，管它勾了还是没勾

boyhong

IF    判断 注册表
qq82015930 发表于 2010-2-4 15:31

能否写个例子？

阿福

只需要去勾选的话，这样就可以了：
$sOpt = '01'; ='01'去勾, ='09'打勾

$sDCS = Hex(RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections","DefaultConnectionSettings"))
$sDCS = StringLeft($sDCS, 16) & $sOpt & StringMid($sDCS, 19, StringLen($sDCS) - 18)
RegWrite("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections","DefaultConnectionSettings","REG_BINARY", Binary('0x' & $sDCS))

如果要和系统保持一致就再加上这段代码：
$sSLS = Hex(RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections","SavedLegacySettings"))
$sSLS = StringLeft($sSLS, 16) & $sOpt & StringMid($sSLS, 19, StringLen($sSLS) - 18)
RegWrite("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections","SavedLegacySettings","REG_BINARY", Binary('0x' & $sSLS))

有的IE版本可能出现：仅是注册表的修改不会马上应用到IE，可以再加这个应用修改的代码：
DllCall( 'wininet.dll', 'uint', 'InternetSetOption', 'ptr', 0, 'dword', 39, 'ptr', 0, 'dword', 0 )

如果应用修改对付不了所有IE版本，就再做刷新：
DllCall( 'wininet.dll', 'uint', 'InternetSetOption', 'ptr', 0, 'dword', 37, 'ptr', 0, 'dword', 0 )

所以通用的完整代码为：

$sOpt = '01'; ='01'去勾, ='09'打勾

$sDCS = Hex(RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections","DefaultConnectionSettings"))
$sDCS = StringLeft($sDCS, 16) & $sOpt & StringMid($sDCS, 19, StringLen($sDCS) - 18)
RegWrite("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections","DefaultConnectionSettings","REG_BINARY", Binary('0x' & $sDCS))

$sSLS = Hex(RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections","SavedLegacySettings"))
$sSLS = StringLeft($sSLS, 16) & $sOpt & StringMid($sSLS, 19, StringLen($sSLS) - 18)
RegWrite("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections","SavedLegacySettings","REG_BINARY", Binary('0x' & $sSLS))

DllCall( 'wininet.dll', 'uint', 'InternetSetOption', 'ptr', 0, 'dword', 39, 'ptr', 0, 'dword', 0 ) 

DllCall( 'wininet.dll', 'uint', 'InternetSetOption', 'ptr', 0, 'dword', 37, 'ptr', 0, 'dword', 0 ) 

如果你把这段代码写成自定义func的话，判断成功的返回可以这样表达：
DllCall( 'wininet.dll', 'uint', 'InternetSetOption', 'ptr', 0, 'dword', 39, 'ptr', 0, 'dword', 0 )
If @error Then Return 0
DllCall( 'wininet.dll', 'uint', 'InternetSetOption', 'ptr', 0, 'dword', 37, 'ptr', 0, 'dword', 0 )
If @error Then Return 0
Return 1 ;成功

如果你要判断原始状态就取StringMid($sDCS, 17, 2),是'01'就是没打勾, 是'09'就是打勾了.

catcher

强大的阿福

boyhong

强大的阿福~~~无比敬仰~~~~~~~~~~

shirleyp

好强大呀，正需要呢，十分感谢.

leon460

忍不住想顶下