请问关于timer的问题

kxing

我希望在每10分钟调用一次某个函数。
尝试过用 if @min==0 or @min==10 ...
但是这样的话在这一分钟内反复调用.
所以想到了相关的timer函数，打开看都是e文。
因此特意来这里寻求高手帮助，多谢！！！

lxz

把10分钟循环就行了.

kxing

晕死,那我其他控件怎么判断啊?

afan

AdlibRegister()

kxing

多谢,这个函数是不是不能放在消息循环内呢
否则被反复重新注册了.

boyhong

试试士办法！！用cmdline  多次调用自身！多进程代替你的多线程？

afan

多谢,这个函数是不是不能放在消息循环内呢
否则被反复重新注册了.
kxing 发表于 2010-4-27 16:59

    这里按需求只适合放在主循环（外面）前面~

3mile

#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>
#include <Timers.au3>
#include <GuiStatusBar.au3>
#include <ProgressConstants.au3>

Opt("MustDeclareVars", 1)

Global $hStatusBar

_Example_CallBack()

Func _Example_CallBack()
        Local $hGUI 
        $hGUI = GUICreate("Timers Using CallBack Function(s)", 400, 320)
        $hStatusBar = _GUICtrlStatusBar_Create($hGUI, 75,300,-1)
        _GUICtrlStatusBar_SetText($hStatusBar, "Timers")
        _GUICtrlStatusBar_SetText($hStatusBar, @TAB & @TAB & StringFormat("%02d:%02d:%02d", @HOUR, @MIN, @SEC), 0)
        GUISetState()        
        _Timer_SetTimer($hGUI, 1000, "_UpdateStatusBarClock") ; create timer

        While 1
                Switch GUIGetMsg()
                        Case $GUI_EVENT_CLOSE
                                ExitLoop
                EndSwitch
        WEnd
        _Timer_KillAllTimers($hGUI)
        GUIDelete()
EndFunc   ;==>_Example_CallBack

; call back function
Func _UpdateStatusBarClock($hWnd, $Msg, $iIDTimer, $dwTime)
        #forceref $hWnd, $Msg, $iIDTimer, $dwTime
        _GUICtrlStatusBar_SetText($hStatusBar, @TAB & @TAB & StringFormat("%02d:%02d:%02d", @HOUR, @MIN, @SEC), 0)
EndFunc   ;==>_UpdateStatusBarClock

superflq

3mile 发表于 2010-4-28 10:06

    嗯，正解