找回密码
 加入
搜索
AUTOIT CN»论坛 › AU3交流 › 『 GUI 交流 』 › 官网 GUI 脚本，应该可以作为托盘提示使用，但汉化后显 ...
12下一页
返回列表 发新帖
查看: 31144|回复: 29

[特效] 官网 GUI 脚本，应该可以作为托盘提示使用，但汉化后显示失常，有兴趣的看看！！

 火... [复制链接]
131738
发表于 2010-8-12 20:14:28 | 显示全部楼层 |阅读模式
本帖最后由 131738 于 2010-8-14 21:16 编辑

无任何包含文件，文件名：Toast_Example_Obfuscated.au3.au3

Toast 这个词词霸解释为 吐司、面包、祝酒；尽是吃的东西，真不知这个词是如何与这个脚本内容联系起来的！！！

继续往下看，超版 afan 以做了修改。
  1. Func _StringSize($sText, $iSize = Default, $iWeight = Default, $iAttrib = Default, $sName = Default, $iWidth = 0)
  2.         Local $avSize_Info[4], $aRet, $iLine_Width = 0, $iLast_Word, $iWrap_Count
  3.         Local $hLabel_Handle, $hFont, $hDC, $oFont, $tSize = DllStructCreate("int X;int Y")
  4.         If Not IsString($sText) Then Return SetError(1, 1, 0)
  5.         If Not IsNumber($iSize) And $iSize <> Default Then Return SetError(1, 2, 0)
  6.         If Not IsInt($iWeight) And $iWeight <> Default Then Return SetError(1, 3, 0)
  7.         If Not IsInt($iAttrib) And $iAttrib <> Default Then Return SetError(1, 4, 0)
  8.         If Not IsString($sName) And $sName <> Default Then Return SetError(1, 5, 0)
  9.         If Not IsNumber($iWidth) Then Return SetError(1, 6, 0)
  10.         Local $hGUI = GUICreate("", 1200, 500, 10, 10)
  11.         If $hGUI = 0 Then Return SetError(2, 0, 0)
  12.         GUISetFont($iSize, $iWeight, $iAttrib, $sName)
  13.         $avSize_Info[0] = $sText
  14.         If StringInStr($sText, @CRLF) = 0 Then StringRegExpReplace($sText, "[\x0a|\x0d]", @CRLF)
  15.         Local $asLines = StringSplit($sText, @CRLF, 1)
  16.         Local $hText_Label = GUICtrlCreateLabel($sText, 10, 10)
  17.         Local $aiPos = ControlGetPos($hGUI, "", $hText_Label)
  18.         GUISetState(@SW_HIDE)
  19.         GUICtrlDelete($hText_Label)
  20.         $avSize_Info[1] = ($aiPos[3] - 8) / $asLines[0]
  21.         $avSize_Info[2] = $aiPos[2]
  22.         $avSize_Info[3] = $aiPos[3] - 4
  23.         If $aiPos[2] > $iWidth And $iWidth > 0 Then
  24.                 $avSize_Info[0] = ""
  25.                 $avSize_Info[2] = $iWidth
  26.                 Local $iLine_Count = 0
  27.                 For $j = 1 To $asLines[0]
  28.                         $hText_Label = GUICtrlCreateLabel($asLines[$j], 10, 10)
  29.                         $aiPos = ControlGetPos($hGUI, "", $hText_Label)
  30.                         GUICtrlDelete($hText_Label)
  31.                         If $aiPos[2] < $iWidth Then
  32.                                 $iLine_Count += 1
  33.                                 $avSize_Info[0] &= $asLines[$j] & @CRLF
  34.                         Else
  35.                                 $hText_Label = GUICtrlCreateLabel("", 0, 0)
  36.                                 $hLabel_Handle = ControlGetHandle($hGUI, "", $hText_Label)
  37.                                 $aRet = DllCall("User32.dll", "hwnd", "GetDC", "hwnd", $hLabel_Handle)
  38.                                 If @error Then _StringSize_Error(3, 1, $hLabel_Handle, 0, $hGUI)
  39.                                 $hDC = $aRet[0]
  40.                                 $aRet = DllCall("user32.dll", "lparam", "SendMessage", "hwnd", $hLabel_Handle, "int", 0x0031, "wparam", 0, "lparam", 0)
  41.                                 If @error Then _StringSize_Error(3, 2, $hLabel_Handle, $hDC, $hGUI)
  42.                                 $hFont = $aRet[0]
  43.                                 $aRet = DllCall("GDI32.dll", "hwnd", "SelectObject", "hwnd", $hDC, "hwnd", $hFont)
  44.                                 If @error Then _StringSize_Error(3, 3, $hLabel_Handle, $hDC, $hGUI)
  45.                                 $oFont = $aRet[0]
  46.                                 If $oFont = 0 Then _StringSize_Error(3, 4, $hLabel_Handle, $hDC, $hGUI)
  47.                                 $iWrap_Count = 0
  48.                                 While 1
  49.                                         $iLine_Width = 0
  50.                                         $iLast_Word = 0
  51.                                         For $i = 1 To StringLen($asLines[$j])
  52.                                                 If StringMid($asLines[$j], $i, 1) = " " Then $iLast_Word = $i - 1
  53.                                                 Local $sTest_Line = StringMid($asLines[$j], 1, $i)
  54.                                                 GUICtrlSetData($hText_Label, $sTest_Line)
  55.                                                 $iSize = StringLen($sTest_Line)
  56.                                                 DllCall("GDI32.dll", "int", "GetTextExtentPoint32", "hwnd", $hDC, "str", $sTest_Line, "int", $iSize, "ptr", DllStructGetPtr($tSize))
  57.                                                 If @error Then _StringSize_Error(3, 5, $hLabel_Handle, $hDC, $hGUI)
  58.                                                 $iLine_Width = DllStructGetData($tSize, "X")
  59.                                                 If $iLine_Width >= $iWidth - Int($iSize / 2) Then ExitLoop
  60.                                         Next
  61.                                         If $i > StringLen($asLines[$j]) Then
  62.                                                 $iWrap_Count += 1
  63.                                                 $avSize_Info[0] &= $sTest_Line & @CRLF
  64.                                                 ExitLoop
  65.                                         Else
  66.                                                 $iWrap_Count += 1
  67.                                                 If $iLast_Word = 0 Then
  68.                                                         _StringSize_Error(4, 0, $hLabel_Handle, $hDC, $hGUI)
  69.                                                 EndIf
  70.                                                 $avSize_Info[0] &= StringLeft($sTest_Line, $iLast_Word) & @CRLF
  71.                                                 $asLines[$j] = StringTrimLeft($asLines[$j], $iLast_Word)
  72.                                                 $asLines[$j] = StringStripWS($asLines[$j], 1)
  73.                                         EndIf
  74.                                 WEnd
  75.                                 $iLine_Count += $iWrap_Count
  76.                                 DllCall("User32.dll", "int", "ReleaseDC", "hwnd", $hLabel_Handle, "hwnd", $hDC)
  77.                                 If @error Then _StringSize_Error(3, 6, $hLabel_Handle, $hDC, $hGUI)
  78.                                 GUICtrlDelete($hText_Label)
  79.                         EndIf
  80.                 Next
  81.                 $avSize_Info[3] = ($iLine_Count * $avSize_Info[1]) + 4
  82.         EndIf
  83.         GUIDelete($hGUI)
  84.         Return $avSize_Info
  85. EndFunc   ;==>_StringSize
  86. Func _StringSize_Error($iError, $iExtended, $hLabel_Handle, $hDC, $hGUI)
  87.         DllCall("User32.dll", "int", "ReleaseDC", "hwnd", $hLabel_Handle, "hwnd", $hDC)
  88.         GUIDelete($hGUI)
  89.         Return SetError($iError, $iExtended, 0)
  90. EndFunc   ;==>_StringSize_Error
  91. Global $iDef_Toast_Font_Size = _Toast_GetDefFont(0)
  92. Global $sDef_Toast_Font_Name = _Toast_GetDefFont(1)
  93. Global $hToast_Handle = 0
  94. Global $hToast_Close_X = 9999
  95. Global $iToast_Move = 0
  96. Global $iToast_Style = 1
  97. Global $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 8)
  98. Global $iToast_Header_BkCol = $aRet[0]
  99. $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 5)
  100. Global $iToast_Header_Col = $aRet[0]
  101. Global $iToast_Message_BkCol = $iToast_Header_Col
  102. Global $iToast_Message_Col = $iToast_Header_BkCol
  103. Global $iToast_Font_Size = $iDef_Toast_Font_Size
  104. Global $sToast_Font_Name = $sDef_Toast_Font_Name
  105. Global $iToast_Timer = 0
  106. Global $iToast_Start = 0
  107. Global $fToast_Close = False
  108. Func _Toast_Set($vJust, $iHdr_BkCol = -1, $iHdr_Col = -1, $iMsg_BkCol = -1, $iMsg_Col = -1, $iFont_Size = -1, $sFont_Name = "")
  109.         Switch $vJust
  110.                 Case Default
  111.                         $iToast_Style = 1
  112.                         $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 8)
  113.                         $iToast_Header_BkCol = $aRet[0]
  114.                         $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 5)
  115.                         $iToast_Header_Col = $aRet[0]
  116.                         $iToast_Message_BkCol = $iToast_Header_Col
  117.                         $iToast_Message_Col = $iToast_Header_BkCol
  118.                         $sToast_Font_Name = $sDef_Toast_Font_Name
  119.                         $iToast_Font_Size = $iDef_Toast_Font_Size
  120.                         Return
  121.                 Case 0, 1, 2, 4, 5, 6
  122.                         $iToast_Style = $vJust
  123.                 Case -1
  124.                 Case Else
  125.                         Return SetError(1, 1, 0)
  126.         EndSwitch
  127.         Switch $iHdr_BkCol
  128.                 Case Default
  129.                         $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 8)
  130.                         $iToast_Header_BkCol = $aRet[0]
  131.                 Case 0 To 0xFFFFFF
  132.                         $iToast_Header_BkCol = Int($iHdr_BkCol)
  133.                 Case -1
  134.                 Case Else
  135.                         Return SetError(1, 2, 0)
  136.         EndSwitch
  137.         Switch $iHdr_Col
  138.                 Case Default
  139.                         $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 5)
  140.                         $iToast_Header_Col = $aRet[0]
  141.                 Case 0 To 0xFFFFFF
  142.                         $iToast_Header_Col = Int($iHdr_Col)
  143.                 Case -1
  144.                 Case Else
  145.                         Return SetError(1, 3, 0)
  146.         EndSwitch
  147.         Switch $iMsg_BkCol
  148.                 Case Default
  149.                         $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 8)
  150.                         $iToast_Message_BkCol = $aRet[0]
  151.                 Case 0 To 0xFFFFFF
  152.                         $iToast_Message_BkCol = Int($iMsg_BkCol)
  153.                 Case -1
  154.                 Case Else
  155.                         Return SetError(1, 4, 0)
  156.         EndSwitch
  157.         Switch $iMsg_Col
  158.                 Case Default
  159.                         $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 8)
  160.                         $iToast_Message_Col = $aRet[0]
  161.                 Case 0 To 0xFFFFFF
  162.                         $iToast_Message_Col = Int($iMsg_Col)
  163.                 Case -1
  164.                 Case Else
  165.                         Return SetError(1, 5, 0)
  166.         EndSwitch
  167.         Switch $iFont_Size
  168.                 Case Default
  169.                         $iToast_Font_Size = $iDef_Toast_Font_Size
  170.                 Case 8 To 72
  171.                         $iToast_Font_Size = Int($iFont_Size)
  172.                 Case -1
  173.                 Case Else
  174.                         Return SetError(1, 6, 0)
  175.         EndSwitch
  176.         Switch $sFont_Name
  177.                 Case Default
  178.                         $sToast_Font_Name = $sDef_Toast_Font_Name
  179.                 Case ""
  180.                 Case Else
  181.                         If IsString($sFont_Name) Then
  182.                                 $sToast_Font_Name = $sFont_Name
  183.                         Else
  184.                                 Return SetError(1, 7, 0)
  185.                         EndIf
  186.         EndSwitch
  187.         Return 1
  188. EndFunc   ;==>_Toast_Set
  189. Func _Toast_Show($sTitle, $sMessage, $iDelay = 0, $fWait = True)
  190.         Local $nOldOpt = Opt('GUIOnEventMode', 0)
  191.         If $hToast_Handle <> 0 Then _Toast_Hide()
  192.         $hToast_Close_X = 9999
  193.         Local $iToast_Width_max = 500
  194.         Local $iToast_Width_min = 150
  195.         Local $aLabel_Pos = _StringSize($sMessage, $iToast_Font_Size, Default, Default, $sToast_Font_Name, $iToast_Width_max - 20)
  196.         $sMessage = $aLabel_Pos[0]
  197.         Local $iLine_Height = $aLabel_Pos[1]
  198.         Local $iLabelwidth = $aLabel_Pos[2]
  199.         Local $iLabelheight = $aLabel_Pos[3]
  200.         Local $iToast_Width = $iLabelwidth + 20
  201.         If $iToast_Width < $iToast_Width_min Then
  202.                 $iToast_Width = $iToast_Width_min
  203.                 $iLabelwidth = $iToast_Width_min - 20
  204.         EndIf
  205.         Local $iTitle_Height = 0
  206.         If $sTitle = "" Then
  207.                 If $iDelay < 0 Then $iTitle_Height = 5
  208.         Else
  209.                 $iTitle_Height = $iLine_Height + 2
  210.                 If $iDelay < 0 Then
  211.                         If $iTitle_Height < 17 Then $iTitle_Height = 17
  212.                 EndIf
  213.         EndIf
  214.         Local $iToast_Height = $iLabelheight + $iTitle_Height + 20
  215.         Local $aToast_Data = _Toast_Locate($iToast_Width, $iToast_Height)
  216.         $hToast_Handle = GUICreate("", $iToast_Width, $iToast_Height, $aToast_Data[0], $aToast_Data[1], 0x80880000, BitOR(0x00000080, 0x00000008))
  217.         If @error Then
  218.                 $nOldOpt = Opt('GUIOnEventMode', $nOldOpt)
  219.                 Return SetError(1, 0, -1)
  220.         EndIf
  221.         GUISetFont($iToast_Font_Size, Default, Default, $sToast_Font_Name)
  222.         GUISetBkColor($iToast_Message_BkCol)
  223.         Local $iLabel_Style = 0
  224.         If BitAND($iToast_Style, 1) = 1 Then
  225.                 $iLabel_Style = 1
  226.         ElseIf BitAND($iToast_Style, 2) = 2 Then
  227.                 $iLabel_Style = 2
  228.         EndIf
  229.         If $sTitle <> "" Then
  230.                 GUICtrlCreateLabel("", 0, 0, $iToast_Width, $iTitle_Height)
  231.                 GUICtrlSetBkColor(-1, $iToast_Header_BkCol)
  232.                 GUICtrlSetState(-1, 128)
  233.                 Local $iTitle_Width = $iToast_Width - 10
  234.                 If $iDelay < 0 Then
  235.                         Local $iX_YCoord = Int(($iTitle_Height - 17) / 2)
  236.                         $hToast_Close_X = GUICtrlCreateLabel("T", $iToast_Width - 18, $iX_YCoord, 17, 17)
  237.                         GUICtrlSetFont(-1, 14, Default, Default, "Wingdings 2")
  238.                         GUICtrlSetBkColor(-1, -2)
  239.                         GUICtrlSetColor(-1, $iToast_Header_Col)
  240.                         $iTitle_Width -= 18
  241.                 EndIf
  242.                 GUICtrlCreateLabel($sTitle, 10, 0, $iTitle_Width, $iTitle_Height, 0x0200)
  243.                 GUICtrlSetBkColor(-1, $iToast_Header_BkCol)
  244.                 GUICtrlSetColor(-1, $iToast_Header_Col)
  245.                 If BitAND($iToast_Style, 4) = 4 Then GUICtrlSetFont(-1, $iToast_Font_Size, 600)
  246.         Else
  247.                 If $iDelay < 0 Then
  248.                         $hToast_Close_X = GUICtrlCreateLabel("T", $iToast_Width - 18, 0, 17, 17)
  249.                         GUICtrlSetFont(-1, 14, Default, Default, "Wingdings 2")
  250.                         GUICtrlSetBkColor(-1, -2)
  251.                         GUICtrlSetColor(-1, $iToast_Message_Col)
  252.                 EndIf
  253.         EndIf
  254.         GUICtrlCreateLabel($sMessage, 10, 10 + $iTitle_Height, $iLabelwidth, $iLabelheight)
  255.         GUICtrlSetStyle(-1, $iLabel_Style)
  256.         If $iToast_Message_Col <> Default Then GUICtrlSetColor(-1, $iToast_Message_Col)
  257.         DllCall("user32.dll", "int", "AnimateWindow", "hwnd", $hToast_Handle, "int", 1000, "long", $aToast_Data[2])
  258.         GUISetState(@SW_SHOWNOACTIVATE, $hToast_Handle)
  259.         If $fWait = True Then
  260.                 Local $iTimeout_Begin = TimerInit()
  261.                 While 1
  262.                         If GUIGetMsg() = $hToast_Close_X Or TimerDiff($iTimeout_Begin) / 1000 >= Abs($iDelay) Then ExitLoop
  263.                 WEnd
  264.         ElseIf Abs($iDelay) > 0 Then
  265.                 $iToast_Timer = Abs($iDelay * 1000)
  266.                 $iToast_Start = TimerInit()
  267.                 AdlibRegister("_Toast_Timer_Check", 100)
  268.                 GUIRegisterMsg(0x0021, "_Toast_WM_EVENTS")
  269.         EndIf
  270.         $nOldOpt = Opt('GUIOnEventMode', $nOldOpt)
  271.         Local $aToast_Data[3] = [$iToast_Width, $iToast_Height, $iLine_Height]
  272.         Return $aToast_Data
  273. EndFunc   ;==>_Toast_Show
  274. Func _Toast_Hide()
  275.         If $hToast_Handle = 0 Then Return SetError(1, 0, -1)
  276.         DllCall("user32.dll", "int", "AnimateWindow", "hwnd", $hToast_Handle, "int", 500, "long", $iToast_Move)
  277.         GUIDelete($hToast_Handle)
  278.         $hToast_Handle = 0
  279. EndFunc   ;==>_Toast_Hide
  280. Func _Toast_Locate($iToast_Width, $iToast_Height)
  281.         Local $aToast_Data[3]
  282.         Local $iPrevMode = Opt("WinTitleMatchMode", 4)
  283.         Local $aTray_Pos = WinGetPos("[CLASS:Shell_TrayWnd]")
  284.         Opt("WinTitleMatchMode", $iPrevMode)
  285.         If Not IsArray($aTray_Pos) Then Return SetError(2, 0, -1)
  286.         If $aTray_Pos[1] > 0 Then
  287.                 $iToast_Move = 0x00050004
  288.                 $aToast_Data[0] = @DesktopWidth - $iToast_Width - 10
  289.                 $aToast_Data[1] = $aTray_Pos[1] - $iToast_Height
  290.                 $aToast_Data[2] = 0x00040008
  291.         ElseIf $aTray_Pos[0] > 0 Then
  292.                 $iToast_Move = 0x00050001
  293.                 $aToast_Data[0] = $aTray_Pos[0] - $iToast_Width
  294.                 $aToast_Data[1] = @DesktopHeight - $iToast_Height - 10
  295.                 $aToast_Data[2] = 0x00040002
  296.         ElseIf $aTray_Pos[2] = @DesktopWidth Then
  297.                 $iToast_Move = 0x00050008
  298.                 $aToast_Data[0] = @DesktopWidth - $iToast_Width - 10
  299.                 $aToast_Data[1] = $aTray_Pos[1] + $aTray_Pos[3]
  300.                 $aToast_Data[2] = 0x00040004
  301.         ElseIf $aTray_Pos[3] = @DesktopHeight Then
  302.                 $iToast_Move = 0x00050002
  303.                 $aToast_Data[0] = $aTray_Pos[0] + $aTray_Pos[2]
  304.                 $aToast_Data[1] = @DesktopHeight - $iToast_Height - 10
  305.                 $aToast_Data[2] = 0x00040001
  306.         EndIf
  307.         Return $aToast_Data
  308. EndFunc   ;==>_Toast_Locate
  309. Func _Toast_Timer_Check()
  310.         If TimerDiff($iToast_Start) < $iToast_Timer And $fToast_Close = False Then Return
  311.         GUIRegisterMsg(0x0021, "")
  312.         AdlibUnRegister("_Toast_Timer_Check")
  313.         $fToast_Close = False
  314.         _Toast_Hide()
  315. EndFunc   ;==>_Toast_Timer_Check
  316. Func _Toast_WM_EVENTS($hWnd, $Msg, $wParam, $lParam)
  317.         #forceref $wParam, $lParam
  318.         If $hWnd = $hToast_Handle Then
  319.                 If $Msg = 0x0021 Then
  320.                         Local $aPos = GUIGetCursorInfo($hToast_Handle)
  321.                         If $aPos[4] = $hToast_Close_X Then $fToast_Close = True
  322.                 EndIf
  323.         EndIf
  324.         Return 'GUI_RUNDEFMSG'
  325. EndFunc   ;==>_Toast_WM_EVENTS
  326. Func _Toast_GetDefFont($iData)
  327.         Local $tNONCLIENTMETRICS = DllStructCreate("uint;int;int;int;int;int;byte[60];int;int;byte[60];int;int;byte[60];byte[60];byte[60]")
  328.         DllStructSetData($tNONCLIENTMETRICS, 1, DllStructGetSize($tNONCLIENTMETRICS))
  329.         DllCall("user32.dll", "int", "SystemParametersInfo", "int", 41, "int", DllStructGetSize($tNONCLIENTMETRICS), "ptr", DllStructGetPtr($tNONCLIENTMETRICS), "int", 0)
  330.         Local $tLOGFONT = DllStructCreate("long;long;long;long;long;byte;byte;byte;byte;byte;byte;byte;byte;char[32]", DllStructGetPtr($tNONCLIENTMETRICS, 15))
  331.         Switch $iData
  332.                 Case 0
  333.                         Return Int((Abs(DllStructGetData($tLOGFONT, 1)) + 1) * .75)
  334.                 Case 1
  335.                         Return DllStructGetData($tLOGFONT, 14)
  336.         EndSwitch
  337. EndFunc   ;==>_Toast_GetDefFont
  338. Local $sMsg, $hProgress, $aRet[3]
  339. $sMsg = "The message text goes in this area" & @CRLF & @CRLF
  340. $sMsg &= "This Toast uses the System colours and font"
  341. $aRet = _Toast_Show("The Title text goes here", $sMsg, 5)
  342. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & " - " & "Line height: " & $aRet[2] & @CRLF)
  343. _Toast_Hide()
  344. $sMsg = "This Toast uses colours and font defined in a _Toast_Set call." & @CRLF & @CRLF
  345. $sMsg &= "Subsequent Toasts will use these values until they are reset by another _Toast_Set call" & @CRLF & @CRLF
  346. $sMsg &= "The next Toast has a very small message to show the pre-set minimum size"
  347. _Toast_Set(5, 0xFF00FF, 0xFFFF00, 0x0000FF, 0xFFFFFF, 10, "Arial")
  348. $aRet = _Toast_Show("User-defined Colours and Bold Header", $sMsg, 10)
  349. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & " - " & "Line height: " & $aRet[2] & @CRLF)
  350. _Toast_Hide()
  351. $aRet = _Toast_Show("", "Tiny", 2)
  352. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & " - " & "Line height: " & $aRet[2] & @CRLF)
  353. _Toast_Hide()
  354. $sMsg = "These lines are of medium length" & @CRLF & @CRLF
  355. $sMsg &= "The width is set by the longest" & @CRLF & @CRLF
  356. $sMsg &= "No wrapping occurs here" & @CRLF & @CRLF
  357. $sMsg &= "Note increased font size"
  358. _Toast_Set(-1, -1, -1, -1, -1, 15)
  359. $aRet = _Toast_Show("Mid Width", $sMsg, 5)
  360. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & " - " & "Line height: " & $aRet[2] & @CRLF)
  361. _Toast_Hide()
  362. $sMsg = "This is a long message set to left justified and a much larger font using _Toast_Set" & @CRLF & @CRLF
  363. $sMsg &= "The Toast is automatically set to the maximum preset width and the message text "
  364. $sMsg &= "is wrapped as necessary to fit within the margins of the Toast" & @CRLF & @CRLF
  365. $sMsg &= "The Toast colours and weight have been changed by another _Toast_Set call" & @CRLF & @CRLF
  366. $sMsg &= "Note the closure [X] on the title bar.  This Toast will time out in 30 secs "
  367. $sMsg &= "but clicking the [X] will resume the script immediately"
  368. _Toast_Set(0, -1, 0xFFFF00, 0x00FF00, 0x000000, 15, "Courier New")
  369. $aRet = _Toast_Show("Max Width and Normal Header", $sMsg, -30)
  370. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & " - " & "Line height: " & $aRet[2] & @CRLF)
  371. _Toast_Hide()
  372. $sMsg = "Note how Toasts adjust automatically in height to display all of the message "
  373. $sMsg &= "regardless of whether there is a title bar to display, the font used, "
  374. $sMsg &= "the number of lines or whether wrapping occurs" & @CRLF & @CRLF
  375. $sMsg &= "This Toast will retract automatically when the next Toast is called "
  376. $sMsg &= "or when the [X] is clicked"
  377. _Toast_Set(5, 0xFF00FF, 0xFFFF00, 0x0000FF, 0xFFFFFF, 10, "Arial")
  378. $aRet = _Toast_Show("", $sMsg, -10)
  379. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & " - " & "Line height: " & $aRet[2] & @CRLF)
  380. $sMsg = "This Toast has several blank lines inserted. "
  381. $sMsg &= "This can be useful if you want to leave space to add other controls, "
  382. $sMsg &= "such as a progress bar, to the Toast once it is displayed" & @CRLF & @CRLF & @CRLF & @CRLF
  383. $sMsg &= "The Toast size and line height are returned by the function so you can easily calculate "
  384. $sMsg &= "where to place the other controls.  "
  385. $sMsg &= "This example script writes the size in the SciTE console" & @CRLF & @CRLF
  386. $sMsg &= "Note that Toast colours and font have been reset to Default"
  387. _Toast_Set(Default)
  388. $aRet = _Toast_Show("Progress Bar", $sMsg, 0)
  389. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & " - " & "Line height: " & $aRet[2] & @CRLF)
  390. $hProgress = GUICtrlCreateProgress(10, $aRet[2] * 5.5, $aRet[0] - 20, 20)
  391. For $i = 1 To 100
  392.         GUICtrlSetData($hProgress, $i)
  393.         Sleep(50)
  394. Next
  395. Sleep(5000)
  396. _Toast_Hide()
  397. $sMsg = "This Toast has the 'Wait' flag set to False. " & @CRLF & @CRLF
  398. $sMsg &= "That means that the script will continue while the Toast is displayed as "
  399. $sMsg &= "as you can see from this counter." & @CRLF & @CRLF & @CRLF
  400. $sMsg &= "Clicking the [X] will retract the Toast immediately but it will "
  401. $sMsg &= "automatically retract after 20 seconds in any event"
  402. _Toast_Set(5, 0xFF00FF, 0xFFFF00, 0x0000FF, 0xFFFFFF, 10)
  403. $aRet = _Toast_Show("Script Continuing", $sMsg, -20, False)
  404. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & " - " & "Line height: " & $aRet[2] & @CRLF)
  405. $hLabel = GUICtrlCreateLabel("", ($aRet[0] - 20) / 2, $aRet[2] * 6, 20, 20)
  406. GUICtrlSetBkColor(-1, -2)
  407. GUICtrlSetColor(-1, 0xFFFF00)
  408. GUICtrlSetFont(-1, 12)
  409. $iCount = 0
  410. Do
  411.         $iCount += 1
  412.         GUICtrlSetData($hLabel, $iCount)
  413.         Sleep(1000)
  414. Until $iCount = 60 Or $hToast_Handle = 0
  415. Exit
