[已解决] 如何替换指定行？

xlcwxl

有一文本，其中第1、4、7、11行中的内容是一致，可以通过什么方法把他们分别替换成不一样的内容？

答案在：
11#  afan
12# 3mile

感谢afan、3mile的热心帮助

ajian55

文本替换，一次替换一个，做四次完成，每次替换的结果不同~

afan

ini文件？关键字相同？

xlcwxl

回复 3# afan


谢谢afan，文本文件

afan

回复 4# xlcwxl


   举例说明吧，范本及期望结果

xlcwxl

回复 5# afan

==================================================
编  号=03
用户名=张三
密  码=123456
==================================================

==================================================
编  号=03
用户名=李四
密  码=654321
==================================================

==================================================
编  号=03
用户名=王五
密  码=123
==================================================

想替换成以下格式

[001]
编  号=03
用户名=张三
密  码=123456


[002]
编  号=03
用户名=李四
密  码=654321


[003]
编  号=03
用户名=王五
密  码=123

afan

“==================================================”这东西也有？
另外你这个范本只有重复的，没有不重复的？ 还要新增加字段名？ 字段名数字递加？ 太多不解

xlcwxl

回复 7# afan

呵呵，基本格式就是这样，没有其它变化，只有重复
至于字段名数字递加这个无所谓，随便叫什么都可以

谢谢afan我想下能否通过其它方法解决。

afan

所有的都是 “编  号=03”？

xlcwxl

回复 9# afan

不一样，测试的时候搞忘改了

afan

$Str = _
                '==================================================' & @CRLF & _
                '编  号=03' & @CRLF & _
                '用户名=张三' & @CRLF & _
                '密  码=123456' & @CRLF & _
                '==================================================' & @CRLF & _
                '' & @CRLF & _
                '==================================================' & @CRLF & _
                '编  号=03' & @CRLF & _
                '用户名=李四' & @CRLF & _
                '密  码=654321' & @CRLF & _
                '==================================================' & @CRLF & _
                '' & @CRLF & _
                '==================================================' & @CRLF & _
                '编  号=03' & @CRLF & _
                '用户名=王五' & @CRLF & _
                '密  码=123' & @CRLF & _
                '=================================================='
MsgBox(0, '原字符串', $Str)
Local $i = 1, $bj
While 1
        If Not $bj Then
                $Str = StringRegExpReplace($Str, '==+', '[' & StringFormat('%03d', $i) & ']', 1)
                $bj = True
                $i += 1
        Else
                $Str = StringRegExpReplace($Str, '==+(\r\n|$)', '', 1)
                $bj = False
        EndIf
        If @extended = 0 Then ExitLoop
WEnd
MsgBox(0, '替换后', $Str)

3mile

$Str = _
                '==================================================' & @CRLF & _
                '编  号=03' & @CRLF & _
                '用户名=张三' & @CRLF & _
                '密  码=123456' & @CRLF & _
                '==================================================' & @CRLF & _
                '' & @CRLF & _
                '==================================================' & @CRLF & _
                '编  号=03' & @CRLF & _
                '用户名=李四' & @CRLF & _
                '密  码=654321' & @CRLF & _
                '==================================================' & @CRLF & _
                '' & @CRLF & _
                '==================================================' & @CRLF & _
                '编  号=03' & @CRLF & _
                '用户名=王五' & @CRLF & _
                '密  码=123' & @CRLF & _
                '=================================================='
MsgBox(0, '原字符串', $Str)
$obj=StringRegExp($str,'(?ms)={2,}(.*?)={2,}',3)
$str=''
For $i=0 To UBound($obj)-1
        $str&='['&StringFormat('%03d',$i+1)&']'&$obj[$i]&@CRLF
Next
MsgBox(0,'替换后',$str)