如何创建一个用户netuser,并修改组策略中的 用户权限分配 拒绝从本地登录

pandy05

请教高人啊！如何创建一个用户netuser,设置密码为1234567，用户属性为：用户不能修改密码、密码永不过期，同时并修改组策略中的 用户权限分配 拒绝从本地登录，捣鼓了好久还是不知道怎么弄啊，先拜谢了！！！

netegg

你要干什么

pandy05

回复 2# netegg

局域网内用来共享文件和打印机，但不允许用来登录！

netegg

晕了,不登录要控制(共享)主机的硬件设备?
客户机登录不登录

pusofalse

#include <lsasecur.au3>

Const $UF_PASSWD_CANT_CHANGE = 0x40 ; User cannot change the password.
Const $UF_DONT_EXPIRE_PASSWD = 0x10000 ; Password should never expire.

Const $USERNAME = "netuser"
Const $PASSWORD = "1234567"

If _SeCreateLocalUser($USERNAME, $PASSWORD, BitOR($UF_DONT_EXPIRE_PASSWD, $UF_PASSWD_CANT_CHANGE)) = 0 Then
        If @error <> 2224 Then ; User Already exists
                MsgBox(48, "Error", _SeFormatMsg(@error))
                Exit
        EndIf
EndIf

If _SeAddAccountRight($USERNAME, $SE_DENY_INTERACTIVE_LOGON_RIGHT) Then
        MsgBox(48, "OK", "Done")
Else
        MsgBox(48, "Error", _SeFormatMsg(@error))
EndIf

pandy05

回复 5# pusofalse


    多谢斑斑！都从没用过lsasecur.au3这个函数，多想斑斑学习！

pandy05

回复 5# pusofalse


    还是得回来找斑斑求救一下，怎么设置用户属于users组呢，用
下面的代码为什么不行呢，出错了

Const $SE_USER_PRIV_USER = 1

pusofalse

新添加的用户不属于任何组，调用_SeAddLocalGroupMembers 将指定用户添加到指定的组，cmd命令 net user netuser /add也是这样做的。

#include <lsasecur.au3>

Const $USERNAME = "netuser"

; Get 'USER' group SID.
Local $pLocalGroupSid = _SeGetWellKnownAccountSid($SE_WELLKNOWN_USERS)

; Convert SID to string.
Local $sLocalGroup = _SeLookupAccountSid($pLocalGroupSid)

; Parse out the groupname from the complete name string.
$sLocalGroup = StringRegExpReplace($sLocalGroup, "(.*)\\(.+)", "\2")

; Add $USERNAME to the specified $sLocalGroup.
If $sLocalGroup And _SeAddLocalGroupMembers($sLocalGroup, $USERNAME) Then
        MsgBox(48, "OK", "Done")
Else
        MsgBox(48, "Error", _SeFormatMsg())
EndIf

_SeHeapFree($pLocalGroupSid)

pandy05

回复 8# pusofalse


    多谢斑斑啊，还要再慢慢看看能看懂

xms77

版主是高人，不是一般的高啊！

qqgghh1

lsasecur.au3>函数填补了XX技术空白，感谢你，P大。