复制代码
已汉化部分：
  1. # ************************************* 第一界面 size: 286 x 74 - Line height: 12        160 x 74 - 行高: 12
  2. $sMsg = "信息本文在这个区域" & @CRLF & @CRLF
  3. $sMsg &= "界面使用系统颜色和字型"
  4. $aRet = _Toast_Show("这里是窗口标题", $sMsg, 5)
  5. ConsoleWrite("界面尺寸: " & $aRet[0] & " x " & $aRet[1] & " - " & "行高: " & $aRet[2] & @CRLF)
  6. _Toast_Hide()

  8. # ************************************* 第二界面 size: 500 x 138 - Line height: 16        486 x 122 - 行高: 16
  9. $sMsg = "这个界面是调用 _Toast_Set 定义的颜色和字型." & @CRLF & @CRLF
  10. $sMsg &= "后来界面将使用这些数值，直到调用另外一个 _Toast_Set 重新设定" & @CRLF & @CRLF
  11. $sMsg &= "下一界面有一个非常小的信息表示前固定的最小尺寸"
  12. _Toast_Set(5, 0xFF00FF, 0xFFFF00, 0x0000FF, 0xFFFFFF, 10, "Arial")
  13. $aRet = _Toast_Show("自定义颜色和粗体表头", $sMsg, 10)
  14. ConsoleWrite("界面尺寸: " & $aRet[0] & " x " & $aRet[1] & " - " & "行高: " & $aRet[2] & @CRLF)
  15. _Toast_Hide()

  17. # ************************************* 第三界面 size: 150 x 40 - Line height: 16        150 x 40 - 行高: 16
  18. $aRet = _Toast_Show("", "小界面", 2)
  19. ConsoleWrite("界面尺寸: " & $aRet[0] & " x " & $aRet[1] & " - " & "行高: " & $aRet[2] & @CRLF)
  20. _Toast_Hide()

  22. # ************************************* 第四界面 size: 317 x 210 - Line height: 23        268 x 210 - 行高: 23
  23. $sMsg = "这些行有不同的长度的" & @CRLF & @CRLF
  24. $sMsg &= "宽度按照最长的文本行设定" & @CRLF & @CRLF
  25. $sMsg &= "没有发生环绕" & @CRLF & @CRLF
  26. $sMsg &= "注意增加的字型大小"
  27. _Toast_Set(-1, -1, -1, -1, -1, 15)
  28. $aRet = _Toast_Show("Mid Width", $sMsg, 5)
  29. ConsoleWrite("界面尺寸: " & $aRet[0] & " x " & $aRet[1] & " - " & "行高: " & $aRet[2] & @CRLF)
  30. _Toast_Hide()

  32. # ************************************* 第五界面 size: 500 x 400 - Line height: 22        500 x 224 - 行高: 22
  33. $sMsg = "这是 _Toast_Set 设置的长文本信息，文本使用左对齐和大字体" & @CRLF & @CRLF
  34. $sMsg &= "界面自动设定为预设的最大宽度和消息文本 "
  35. $sMsg &= "是必要的，以适应包装内的界面边缘" & @CRLF & @CRLF
  36. $sMsg &= "调用另一个 _Toast_Set 改变界面的颜色和深浅" & @CRLF & @CRLF
  37. $sMsg &= "请注意在标题栏中的关闭 [X] 符号。这个界面将持续 30 秒时间 "
  38. $sMsg &= "但点击 [X] 脚本将立即继续下面的操作"
  39. _Toast_Set(0, -1, 0xFFFF00, 0x00FF00, 0x000000, 15, "Courier New")
  40. $aRet = _Toast_Show("最大宽度与正常头", $sMsg, -30)
  41. ConsoleWrite("界面尺寸: " & $aRet[0] & " x " & $aRet[1] & " - " & "行高: " & $aRet[2] & @CRLF)
  42. _Toast_Hide()

  44. # ************************************* 第六界面 size: 500 x 125 - Line height: 16        500 x 77 - 行高: 16
  45. $sMsg = "注意界面如何自动调整高度，以显示全部消息 "
  46. $sMsg &= "不论是否有标题栏显示, 使用的字体, "
  47. $sMsg &= "行数或是否出现环绕" & @CRLF & @CRLF
  48. $sMsg &= "当调用下一个界面时，这个界面将自动缩回  "
  49. $sMsg &= "或点击 [X] 按钮时"
  50. _Toast_Set(5, 0xFF00FF, 0xFFFF00, 0x0000FF, 0xFFFFFF, 10, "Arial")
  51. $aRet = _Toast_Show("", $sMsg, -10)
  52. ConsoleWrite("界面尺寸: " & $aRet[0] & " x " & $aRet[1] & " - " & "行高: " & $aRet[2] & @CRLF)

  54. # ************************************* 第七界面 size: 500 x 170 - Line height: 12        500 x 170 - 行高: 12
  55. $sMsg = "这个界面插入了几个空白行. "
  56. $sMsg &= "这是必要的，预留空间以方便你添加一些控件,  "
  57. $sMsg &= "例如一个进度条。 一旦界面显示" & @CRLF & @CRLF & @CRLF & @CRLF
  58. $sMsg &= "由函数返回的界面大小和行的高度， 你就可以很容易地计算出"; & @CRLF
  59. $sMsg &= "在什么地方放置其他控件.  "
  60. $sMsg &= "这个示例脚本将界面尺寸大小写入 SciTE 的控制台" & @CRLF & @CRLF
  61. $sMsg &= "请注意，界面的颜色和字体都被重置为默认值"
  62. _Toast_Set(Default)
  63. $aRet = _Toast_Show("Progress Bar", $sMsg, 0)
  64. ConsoleWrite("界面尺寸: " & $aRet[0] & " x " & $aRet[1] & " - " & "行高: " & $aRet[2] & @CRLF)
  65. $hProgress = GUICtrlCreateProgress(10, $aRet[2] * 5.5, $aRet[0] - 20, 20)
  66. For $i = 1 To 100
  67.         GUICtrlSetData($hProgress, $i)
  68.         Sleep(50)
  69. Next
  70. Sleep(5000)
  71. _Toast_Hide()

  73. # ************************************* 第八界面 size: 500 x 145 - Line height: 13        500 x 119 - 行高: 13
  74. $sMsg = "这个界面的 'Wait' 等待标志参数值被设为 False. " & @CRLF & @CRLF
  75. $sMsg &= "脚本在计时设定的时间内会连续显示这个界面,在计时装置完成之前, "
  76. $sMsg &= "你可以观察到计数装置从 1 增到 20." & @CRLF & @CRLF & @CRLF                  
  77. $sMsg &= "计时装置完成前,单击 [X] 符号按钮，界面将立即关闭 "
  78. $sMsg &= "但无论怎样，20 秒计时完成之后，界面会自动关闭的"
  79. _Toast_Set(5, 0xFF00FF, 0xFFFF00, 0x0000FF, 0xFFFFFF, 12)
  80. $aRet = _Toast_Show("脚本连续显示界面", $sMsg, -20, False)
  81. ConsoleWrite("界面尺寸: " & $aRet[0] & " x " & $aRet[1] & " - " & "行高: " & $aRet[2] & @CRLF)
  82. $hLabel = GUICtrlCreateLabel("", ($aRet[0] - 20) / 2, $aRet[2] * 6, 20, 20)
  83. GUICtrlSetBkColor(-1, -2)
  84. GUICtrlSetColor(-1, 0xFFFF00)
  85. GUICtrlSetFont(-1, 12)
  86. $iCount = 0
  87. Do
  88.         $iCount += 1
  89.         GUICtrlSetData($hLabel, $iCount)
  90.         Sleep(1000)
  91. Until $iCount = 60 Or $hToast_Handle = 0
  92. Exit
