(已解决)求助如何在状态栏内嵌入进度条

xyhqqaa

本人新手。。之前看过蛋蛋的一帖子，好像就是关于在statusbar内嵌入进度条的例子，但是就是找不到。求传送门。连接。。我是真的找不到了。。什么关键词都用了。。百度谷歌都试了。。。囧，。。。本人不是职业伸手党，只是一业余的。。求大哥们知道的帮帮忙。  想法是在状态栏内显示。但是不知道这方法可以实现吗。。不会出问题吗

afan

#include <GuiConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <ProgressConstants.au3>
#include <SendMessage.au3>

Opt('MustDeclareVars', 1)

$Debug_SB = False ; 检查传递给函数的类名, 设置为True,并使用另一个控件句柄,看看它的工作.

_Main()

Func _Main()

        Local $hGUI, $hProgress, $hInput, $input, $progress, $hStatus
        Local $aParts[4] = [80, 160, 300, -1]

        ; 创建 GUI
        $hGUI = GUICreate("嵌入子控件", 400, 300)

        ;===============================================================================
        ; 默认一个部件, 没有文本
        $hStatus = _GUICtrlStatusBar_Create($hGUI)
        _GUICtrlStatusBar_SetMinHeight($hStatus, 20)

        ;===============================================================================
        GUISetState()

        ; 初始化部件
        _GUICtrlStatusBar_SetParts($hStatus, $aParts)
        _GUICtrlStatusBar_SetText($hStatus, "部件 1")
        _GUICtrlStatusBar_SetText($hStatus, "部件 2", 1)

        ; 嵌入一个进度条
        If @OSType = "WIN32_WINDOWS" Then
                $progress = GUICtrlCreateProgress(0, 0, -1, -1, $PBS_SMOOTH)
                $hProgress = GUICtrlGetHandle($progress)
                _GUICtrlStatusBar_EmbedControl($hStatus, 2, $hProgress)
        Else
                $progress = GUICtrlCreateProgress(0, 0, -1, -1, $PBS_MARQUEE) ; marquee 工作于 Win XP 及更高版本
                $hProgress = GUICtrlGetHandle($progress)
                _GUICtrlStatusBar_EmbedControl($hStatus, 2, $hProgress)
                _SendMessage($hProgress, $PBM_SETMARQUEE, True, 200) ; marquee 工作于 Win XP 及更高版本
        EndIf

        $input = GUICtrlCreateInput("嵌入的输入框", 0, 0)
        $hInput = GUICtrlGetHandle($input)
        _GUICtrlStatusBar_EmbedControl($hStatus, 3, $hInput, 3)

        ; 循环到用户退出
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>_Main

131738

回复 2# afan

新版文档不好用么？ 那个的总目录表可是十分完整的。。。呵呵。。。

afan

回复  afan

新版文档不好用么？ 那个的总目录表可是十分完整的。。。呵呵。。。
131738 发表于 2011-9-28 16:23

    我还在用 3361 版，前辈的新版帮助文档可能与之会有出入，所以只下载了并没有具体使用，呵呵

131738

回复 4# afan

应该不会与3361有区别，只会更好，应为3361有漏翻译的和错误描述。。。

不知出入指的什么？。。。。

afan

回复 5# 131738


    函数库应该会不同吧，帮助文档基本上主要就是与之配套。新版应该有增减。当然，具体什么变化前辈应该很清楚，我只是瞎猜的~ 因为遇到过旧版能编译通过而新版却需要修改的问题，特别是api函数~

131738

回复 6# afan

喔。。。。。。。

gzh888666

本人新手。。之前看过蛋蛋的一帖子，好像就是关于在statusbar内嵌入进度条的例子，但是就是找不到。求传送门 ...
xyhqqaa 发表于 2011-9-28 15:19

这个工具不错呀！开源了吧！呵呵

zfyczyh

进来向各位大大学习啦

iori2882

谢谢 很有用的例子

yuwentao4761

支持了....我貌似以前也做过类似的...

zhuang513

不理解_SendMessage 的意思..哎..

xms77

回复 2# afan
$Debug_SB = False ; 检查传递给函数的类名, 设置为True,并使用另一个控件句柄,看看它的工作.
这一句是什么意思，好像下面的代码没有使用到嘛？

gzh888666

初始化的作用而已！用于检测

andersonljw

谢谢 很有用的例子