『已解决』请问如何使Autoit判断电脑有几个硬盘，和几个分区，还有硬盘类型？

aassddffgg961

比方说电脑有两个以上硬盘，每个硬盘又都有分区，请问要怎么让Autoit判断？查找帮助好像没看到有判断分区的代码，论坛好像也没搜索到。请高手指点下。谢谢。


以上问题基本解决，现在的问题是盘类型的检测，有时插入移动硬盘或者是VMware映射盘排除等。只检测电脑内置硬盘。谢谢。

netegg

不知道lz如何查的帮助，还是不过臆想了一下

aassddffgg961

好吧，我承认我很蹩脚，请问能否提示下命令行的关键词？另外有时插入移动盘或者是虚拟盘能否自动排除？只找电脑内置硬盘的所有分区？谢谢。

zerobin

点这里，监视硬盘分区的实例

至于多少个硬盘，楼主自己举一反三吧。

netegg

#Include <WinAPIEx.au3>
_WinAPI_GetDriveNumber

盘类型没测试过

aassddffgg961

谢谢楼上几位。坐等盘类型的例子。

ooxxgod

Local $aArray = DriveGetDrive("ALL")
If @error Then
        ; An error occurred when retrieving the drives.
        MsgBox(4096, "DriveGetDrive", "It appears an error occurred.")
Else
        For $i = 1 To $aArray[0]
                ; Show all the drives found and convert the drive letter to uppercase.
                MsgBox(4096, "DriveGetDrive", "Drive " & $i & "/" & $aArray[0] & ":" & @CRLF & StringUpper($aArray[$i]))
        Next
EndIf

aassddffgg961

试了一下楼上的，但好像不能区分盘类型哦。不能排除移动盘。

zerobin

代码如下 原帖地址

GetPartionMsg("", 1)        ;GetPartionMsg 的第一个参数可以是 USB、IDE 等;如果不带任何参数，则是检测所有磁盘分区
                                                ;第二个参数可以是 1、0，1 表示 TRUE，0 表示 FALSE;如果第一个参数为空，则第二个必需为 1
 
Func GetPartionMsg($Interface, $b)
        $objWMIService = ObjGet("winmgmts:\\.\root\cimv2")
        $colItems = $objWMIService.ExecQuery ("Select * from Win32_LogicalDiskToPartition")
        $DiskInfo = ""
        $DiskInfoCombo = ""
        For $objItem In $colItems
                $DiskFH = StringLeft(StringRight($objItem.Dependent, 3), 2)
                $PartNum = QueryDiskNum($DiskFH)
                $PartMsg = QueryPartitionVolume($DiskFH)
                If $Interface <> "" Then
                        If $b = 1 Then
                                If StringMid($PartNum, 2, 3) = $Interface Then
                                        $DiskInfo = $DiskInfo & $PartNum & $DiskFH & $PartMsg & @CRLF
                                EndIf
                        ElseIf $b = 0 Then
                                If StringMid($PartNum, 2, 3) <> $Interface Then
                                        $DiskInfo = $DiskInfo & $PartNum & $DiskFH & $PartMsg & @CRLF
                                EndIf
                        EndIf
                Else
                        $DiskInfo = $DiskInfo & $PartNum & $DiskFH & $PartMsg & @CRLF
                EndIf
        Next
        MsgBox(64, "磁盘信息", $DiskInfo)
EndFunc   ;==>GetPartionMsg
 
Func QueryDiskInterface($n)
        $objWMIService = ObjGet("winmgmts:\\.\root\cimv2")
        $colItems = $objWMIService.ExecQuery ("Select * from Win32_DiskDrive Where Index=" & $n)
        For $objItem In $colItems
                Return $objItem.InterfaceType
        Next
EndFunc   ;==>QueryDiskInterface
 
Func QueryPartitionVolume($v)
        $objWMIService = ObjGet("winmgmts:\\.\root\cimv2")
        $colItems = $objWMIService.ExecQuery ("Select * from Win32_LogicalDisk Where DeviceID='" & $v & "'")
        For $objItem In $colItems
                Return $objItem.VolumeName & "" & $objItem.FileSystem & "_" & CalcKMG($objItem.Size) & "_" & $objItem.Description
        Next
EndFunc   ;==>QueryPartitionVolume
 
Func QueryDiskNum($d)
        $objWMIService = ObjGet("winmgmts:\\.\root\cimv2")
        $colItems = $objWMIService.ExecQuery ("Associators of {win32_LogicalDisk.DeviceID='" & $d & "'} where ResultClass = Win32_DiskPartition")
        For $colItem In $colItems
                Return "(" & QueryDiskInterface($colItem.DiskIndex) & ":hd" & $colItem.DiskIndex & ")" 
        Next
EndFunc   ;==>QueryDiskNum
 
Func CalcKMG($n)
        If $n < 1024 Then
                Return $n & "Byte" 
        ElseIf $n < 1048576 Then
                Return Round($n / 1024, 2) & "KB" 
        ElseIf $n < 1073741824 Then
                Return Round($n / 1048576, 2) & "MB" 
        Else
                Return Round($n / 1073741824, 2) & "GB" 
        EndIf
EndFunc   ;==>CalcKMG

zerobin

楼主说的“现在的问题是盘类型的检测，有时插入移动硬盘或者是VMware映射盘排除等。只检测电脑内置硬盘。谢谢。”
添加条件限制就行了。
看图
看到后面的类型了吧

aassddffgg961

回复 10# zerobin


    谢谢了，还有一个疑问，使用于SATA硬盘吧？刚好我的电脑现在是IDE模式。。。无法试。。。