复制代码

评分

参与人数 2金钱 +90 贡献 +5 收起 理由
republican + 40
afan + 50 + 5

查看全部评分

回复

举报

afan
发表于 2010-8-12 20:17:12 | 显示全部楼层
很简约，漂亮啊~~
回复

举报

131738
 楼主| 发表于 2010-8-12 20:21:46 | 显示全部楼层
回复 2# afan

能找到汉化异常的原因吗？
回复

举报

afan
发表于 2010-8-12 21:00:10 | 显示全部楼层
回复 3# 131738


    初步认为他没有考虑双字节的情况，造成获取字符串的宽度有问题，继而造成高度的不足。
代码太长了，没时间研究哦…

简单解决方法： 在$sMsg最后补适量的 & @CRLF 即可，如：
========第六界面=========
最后的 $sMsg &= "或点击 [X] 按钮时" & @CRLF

========第八界面=========
最后的 $sMsg &= "但无论怎样，20 秒计时完成之后，界面会自动关闭的" & @CRLF & @CRLF

本帖子中包含更多资源

您需要 登录 才可以下载或查看，没有账号？加入

×
回复

举报

131738
 楼主| 发表于 2010-8-12 21:17:16 | 显示全部楼层
回复 4# afan

谢谢！！！！受教了。。。

另，谢谢加分。。。打扰了。。。。
回复

举报

afan
发表于 2010-8-13 18:20:11 | 显示全部楼层
忘了很重要的一点，字母语言环境和方块文字环境断行的方式是不同的。
字母语言环境会以单词和空格的方式来判断，且Label不会自动调整换行显示，如果强制在范围内显示它会裁剪字符，使部分字符不会显示，因此，此脚本是用的将超出长度的字符串另外组织成另外的行，以保证每行文字都能完整显示。而这样每行的字符串长度相差可能都很大，所以它很多情况下都使用了水平居中显示的样式（8个例子中有7个是如此），以免居左显示时，右边会参差不齐，影响美观。
而方块文字环境则无此困扰，超过水平范围会自动换行，只要Label控件足够高则可完全显示。此脚本是针对字母语言环境的，所以它调整起来非常繁琐，如果按我们的文字习惯会简单很多，当然也就无法满足字母环境了。
回复

举报

afan
发表于 2010-8-13 18:25:57 | 显示全部楼层
回复  afan

其实这个脚本有点意思的， 创建窗口宽度为 1200， 够大的了

但实际并没有显示出这么大的窗口，而是根据字符串的多少，来确定显示窗口的大小，

你的“认为他没有考虑双字节的情况，造成获取字符串的宽度有问题，继而造成高度的不足”判断肯定是正确的

发的代码中，有进度条的窗口我没有汉化，结果汉化后，显示进度条压住了紧随进度条下方的文本，

这就不是添加 @CRLF 能解决的，摸索半天，用空格充足源代码的字节数，这才使进度条不压文本了，

但文本显示就不整齐了，创建进度条，位置参数使用的是变量，且变量又不是常数，我再好好看看它是如何计算的。。。。。

GUICtrlCreateProgress(10, $aRet[2] * 5.5, $aRet[0] - 20, 20)
131738 发表于 2010-8-13 01:09


    在自动生成的界面中再添加控件，比如第七界面的进度条、第八界面的计时Label，其实并无自动的需求，它完全是根据已经规定的$sMsg字符串来定的，并非自动调整，比如原$sMsg英文字符串，你删除下面的行，仅保留两行，同样不会显示进度条。所以，这个是需要自行调整数值的，就像写Gui界面一样。比如我把进度条用在下面，同样可以
  1. #************************************* 第八界面 size: 500 x 145 - Line height: 13        500 x 119 - 行高: 13
  2. $sMsg = "这个界面的 'Wait' 等待标志参数值被设为 False. " & @CRLF & @CRLF
  3. $sMsg &= "脚本在计时设定的时间内会连续显示这个界面,在计时装置完成之前, "
  4. $sMsg &= "你可以观察到计数装置从 1 增到 20." & @CRLF & @CRLF & @CRLF & @CRLF                 
  5. $sMsg &= "计时装置完成前,单击 [X] 符号按钮，界面将立即关闭 "
  6. $sMsg &= "但无论怎样，20 秒计时完成之后，界面会自动关闭的" & @CRLF & @CRLF
  7. _Toast_Set(5, 0xFF00FF, 0xFFFF00, 0x0000FF, 0xFFFFFF, 12)
  8. $aRet = _Toast_Show("脚本连续显示界面", $sMsg, -20, False)
  9. ConsoleWrite("界面尺寸: " & $aRet[0] & " x " & $aRet[1] & " - " & "行高: " & $aRet[2] & @CRLF)
  10. $hLabel = GUICtrlCreateLabel("", ($aRet[0] - 20) / 2, $aRet[2] * 6, 20, 20)
  11. GUICtrlSetBkColor(-1, -2)
  12. GUICtrlSetColor(-1, 0xFFFF00)
  13. GUICtrlSetFont(-1, 12)
  14. $iCount = 0
  15. $hProgress = GUICtrlCreateProgress(10, 135, 480, 20)
  16. Do
  17.         $iCount += 1
  18.         GUICtrlSetData($hLabel, $iCount)
  19.         GUICtrlSetData($hProgress, $iCount / 20 * 100)
  20.         Sleep(1000)
  21. Until $hToast_Handle = 0
  22. Exit
复制代码
回复

举报

afan
发表于 2010-8-13 18:31:53 | 显示全部楼层
修改了半天此脚本，终于要搞定了
回复

举报

131738
 楼主| 发表于 2010-8-13 19:15:58 | 显示全部楼层
修改了半天此脚本，终于要搞定了
afan 发表于 2010-8-13 18:31


等待看你的修改结果，然后对照源码学习你的技巧！！！
回复

举报

131738
 楼主| 发表于 2010-8-14 00:04:40 | 显示全部楼层
本帖最后由 131738 于 2010-8-14 20:09 编辑

回复 8# afan

又搜到一套脚本，是 1 楼脚本的改良，包含文件独立在外，且有参数描述发布于今年7月初：

http://www.autoitscript.com/foru ... =1&#entry764115

作者曾经帮助过这里写电脑硬件测温工具的那位网友

包含文件：Toast.au3
  1. #include-once

  3. ; #INDEX# ============================================================================================================
  4. ; Title .........: Toast
  5. ; AutoIt Version : 3.3.2.0 - uses AdlibRegister/Unregister
  6. ; Language ......: English
  7. ; Description ...: Show and hides slice messages from the systray in user defined colours and fonts
  8. ; Author(s) .....: Melba23.  Credit to GioVit (tray location)
  9. ; ====================================================================================================================

  11. ;#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6

  13. ; #INCLUDES# =========================================================================================================
  14. #include "StringSize.au3"

  16. ; #GLOBAL VARIABLES# =================================================================================================
  17. Global $iDef_Toast_Font_Size   = _Toast_GetDefFont(0)
  18. Global $sDef_Toast_Font_Name   = _Toast_GetDefFont(1)

  20. Global $hToast_Handle        = 0
  21. Global $hToast_Close_X       = 9999
  22. Global $iToast_Move          = 0
  23. Global $iToast_Style         = 1 ; $SS_CENTER
  24. Global $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 8) ; $COLOR_WINDOWTEXT = 8
  25. Global $iToast_Header_BkCol  = $aRet[0]
  26. $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 5) ; $COLOR_WINDOW = 5
  27. Global $iToast_Header_Col    = $aRet[0]
  28. Global $iToast_Header_Bold   = 0
  29. Global $iToast_Message_BkCol = $iToast_Header_Col
  30. Global $iToast_Message_Col   = $iToast_Header_BkCol
  31. Global $iToast_Font_Size     = $iDef_Toast_Font_Size
  32. Global $sToast_Font_Name     = $sDef_Toast_Font_Name
  33. Global $iToast_Timer         = 0
  34. Global $iToast_Start         = 0
  35. Global $fToast_Close         = False

  37. ; #CURRENT# ==========================================================================================================
  38. ; _Toast_Set:  Sets text justification and optionally colours and font, for _Toast_Show function calls
  39. ; _Toast_Show: Shows a slice message from the systray
  40. ; _Toast_Hide: Hides a slice message from the systray
  41. ; ====================================================================================================================

  43. ; #INTERNAL_USE_ONLY#=================================================================================================
  44. ; _Toast_Locate:        Find Systray and determine Toast start position and movement direction
  45. ; _Toast_Timer_Check:   Checks whether Toast has timed out or closure [X] clicked
  46. ; _Toast_WM_EVENTS:     Message handler to check if closure [X] clicked
  47. ; _Toast_GetDefFont: Determine system default MsgBox font and size
  48. ; ====================================================================================================================

  50. ; #FUNCTION# =========================================================================================================
  51. ; Name...........: _Toast_Set
  52. ; Description ...: Sets text justification and optionally colours and font, for _Toast_Show function calls
  53. ; Syntax.........: _Toast_Set($vJust, [$iHdr_BkCol, [$iHdr_Col, [$iMsg_BkCol, [$iMsg_Col, [$sFont_Size, [$iFont_Name]]]]]])
  54. ; Parameters ....: $vJust     - 0 = Left justified, 1 = Centred (Default), 2 = Right justified
  55. ;                                Can use $SS_LEFT, $SS_CENTER, $SS_RIGHT
  56. ;                                + 4 = Header text in bold
  57. ;                       >>>>>    Setting this parameter to' Default' will reset ALL parameters to default values     <<<<<
  58. ;                       >>>>>    All optional parameters default to system MsgBox default values                     <<<<<
  59. ;                  $iHdr_BkCol - [Optional] The colour for the title bar background
  60. ;                  $iHdr_Col   - [Optional] The colour for the title bar text
  61. ;                  $iMsg_BkCol - [Optional] The colour for the message background
  62. ;                  $iMsg_Col   - [Optional] The colour for the message text
  63. ;                                Omitting a colour parameter or setting it to -1 leaves it unchanged
  64. ;                                Setting a colour parameter to Default resets the system colour
  65. ;                  $iFont_Size - [Optional] The font size in points to use for the Toast
  66. ;                  $sFont_Name - [Optional] The font to use for the Toast
  67. ;                       >>>>>    Omitting a font parameter, setting size to -1 or name to "" leaves it unchanged     <<<<<
  68. ;                       >>>>>    Setting a font parameter to Default resets the system message box font or size      <<<<<
  69. ; Requirement(s).: v3.3.2.0 or higher - AdlibRegister/Unregister used in _Toast_Show
  70. ; Return values .: Success - Returns 1
  71. ;                  Failure - Returns 0 and sets @error to 1 with @extended set to parameter index number
  72. ; Author ........: Melba23
  73. ; Example........; Yes
  74. ;=====================================================================================================================

  76. Func _Toast_Set($vJust, $iHdr_BkCol = -1, $iHdr_Col = -1, $iMsg_BkCol = -1, $iMsg_Col = -1, $iFont_Size = -1, $sFont_Name = "")

  78.         ; Set parameters
  79.         Switch $vJust
  80.                 Case Default
  81.                         $iToast_Style         = 1; $SS_CENTER
  82.                         $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 8) ; $COLOR_WINDOWTEXT = 8
  83.                         $iToast_Header_BkCol  = $aRet[0]
  84.                         $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 5) ; $COLOR_WINDOW = 5
  85.                         $iToast_Header_Col    = $aRet[0]
  86.                         $iToast_Message_BkCol = $iToast_Header_Col
  87.                         $iToast_Message_Col   = $iToast_Header_BkCol
  88.                         $sToast_Font_Name     = $sDef_Toast_Font_Name
  89.                         $iToast_Font_Size     = $iDef_Toast_Font_Size
  90.                         Return
  91.                 Case 0, 1, 2, 4, 5, 6
  92.                         $iToast_Style = $vJust
  93.                 Case -1
  94.                         ; Do nothing
  95.                 Case Else
  96.                         Return SetError(1, 1, 0)
  97.         EndSwitch

  99.         Switch $iHdr_BkCol
  100.                 Case Default
  101.                         $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 8) ; $COLOR_WINDOWTEXT = 8
  102.                         $iToast_Header_BkCol  = $aRet[0]
  103.                 Case 0 To 0xFFFFFF
  104.                         $iToast_Header_BkCol = Int($iHdr_BkCol)
  105.         Case -1
  106.                         ; Do nothing
  107.                 Case Else
  108.                         Return SetError(1, 2, 0)
  109.         EndSwitch

  111.         Switch $iHdr_Col
  112.                 Case Default
  113.                         $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 5) ; $COLOR_WINDOW = 5
  114.                         $iToast_Header_Col  = $aRet[0]
  115.                 Case 0 To 0xFFFFFF
  116.                         $iToast_Header_Col = Int($iHdr_Col)
  117.         Case -1
  118.                         ; Do nothing
  119.                 Case Else
  120.                         Return SetError(1, 3, 0)
  121.         EndSwitch

  123.         Switch $iMsg_BkCol
  124.                 Case Default
  125.                         $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 8) ; $COLOR_WINDOWTEXT = 8
  126.                         $iToast_Message_BkCol  = $aRet[0]
  127.                 Case 0 To 0xFFFFFF
  128.                         $iToast_Message_BkCol = Int($iMsg_BkCol)
  129.         Case -1
  130.                         ; Do nothing
  131.                 Case Else
  132.                         Return SetError(1, 4, 0)
  133.         EndSwitch

  135.         Switch $iMsg_Col
  136.                 Case Default
  137.                         $aRet = DllCall("User32.dll", "int", "GetSysColor", "int", 8) ; $COLOR_WINDOWTEXT = 8
  138.                         $iToast_Message_Col  = $aRet[0]
  139.                 Case 0 To 0xFFFFFF
  140.                         $iToast_Message_Col = Int($iMsg_Col)
  141.         Case -1
  142.                         ; Do nothing
  143.                 Case Else
  144.                         Return SetError(1, 5, 0)
  145.         EndSwitch

  147.         Switch $iFont_Size
  148.                 Case Default
  149.                         $iToast_Font_Size = $iDef_Toast_Font_Size
  150.                 Case 8 To 72
  151.                         $iToast_Font_Size = Int($iFont_Size)
  152.         Case -1
  153.                         ; Do nothing
  154.                 Case Else
  155.                         Return SetError(1, 6, 0)
  156.         EndSwitch

  158.         Switch $sFont_Name
  159.                 Case Default
  160.                         $sToast_Font_Name = $sDef_Toast_Font_Name
  161.                 Case ""
  162.                         ; Do nothing
  163.                 Case Else
  164.                         If IsString($sFont_Name) Then
  165.                                 $sToast_Font_Name = $sFont_Name
  166.                         Else
  167.                                 Return SetError(1, 7, 0)
  168.                         EndIf
  169.         EndSwitch

  171.         Return 1

  173. EndFunc ; => _Toast_Set

  175. ; #FUNCTION# =========================================================================================================
  176. ; Name...........: _Toast_Show
  177. ; Description ...: Shows a slice message from the systray
  178. ; Syntax.........: _Toast_Show($vIcon, $sTitle, $sMessage, [$iDelay [, $fWait [, $fRaw]]])
  179. ; Parameters ....: $vIcon    - 0 - No icon, 8 - UAC, 16 - Stop, 32 - Query, 48 - Exclamation, 64 - Information
  180. ;                              The $MB_ICON constant can also be used for the last 4 above
  181. ;                              If set to the name of an exe, the main icon of that exe will be displayed
  182. ;                              Any other value returns -1, error 1
  183. ;                  $sTitle   - Text to display on Title bar
  184. ;                  $sMessage - Text to display in Toast body
  185. ;                  $iDelay   - The delay in seconds before the Toast retracts or script continues (Default = 0)
  186. ;                              If negative, an [X] is added to the title bar. Clicking [X] retracts/continues immediately
  187. ;                  $fWait    - True  - Script waits for delay time before continuing and Toast remains visible
  188. ;                              False - Script continues and Toast retracts automatically after delay time
  189. ;                  $fRaw     - True  - Message is not wrapped and Toast expands to show full width
  190. ;                            - False - Message is wrapped if over max preset Toast width
  191. ; Requirement(s).: v3.3.1.5 or higher - AdlibRegister/Unregister used in _Toast_Show
  192. ; Return values .: Success: Returns 2-element array: [Toast width, Toast height]
  193. ;                  Failure:        Returns -1 and sets @error as follows:
  194. ;                           1 = Toast GUI creation failed
  195. ;                           2 = Taskbar not found
  196. ;                           4 = When using Raw, the Toast is too wide for the display
  197. ;                           3 = StringSize error
  198. ; Author ........: Melba23, based on some original code by GioVit for the Toast
  199. ; Notes .........; Any visible Toast is retracted by a subsequent _Toast_Hide or _Toast_Show, or clicking a visible [X]
  200. ; Example........; Yes
  201. ;=====================================================================================================================

  203. Func _Toast_Show($vIcon, $sTitle, $sMessage, $iDelay = 0, $fWait = True, $fRaw = False)

  205.         ; Store current GUI mode and set Message mode
  206.         Local $nOldOpt = Opt('GUIOnEventMode', 0)

  208.         ; Retract any Toast already in place
  209.         If $hToast_Handle <> 0 Then _Toast_Hide()

  211.         ; Reset non-reacting Close [X] ControlID
  212.         $hToast_Close_X = 9999

  214.         ; Set default auto-sizing Toast widths
  215.         Local $iToast_Width_max = 500
  216.         Local $iToast_Width_min = 150

  218.         ; Check for icon
  219.         Local $iIcon_Style = 0
  220.         Local $iIcon_Reduction = 50
  221.         Local $sDLL = "user32.dll"
  222.         If StringIsDigit($vIcon) Then
  223.                 Switch $vIcon
  224.                         Case 0
  225.                                 $iIcon_Reduction = 0
  226.                         Case 8
  227.                                 $sDLL = "imageres.dll"
  228.                                 $iIcon_Style = 78
  229.                         Case 16 ; Stop
  230.                                 $iIcon_Style = -4
  231.                         Case 32 ; Query
  232.                                 $iIcon_Style = -3
  233.                         Case 48 ; Exclam
  234.                                 $iIcon_Style = -2
  235.                         Case 64 ; Info
  236.                                 $iIcon_Style = -5
  237.                         Case Else
  238.                                 $nOldOpt = Opt('GUIOnEventMode', $nOldOpt)
  239.                                 Return SetError(1, 0, -1)
  240.                 EndSwitch
  241.         Else
  242.                 $sDLL = $vIcon
  243.                 $iIcon_Style = 0
  244.         EndIf

  246.         ; Determine max message width
  247.         Local $iMax_Label_Width = $iToast_Width_max - 20 - $iIcon_Reduction
  248.         If $fRaw = True Then $iMax_Label_Width = 0

  250.         ; Get message label size
  251.         Local $aLabel_Pos = _StringSize($sMessage, $iToast_Font_Size, Default, Default, $sToast_Font_Name, $iMax_Label_Width)
  252.         If @error Then
  253.                 $nOldOpt = Opt('GUIOnEventMode', $nOldOpt)
  254.                 Return SetError(3, 0, -1)
  255.         EndIf

  257.         ; Reset text to match rectangle
  258.         $sMessage = $aLabel_Pos[0]

  260.         ;Set line height for this font
  261.         Local $iLine_Height = $aLabel_Pos[1]

  263.         ; Set label size
  264.         Local $iLabelwidth  = $aLabel_Pos[2]
  265.         Local $iLabelheight = $aLabel_Pos[3]

  267.         ; Set Toast size
  268.         Local $iToast_Width = $iLabelwidth + 20 + $iIcon_Reduction
  269.         ; Check if Toast will fit on screen
  270.         If $iToast_Width > @DesktopWidth - 20 Then
  271.                 $nOldOpt = Opt('GUIOnEventMode', $nOldOpt)
  272.                 Return SetError(4, 0, -1)
  273.         EndIf
  274.         ; Increase if below min size
  275.         If $iToast_Width < $iToast_Width_min + $iIcon_Reduction Then
  276.                 $iToast_Width = $iToast_Width_min + $iIcon_Reduction
  277.                 $iLabelwidth  = $iToast_Width_min - 20
  278.         EndIf

  280.         ; Set title bar height - with minimum for [X]
  281.         Local $iTitle_Height = 0
  282.         If $sTitle = "" Then
  283.                 If $iDelay < 0 Then $iTitle_Height = 6
  284.         Else
  285.                 $iTitle_Height = $iLine_Height + 2
  286.                 If $iDelay < 0 Then
  287.                         If $iTitle_Height < 17 Then $iTitle_Height = 17
  288.                 EndIf
  289.         EndIf

  291.         ; Set Toast height as label height + title bar + bottom margin
  292.         Local $iToast_Height = $iLabelheight + $iTitle_Height + 20
  293.         ; Ensure enough room for icon if displayed
  294.         If $iIcon_Reduction Then
  295.                 If $iToast_Height < $iTitle_Height + 42 Then $iToast_Height = $iTitle_Height + 47
  296.         EndIf

  298.         ; Get Toast starting position and direction
  299.         Local $aToast_Data = _Toast_Locate($iToast_Width, $iToast_Height)

  301.         ; Create Toast slice with $WS_POPUPWINDOW, $WS_EX_TOOLWINDOW style and $WS_EX_TOPMOST extended style
  302.         $hToast_Handle = GUICreate("", $iToast_Width, $iToast_Height, $aToast_Data[0], $aToast_Data[1], 0x80880000, BitOr(0x00000080, 0x00000008))
  303.         If @error Then
  304.                 $nOldOpt = Opt('GUIOnEventMode', $nOldOpt)
  305.                 Return SetError(1, 0, -1)
  306.         EndIf
  307.                 GUISetFont($iToast_Font_Size, Default, Default, $sToast_Font_Name)
  308.                 GUISetBkColor($iToast_Message_BkCol)

  310.         ; Set centring parameter
  311.         Local $iLabel_Style = 0 ; $SS_LEFT
  312.         If BitAND($iToast_Style, 1) = 1 Then
  313.                 $iLabel_Style = 1 ; $SS_CENTER
  314.         ElseIf BitAND($iToast_Style, 2) = 2 Then
  315.                 $iLabel_Style = 2 ; $SS_RIGHT
  316.         EndIf

  318.         ; Check installed fonts
  319.         Local $sX_Font = "WingDings"
  320.         Local $sX_Char = "x"
  321.         Local $i = 1
  322.         While 1
  323.                 Local $sInstalled_Font = RegEnumVal("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts", $i)
  324.                 If @error Then ExitLoop
  325.                 If StringInStr($sInstalled_Font, "WingDings 2") Then
  326.                         $sX_Font = "WingDings 2"
  327.                         $sX_Char = "T"
  328.                 EndIf
  329.                 $i += 1
  330.         WEnd

  332.         ; Create title bar if required
  333.         If $sTitle <> "" Then

  335.                 ; Create disabled background strip
  336.                 GUICtrlCreateLabel("", 0, 0, $iToast_Width, $iTitle_Height)
  337.                         GUICtrlSetBkColor(-1, $iToast_Header_BkCol)
  338.                         GUICtrlSetState(-1, 128) ; $GUI_DISABLE

  340.                 ; Set title bar width to offset text
  341.                 Local $iTitle_Width = $iToast_Width - 10

  343.                 ; Create closure [X] if needed
  344.                 If $iDelay < 0 Then
  345.                         ; Create [X]
  346.                         Local $iX_YCoord = Int(($iTitle_Height - 17) / 2)
  347.                         $hToast_Close_X = GUICtrlCreateLabel($sX_Char, $iToast_Width - 18, $iX_YCoord, 17, 17)
  348.                                 GUICtrlSetFont(-1, 14, Default, Default, $sX_Font)
  349.                                 GUICtrlSetBkColor(-1, -2) ; $GUI_BKCOLOR_TRANSPARENT
  350.                                 GUICtrlSetColor(-1, $iToast_Header_Col)
  351.                         ; Reduce title bar width to allow [X] to activate
  352.                         $iTitle_Width -= 18
  353.                 EndIf

  355.                 ; Create Title label with bold text, centred vertically in case bar is higher than line
  356.                 GUICtrlCreateLabel($sTitle, 10, 0, $iTitle_Width, $iTitle_Height, 0x0200) ; $SS_CENTERIMAGE
  357.                         GUICtrlSetBkColor(-1,$iToast_Header_BkCol)
  358.                         GUICtrlSetColor(-1, $iToast_Header_Col)
  359.                         If BitAND($iToast_Style, 4) = 4 Then GUICtrlSetFont(-1, $iToast_Font_Size, 600)

  361.         Else

  363.                 If $iDelay < 0 Then
  364.                         ; Only need [X]
  365.                         $hToast_Close_X = GUICtrlCreateLabel($sX_Char, $iToast_Width - 18, 0, 17, 17)
  366.                                 GUICtrlSetFont(-1, 14, Default, Default, $sX_Font)
  367.                                 GUICtrlSetBkColor(-1, -2) ; $GUI_BKCOLOR_TRANSPARENT
  368.                                 GUICtrlSetColor(-1, $iToast_Message_Col)
  369.                 EndIf

  371.         EndIf

  373.         ; Create icon
  374.         If $iIcon_Reduction Then GUICtrlCreateIcon($sDLL, $iIcon_Style, 10, 10 + $iTitle_Height)

  376.         ; Create Message label
  377.         GUICtrlCreateLabel($sMessage, 10 + $iIcon_Reduction, 10 + $iTitle_Height, $iLabelwidth, $iLabelheight)
  378.                 GUICtrlSetStyle(-1, $iLabel_Style)
  379.                 If $iToast_Message_Col <> Default Then GUICtrlSetColor(-1, $iToast_Message_Col)

  381.         ; Slide Toast Slice into view from behind systray and activate
  382.         DllCall("user32.dll", "int", "AnimateWindow", "hwnd", $hToast_Handle, "int", 1000, "long", $aToast_Data[2])

  384.         ; Activate Toast without stealing focus
  385.         GUISetState(@SW_SHOWNOACTIVATE, $hToast_Handle)

  387.         ; If script is to pause
  388.         If $fWait = True Then

  390.                 ; Begin timeout counter
  391.                 Local $iTimeout_Begin = TimerInit()

  393.                 ; Wait for timeout or closure
  394.                 While 1
  395.                         If GUIGetMsg() = $hToast_Close_X Or TimerDiff($iTimeout_Begin) / 1000 >= Abs($iDelay) Then ExitLoop
  396.                 WEnd

  398.         ; If script is to continue and delay has been set
  399.         ElseIf Abs($iDelay) > 0 Then

  401.                 ; Store timer info
  402.                 $iToast_Timer = Abs($iDelay * 1000)
  403.                 $iToast_Start = TimerInit()

  405.                 ; Register Adlib function to run timer
  406.                 AdlibRegister("_Toast_Timer_Check", 100)
  407.                 ; Register message handler to check for [X] click
  408.                 GUIRegisterMsg(0x0021, "_Toast_WM_EVENTS") ; $WM_MOUSEACTIVATE

  410.         EndIf

  412.         ; Reset original mode
  413.         $nOldOpt = Opt('GUIOnEventMode', $nOldOpt)

  415.         ; Create array to return Toast dimensions
  416.         Local $aToast_Data[3] = [$iToast_Width, $iToast_Height, $iLine_Height]

  418.         Return $aToast_Data

  420. EndFunc ; => _Toast_Show

  422. ; #FUNCTION# ========================================================================================================
  423. ; Name...........: _Toast_Hide
  424. ; Description ...: Hides a slice message from the systray
  425. ; Syntax.........: _Toast_Hide()
  426. ; Requirement(s).: v3.3.1.5 or higher - AdlibRegister used in _Toast_Show
  427. ; Return values .: Success: Returns 0
  428. ;                  Failure:        If Toast does not exist returns -1 and sets @error to 1
  429. ; Author ........: Melba23
  430. ; Example........; Yes
  431. ;=====================================================================================================================

  433. Func _Toast_Hide()

  435.         ; If no Toast to hide, return
  436.         If $hToast_Handle = 0 Then Return SetError(1, 0, -1)

  438.         ; Slide Toast back behind systray
  439.         DllCall("user32.dll", "int", "AnimateWindow", "hwnd", $hToast_Handle, "int", 500, "long", $iToast_Move)

  441.         ; Delete Toast slice
  442.         GUIDelete($hToast_Handle)

  444.         ; Set flag for "no Toast"
  445.         $hToast_Handle = 0

  447. EndFunc ; => _Toast_Hide

  449. ; #INTERNAL_USE_ONLY#============================================================================================================
  450. ; Name...........: _Toast_Locate
  451. ; Description ...: Find Systray and determine Toast start position and movement direction
  452. ; Syntax ........: _Toast_Locate($iToast_Width, $iToast_Height)
  453. ; Parameters ....: $iToast_Width  - required width of slice
  454. ;                  $iToast_Height - required height of slice
  455. ; Author ........: Melba23, based on some original code by GioVit
  456. ; Modified.......:
  457. ; Remarks .......: This function is used internally by _Toast_Show
  458. ; ===============================================================================================================================
  459. Func _Toast_Locate($iToast_Width, $iToast_Height)

  461.         ; Define return array
  462.         Local $aToast_Data[3]

  464.         ; Find systray
  465.         Local $iPrevMode = Opt("WinTitleMatchMode", 4)
  466.     Local $aTray_Pos = WinGetPos("[CLASS:Shell_TrayWnd]")
  467.     Opt("WinTitleMatchMode", $iPrevMode)

  469.         ; If error in finding systray
  470.         If Not IsArray($aTray_Pos) Then Return SetError(2, 0, -1)

  472.         ; Determine direction of Toast motion and starting position
  473.         If $aTray_Pos[1] > 0 Then
  474.         $iToast_Move = 0x00050004 ; $AW_SLIDE_OUT_BOTTOM
  475.         $aToast_Data[0] = @DesktopWidth - $iToast_Width - 10
  476.         $aToast_Data[1] = $aTray_Pos[1] - $iToast_Height
  477.                 $aToast_Data[2] = 0x00040008 ; $AW_SLIDE_IN_BOTTOM
  478.     Elseif $aTray_Pos[0] > 0 Then
  479.         $iToast_Move = 0x00050001 ; $AW_SLIDE_OUT_RIGHT
  480.         $aToast_Data[0] = $aTray_Pos[0] - $iToast_Width
  481.         $aToast_Data[1] = @DesktopHeight - $iToast_Height - 10
  482.                 $aToast_Data[2] = 0x00040002 ; $AW_SLIDE_IN_RIGHT
  483.     ElseIf $aTray_Pos[2] = @DesktopWidth Then
  484.         $iToast_Move = 0x00050008 ; $AW_SLIDE_OUT_TOP
  485.         $aToast_Data[0] = @DesktopWidth - $iToast_Width - 10
  486.         $aToast_Data[1] = $aTray_Pos[1] + $aTray_Pos[3]
  487.                 $aToast_Data[2] = 0x00040004 ; $AW_SLIDE_IN_TOP
  488.     ElseIf $aTray_Pos[3] = @DesktopHeight Then
  489.         $iToast_Move = 0x00050002 ; $AW_SLIDE_OUT_LEFT
  490.         $aToast_Data[0] = $aTray_Pos[0] + $aTray_Pos[2]
  491.         $aToast_Data[1] = @DesktopHeight - $iToast_Height - 10
  492.                 $aToast_Data[2] = 0x00040001 ; $AW_SLIDE_IN_LEFT
  493.     EndIf

  495.         Return $aToast_Data

  497. EndFunc ; => _Toast_Locate

  499. ; #INTERNAL_USE_ONLY#============================================================================================================
  500. ; Name...........: _Toast_Timer_Check
  501. ; Description ...: Checks whether Toast has timed out or closure [X] clicked
  502. ; Syntax ........: _Toast_Locate($iToast_Width, $iToast_Height)
  503. ; Author ........: Melba23
  504. ; Modified.......:
  505. ; Remarks .......: This function is used internally by _Toast_Show if the Wait parameter is set to False
  506. ; ===============================================================================================================================
  507. Func _Toast_Timer_Check()

  509.         ; Return if timeout not elapsed and [X] not clicked
  510.         If TimerDiff($iToast_Start) < $iToast_Timer And $fToast_Close = False Then Return

  512.         ; Unregister message handler
  513.         GUIRegisterMsg(0x0021, "") ; $WM_MOUSEACTIVATE
  514.         ; Unregister this function
  515.         AdlibUnRegister("_Toast_Timer_Check")
  516.         ; Reset flag
  517.         $fToast_Close = False
  518.         ; Retract slice
  519.         _Toast_Hide()

  521. EndFunc; => _Toast_Timer_Check

  523. ; #INTERNAL_USE_ONLY#============================================================================================================
  524. ; Name...........: _Toast_WM_EVENTS
  525. ; Description ...: Message handler to check if closure [X] clicked
  526. ; Author ........: Melba23
  527. ; Modified.......:
  528. ; Remarks .......: This function is used internally by _Toast_Show if the Wait parameter is set to False
  529. ; ===============================================================================================================================
  530. Func _Toast_WM_EVENTS($hWnd, $Msg, $wParam, $lParam)

  532.         #forceref $wParam, $lParam
  533.     If $hWnd = $hToast_Handle Then
  534.                 If $Msg = 0x0021 Then ; $WM_MOUSEACTIVATE
  535.                         ; Check mouse position
  536.             Local $aPos = GUIGetCursorInfo($hToast_Handle)
  537.             If $aPos[4] = $hToast_Close_X Then $fToast_Close = True
  538.                 EndIf
  539.     EndIf
  540.     Return 'GUI_RUNDEFMSG'

  542. EndFunc; => _Toast_WM_EVENTS

  544. ; #INTERNAL_USE_ONLY#============================================================================================================
  545. ; Name...........: _Toast_GetDefFont
  546. ; Description ...: Determine system default MsgBox font and size
  547. ; Syntax ........: _Toast_GetDefFont($iData)
  548. ; Parameters ....: $iData - 0 = Font point size, 1 = Font name
  549. ; Author ........: Melba23
  550. ; Modified.......:
  551. ; Remarks .......: This function is used internally by _Toast functions
  552. ; ===============================================================================================================================
  553. Func _Toast_GetDefFont($iData)

  555.         ; Get default system font data
  556.         Local $tNONCLIENTMETRICS = DllStructCreate("uint;int;int;int;int;int;byte[60];int;int;byte[60];int;int;byte[60];byte[60];byte[60]")
  557.         DLLStructSetData($tNONCLIENTMETRICS, 1, DllStructGetSize($tNONCLIENTMETRICS))
  558.         DLLCall("user32.dll", "int", "SystemParametersInfo", "int", 41, "int", DllStructGetSize($tNONCLIENTMETRICS), "ptr", DllStructGetPtr($tNONCLIENTMETRICS), "int", 0)
  559.         ; Read font data for MsgBox font
  560.         Local $tLOGFONT = DllStructCreate("long;long;long;long;long;byte;byte;byte;byte;byte;byte;byte;byte;char[32]", DLLStructGetPtr($tNONCLIENTMETRICS, 15))
  561.         Switch $iData
  562.                 Case 0
  563.                         ; Font size as integer
  564.                         Return Int((Abs(DllStructGetData($tLOGFONT, 1)) + 1) * .75)
  565.                 Case 1
  566.                         ; Font name
  567.                         Return DllStructGetData($tLOGFONT, 14)
  568.         EndSwitch

  570. EndFunc ;=>_Toast_GetDefFont
复制代码
回复

举报

131738
 楼主| 发表于 2010-8-14 00:10:11 | 显示全部楼层
回复 10# 131738

StringSize.au3
  1. #include-once

  3. ; #INDEX# ============================================================================================================
  4. ; Title .........: _StringSize
  5. ; AutoIt Version : v3.2.12.1 or higher
  6. ; Language ......: English
  7. ; Description ...: Returns size of rectangle required to display string - width can be chosen
  8. ; Remarks .......:
  9. ; Note ..........:
  10. ; Author(s) .....: Melba23
  11. ; ====================================================================================================================

  13. ;#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6

  15. ; #CURRENT# ==========================================================================================================
  16. ; _StringSize: Returns size of rectangle required to display string - maximum permitted width can be chosen
  17. ; ====================================================================================================================

  19. ; #INTERNAL_USE_ONLY#=================================================================================================
  20. ; _StringSize_Error: Returns from error condition after DC and GUI clear up
  21. ; ====================================================================================================================

  23. ; #FUNCTION# =========================================================================================================
  24. ; Name...........: _StringSize
  25. ; Description ...: Returns size of rectangle required to display string - maximum permitted width can be chosen
  26. ; Syntax ........: _StringSize($sText[, $iSize[, $iWeight[, $iAttrib[, $sName[, $iWidth]]]]])
  27. ; Parameters ....: $sText   - String to display
  28. ;                  $iSize   - [optional] Font size in points - default AutoIt GUI default
  29. ;                  $iWeight - [optional] Font weight (400 = normal) - default AutoIt GUI default
  30. ;                  $iAttrib - [optional] Font attribute (0-Normal, 2-Italic, 4-Underline, 8 Strike - default AutoIt
  31. ;                  $sName   - [optional] Font name - default AutoIt GUI default
  32. ;                  $iWidth  - [optional] Width of rectangle - default is unwrapped width of string
  33. ; Requirement(s) : v3.2.12.1 or higher
  34. ; Return values .: Success - Returns array with details of rectangle required for text:
  35. ;                  |$array[0] = String formatted with @CRLF at required wrap points
  36. ;                  |$array[1] = Height of single line in selected font
  37. ;                  |$array[2] = Width of rectangle required to hold formatted string
  38. ;                  |$array[3] = Height of rectangle required to hold formatted string
  39. ;                  Failure - Returns 0 and sets @error:
  40. ;                  |1 - Incorrect parameter type (@extended = parameter index)
  41. ;                  |2 - Failure to create GUI to test label size
  42. ;                  |3 - DLL call error - extended set to indicate which
  43. ;                  |4 - Font too large for chosen width - longest word will not fit
  44. ; Author ........: Melba23
  45. ; Modified ......:
  46. ; Remarks .......:
  47. ; Related .......:
  48. ; Link ..........:
  49. ; Example .......: Yes
  50. ;=====================================================================================================================
  51. Func _StringSize($sText, $iSize = Default, $iWeight = Default, $iAttrib = Default, $sName = Default, $iWidth = 0)

  53.         Local $avSize_Info[4], $aRet, $iLine_Width = 0, $iLast_Word, $iWrap_Count
  54.         Local $hLabel_Handle, $hFont, $hDC, $oFont, $tSize = DllStructCreate("int X;int Y")

  56.         ; Check parameters are correct type
  57.         If Not IsString($sText) Then Return SetError(1, 1, 0)
  58.         If Not IsNumber($iSize) And $iSize <> Default   Then Return SetError(1, 2, 0)
  59.         If Not IsInt($iWeight)  And $iWeight <> Default Then Return SetError(1, 3, 0)
  60.         If Not IsInt($iAttrib)  And $iAttrib <> Default Then Return SetError(1, 4, 0)
  61.         If Not IsString($sName) And $sName <> Default   Then Return SetError(1, 5, 0)
  62.         If Not IsNumber($iWidth) Then Return SetError(1, 6, 0)

  64.         ; Create GUI to contain test labels, set to required font parameters
  65.         Local $hGUI = GUICreate("", 1200, 500, 10, 10)
  66.                 If $hGUI = 0 Then Return SetError(2, 0, 0)
  67.                 GUISetFont($iSize, $iWeight, $iAttrib, $sName)

  69.         ; Store unwrapped text
  70.         $avSize_Info[0] = $sText

  72.         ; Ensure EoL is @CRLF and break text into lines
  73.         If StringInStr($sText, @CRLF) = 0 Then StringRegExpReplace($sText, "[\x0a|\x0d]", @CRLF)
  74.         Local $asLines = StringSplit($sText, @CRLF, 1)

  76.         ; Draw label with unwrapped lines to check on max width
  77.         Local $hText_Label = GUICtrlCreateLabel($sText, 10, 10)
  78.         Local $aiPos = ControlGetPos($hGUI, "", $hText_Label)

  80.         GUISetState(@SW_HIDE)

  82.         GUICtrlDelete($hText_Label)

  84.         ; Store line height for this font size after removing label padding (always 8)
  85.         $avSize_Info[1] = ($aiPos[3] - 8)/ $asLines[0]
  86.         ; Store width and height of this label
  87.         $avSize_Info[2] = $aiPos[2]
  88.         $avSize_Info[3] = $aiPos[3] - 4 ; Reduce margin

  90.         ; Check if wrapping is required
  91.         If $aiPos[2] > $iWidth And $iWidth > 0 Then

  93.                 ; Set returned text element to null
  94.                 $avSize_Info[0] = ""

  96.                 ; Set width element to max allowed
  97.                 $avSize_Info[2] = $iWidth

  99.                 ; Set line count to zero
  100.                 Local $iLine_Count = 0

  102.                 ; Take each line in turn
  103.                 For $j = 1 To $asLines[0]

  105.                         ; Size this line unwrapped
  106.                         $hText_Label = GUICtrlCreateLabel($asLines[$j], 10, 10)
  107.                         $aiPos = ControlGetPos($hGUI, "", $hText_Label)
  108.                         GUICtrlDelete($hText_Label)

  110.                         ; Check wrap status
  111.                         If $aiPos[2] < $iWidth Then
  112.                                 ; No wrap needed so count line and store
  113.                                 $iLine_Count += 1
  114.                                 $avSize_Info[0] &= $asLines[$j] & @CRLF
  115.                         Else
  116.                                 ; Wrap needed so need to count wrapped lines

  118.                                 ; Create label to hold line as it grows
  119.                                 $hText_Label = GUICtrlCreateLabel("", 0, 0)
  120.                                 ; Initialise Point32 method
  121.                                 $hLabel_Handle = ControlGetHandle($hGui, "", $hText_Label)
  122.                                 ; Get DC with selected font
  123.                                 $aRet = DllCall("User32.dll", "hwnd", "GetDC", "hwnd", $hLabel_Handle)
  124.                                 If @error Then _StringSize_Error(3, 1, $hLabel_Handle, 0, $hGUI)
  125.                                 $hDC = $aRet[0]
  126.                                 $aRet = DllCall("user32.dll", "lparam", "SendMessage", "hwnd", $hLabel_Handle, "int", 0x0031, "wparam", 0, "lparam", 0) ; $WM_GetFont
  127.                                 If @error Then _StringSize_Error(3, 2, $hLabel_Handle, $hDC, $hGUI)
  128.                                 $hFont = $aRet[0]
  129.                                 $aRet = DllCall("GDI32.dll", "hwnd", "SelectObject", "hwnd", $hDC, "hwnd", $hFont)
  130.                                 If @error Then _StringSize_Error(3, 3, $hLabel_Handle, $hDC, $hGUI)
  131.                                 $oFont = $aRet[0]
  132.                                 If $oFont = 0 Then _StringSize_Error(3, 4, $hLabel_Handle, $hDC, $hGUI)

  134.                                 ; Zero counter
  135.                                 $iWrap_Count = 0

  137.                                 While 1

  139.                                         ; Set line width to 0
  140.                                         $iLine_Width = 0
  141.                                         ; Initialise pointer for end of word
  142.                                         $iLast_Word = 0

  144.                                         For $i = 1 To StringLen($asLines[$j])

  146.                                                 ; Is this just past a word ending?
  147.                                                 If StringMid($asLines[$j], $i, 1) = " " Then $iLast_Word = $i - 1
  148.                                                 ; Increase line by one character
  149.                                                 Local $sTest_Line = StringMid($asLines[$j], 1, $i)
  150.                                                 ; Place line in label
  151.                                                 GUICtrlSetData($hText_Label, $sTest_Line)

  153.                                                 ; Get line length into size structure
  154.                                                 $iSize = StringLen($sTest_Line)
  155.                                                 DllCall("GDI32.dll", "int", "GetTextExtentPoint32", "hwnd", $hDC, "str", $sTest_Line, "int", $iSize, "ptr", DllStructGetPtr($tSize))
  156.                                                 If @error Then _StringSize_Error(3, 5, $hLabel_Handle, $hDC, $hGUI)
  157.                                                 $iLine_Width = DllStructGetData($tSize, "X")

  159.                                                 ; If too long exit the loop
  160.                                                 If $iLine_Width >= $iWidth - Int($iSize / 2) Then ExitLoop
  161.                                         Next

  163.                                         ; End of the line of text?
  164.                                         If $i > StringLen($asLines[$j]) Then
  165.                                                 ; Yes, so add final line to count
  166.                                                 $iWrap_Count += 1
  167.                                                 ; Store line
  168.                                                 $avSize_Info[0] &= $sTest_Line & @CRLF
  169.                                                 ExitLoop
  170.                                         Else
  171.                                                 ; No, but add line just completed to count
  172.                                                 $iWrap_Count += 1
  173.                                                 ; Check at least 1 word completed or return error
  174.                                                 If $iLast_Word = 0 Then
  175.                                                         _StringSize_Error(4, 0, $hLabel_Handle, $hDC, $hGUI)
  176.                                                 EndIf
  177.                                                 ; Store line up to end of last word
  178.                                                 $avSize_Info[0] &= StringLeft($sTest_Line, $iLast_Word) & @CRLF
  179.                                                 ; Strip string to point reached
  180.                                                 $asLines[$j] = StringTrimLeft($asLines[$j], $iLast_Word)
  181.                                                 ; Trim leading whitespace
  182.                                                 $asLines[$j] = StringStripWS($asLines[$j], 1)
  183.                                                 ; Repeat with remaining characters in line
  184.                                         EndIf

  186.                                 WEnd

  188.                                 ; Add the number of wrapped lines to the count
  189.                                 $iLine_Count += $iWrap_Count

  191.                                 ; Clean up
  192.                                 DllCall("User32.dll", "int", "ReleaseDC", "hwnd", $hLabel_Handle, "hwnd", $hDC)
  193.                                 If @error Then _StringSize_Error(3, 6, $hLabel_Handle, $hDC, $hGUI)
  194.                                 GUICtrlDelete($hText_Label)

  196.                         EndIf

  198.                 Next

  200.                 ; Convert lines to pixels and add reduced margin
  201.                 $avSize_Info[3] = ($iLine_Count * $avSize_Info[1]) + 4

  203.         EndIf

  205.         ; Clean up
  206.         GUIDelete($hGUI)

  208.         ; Return array
  209.         Return $avSize_Info

  211. EndFunc ; => _StringSize

  213. ; #INTERNAL_USE_ONLY#============================================================================================================
  214. ; Name...........: _StringSize_Error
  215. ; Description ...: Returns from error condition after DC and GUI clear up
  216. ; Syntax ........: _StringSize_Error($iError, $iExtended, $hLabel_Handle, $hDC, $hGUI)
  217. ; Parameters ....: $iError  - required error value to return
  218. ;                  $iExtended - required extended value to return
  219. ;                  $hLabel_Handle, $hDC, $hGUI - variables as set in _StringSize function
  220. ; Author ........: Melba23
  221. ; Modified.......:
  222. ; Remarks .......: This function is used internally by _StringSize
  223. ; ===============================================================================================================================
  224. Func _StringSize_Error($iError, $iExtended, $hLabel_Handle, $hDC, $hGUI)

  226.         ; Release DC if created
  227.         DllCall("User32.dll", "int", "ReleaseDC", "hwnd", $hLabel_Handle, "hwnd", $hDC)
  228.         ; Delete GUI
  229.         GUIDelete($hGUI)
  230.         ; Return with extended set
  231.         Return SetError($iError, $iExtended, 0)

  233. EndFunc ; => _StringSize_Error
复制代码
回复

举报

131738
 楼主| 发表于 2010-8-14 00:13:06 | 显示全部楼层
本帖最后由 131738 于 2010-8-14 00:56 编辑

回复 11# 131738

示例文件：Toast_Example.au3
  1. ;Example Toast

  3. #include "Toast.au3"

  5. Local $sMsg, $hProgress, $aRet[2]

  7. $sMsg  = "The message text goes in this area" & @CRLF & @CRLF
  8. $sMsg &= "This Toast uses the System colours and font"

  10. $aRet = _Toast_Show(0, "The Title text goes here", $sMsg, 5)
  11. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & @CRLF)
  12. _Toast_Hide()

  14. $sMsg  = "This Toast uses colours and font defined in a _Toast_Set call." & @CRLF & @CRLF
  15. $sMsg &= "Subsequent Toasts will use these values until they are reset by another _Toast_Set call" & @CRLF & @CRLF
  16. $sMsg &= "You can also display a standard icon - or one from an exe as here" & @CRLF & @CRLF
  17. $sMsg &= "The next Toast has a very small message to show the pre-set minimum size"

  19. _Toast_Set(5, 0xFF00FF, 0xFFFF00, 0x0000FF, 0xFFFFFF, 10, "Arial")
  20. $aRet = _Toast_Show(@AutoItExe, "User-defined Colours and Bold Header", $sMsg, 10)
  21. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & @CRLF)
  22. _Toast_Hide()

  24. $aRet = _Toast_Show(0, "", "Tiny", 2)
  25. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & @CRLF)
  26. _Toast_Hide()

  28. $sMsg  = "These lines are of medium length" & @CRLF & @CRLF
  29. $sMsg &= "The width is set by the longest" & @CRLF & @CRLF
  30. $sMsg &= "No wrapping occurs here" & @CRLF & @CRLF
  31. $sMsg &= "Note increased font size"

  33. _Toast_Set(-1, -1, -1, -1, -1, 15)
  34. $aRet = _Toast_Show(0, "Mid Width", $sMsg, 5)
  35. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & @CRLF)
  36. _Toast_Hide()

  38. $sMsg  = "This is a long message set to left justified and a much larger font using _Toast_Set" & @CRLF & @CRLF
  39. $sMsg &= "The Toast is automatically set to the maximum preset width and the message text "
  40. $sMsg &= "is wrapped as necessary to fit within the margins of the Toast" & @CRLF & @CRLF
  41. $sMsg &= "The Toast colours and weight have been changed by another _Toast_Set call" & @CRLF & @CRLF
  42. $sMsg &= "Note the closure [X] on the title bar.  This Toast will time out in 30 secs "
  43. $sMsg &= "but clicking the [X] will resume the script immediately"

  45. _Toast_Set(0, -1, 0xFFFF00, 0x00FF00, 0x000000, 15, "Courier New")
  46. $aRet = _Toast_Show(64, "Max Width and Normal Header", $sMsg, -30)
  47. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & @CRLF)
  48. _Toast_Hide()

  50. $sMsg  = "This line is very long to show that you can override the pre-set maximum width with the 'Raw' parameter. "
  51. $sMsg &= "You have to add a few more parameters to the _Toast_Show call but that is a small price to pay"
  52. $sMsg &= @CRLF & @CRLF & "However, the Toast will not display if it does not fit on the screen!"

  54. _Toast_Set(5, 0xFF00FF, 0xFFFF00, 0x0000FF, 0xFFFFFF, 10, "Arial")
  55. $aRet = _Toast_Show(0, "Unwrapped Toast", $sMsg, -20, True, True)
  56. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & @CRLF)
  57. _Toast_Hide()

  59. $sMsg  = "Note how Toasts adjust automatically in height to display all of the message "
  60. $sMsg &= "regardless of whether there is a title bar to display, the font used, "
  61. $sMsg &= "the number of lines or whether wrapping occurs" & @CRLF & @CRLF
  62. $sMsg &= "This Toast will retract automatically when the next Toast is called "
  63. $sMsg &= "or when the [X] is clicked"

  65. $aRet = _Toast_Show(0, "", $sMsg, -10)
  66. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & @CRLF)

  68. $sMsg  = "This Toast has several blank lines inserted. "
  69. $sMsg &= "This can be useful if you want to leave space to add other controls, "
  70. $sMsg &= "such as a progress bar, to the Toast once it is displayed" & @CRLF & @CRLF & @CRLF & @CRLF
  71. $sMsg &= "The Toast size is returned by the function so you can calculate "
  72. $sMsg &= "where to place the other controls.  "
  73. $sMsg &= "This example script writes the size in the SciTE console" & @CRLF & @CRLF
  74. $sMsg &= "Note that Toast colours and font have been reset to Default"

  76. _Toast_Set(Default)
  77. $aRet = _Toast_Show(0, "Progress Bar", $sMsg, 0) ; No delay or progress bar will not display immediately
  78. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & @CRLF)
  79. $hProgress = GUICtrlCreateProgress(10, 65, $aRet[0] - 20, 20)
  80. For $i = 1 To 100
  81.         GUICtrlSetData($hProgress, $i)
  82.         Sleep(50)
  83. Next
  84. Sleep(5000)
  85. _Toast_Hide()

  87. $sMsg  = "This Toast has the 'Wait' flag set to False. " & @CRLF & @CRLF
  88. $sMsg &= "That means that the script will continue while the Toast is displayed as "
  89. $sMsg &= "as you can see from this counter." & @CRLF & @CRLF
  90. $sMsg &= "Clicking the [X] will retract the Toast immediately but it will "
  91. $sMsg &= "automatically retract after 20 seconds in any event"

  93. _Toast_Set(5, 0xFF00FF, 0xFFFF00, 0x0000FF, 0xFFFFFF, 10)
  94. $aRet = _Toast_Show(32, "Script Continuing", $sMsg, -20, False) ; Delay can be set here because script continues
  95. ConsoleWrite("Toast size: " & $aRet[0] & " x " & $aRet[1] & @CRLF)
  96. $hLabel = GUICtrlCreateLabel("", 267, 98, 15, 15)
  97. GUICtrlSetBkColor(-1, 0xFFFF00)
  98. $iCount = 0
  99. Do
  100.         $iCount += 1
  101.         GUICtrlSetData($hLabel, StringFormat("%2s", $iCount))
  102.         Sleep(1000)
  103. Until $iCount = 60 Or $hToast_Handle = 0 ; Toast will retract automatically before $iCount = 60

  105. Exit
复制代码
1 楼的可能是早期代码，这是本年7月的改良脚本。。。。
回复

举报

afan
发表于 2010-8-14 13:17:08 | 显示全部楼层
这是昨天修改的，也是将例子分开了。
修改了_StringSize() ，在其最后增加了一个参数 $Lang ，为1时使用汉字环境（默认），为0时使用英文环境。
同时 _Toast_Show() 也同时增加了此参数。因为_StringSize() 是使用 _Toast_Show() 调用的

本帖子中包含更多资源

您需要 登录 才可以下载或查看，没有账号？加入

×

评分

参与人数 1贡献 +15 收起 理由
xyhqqaa + 15 好玩。。。。看看Afan哥。。学习ing

查看全部评分

回复

举报

6678720
发表于 2010-8-14 16:33:49 | 显示全部楼层
谢谢各位大侠
回复

举报

131738
 楼主| 发表于 2010-8-14 18:57:50 | 显示全部楼层
回复 13# afan

幸苦了。。。。谢谢！！！！！！！！！！！
回复

举报

下一页 »
12下一页
返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 加入

本版积分规则

QQ|手机版|小黑屋|AUTOIT CN ( 鲁ICP备19019924号-1 )谷歌 百度

GMT+8, 2026-9-25 08:49 , Processed in 0.132481 second(s), 25 queries .

Powered by Discuz! X3.5 Licensed

© 2001-2026 Discuz! Team.

快速回复 返回顶部 返回列表