求个论坛自动发帖子的源码

cnmini

求个论坛自动发帖子的源码
菜鸟，希望热心人能帮忙写个

cnmini

希望能实现后台运行，最好不影响当前工作

liongodmien

你去找＇一路问情论坛自动灌水机＇的破解版吧，如果你不会修改，就算给了你个灌水机的源码如果不适合你要灌水的论坛，那也是白给

cnmini

破解版？不好找，给我个地址？
AU3的源码希望也能给个，想细研究下，自己写的功能太差

番茄

3楼说的很明白了，楼主看不懂？
有这功夫早也baidu搜索到了。

bigfool

想不到还有这样的软件，看来搞T楼活动就有福

cnmini

原帖由 番茄 于 2008-10-29 14:10 发表
3楼说的很明白了，楼主看不懂？
有这功夫早也baidu搜索到了。

呵，我还是希望能有AU3源码的好，研究下

liongodmien

一路问情灌水机的破解版地址：

http://liongodmien.ys168.com

在软件那一个目录里

我前几天写的一个灌水机：

#Region ;**** 参数创建于 ACNWrapper_GUI ****
#AutoIt3Wrapper_icon=CS2-Premium.ico
#AutoIt3Wrapper_outfile=论坛灌水机.exe
#AutoIt3Wrapper_Compression=4
#AutoIt3Wrapper_Res_Description=论坛灌水机 by Lion God Mien
#AutoIt3Wrapper_Res_Fileversion=10.30.9.27
#AutoIt3Wrapper_Res_Fileversion_AutoIncrement=y
#AutoIt3Wrapper_Res_LegalCopyright=Lion God Mien
#AutoIt3Wrapper_Run_Obfuscator=y
#Obfuscator_Parameters=/cs 0 /cn 0 
#EndRegion ;**** 参数创建于 ACNWrapper_GUI ****
#include-once
#include <ie.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

;~ $My_Title = '我的灌水机'
;~ If WinExists($My_Title) Then Exit
;~ AutoItWinSetTitle($My_Title)

FileInstall('gs.txt', 'gs.txt')
HotKeySet('+{F7}', 'SHOWORHIDE')
HotKeySet('+{ESC}', '_GUICLOSE')

Opt('TrayAutoPause', 0)
Opt('GUIOnEventMode', 1)
Opt('TrayOnEventMode', 1)
$Tray = TrayCreateItem('显示/隐藏')
TrayItemSetOnEvent($Tray, 'SHOWORHIDE')
TraySetToolTip('论坛灌水机 by Lion God Mien')

Global $Form, $Input1, $Input2, $Checkbox1, $Button1, $Form1, $oIE

$Form1 = GUICreate("灌水页面显示", 640, 480, -1, 0, BitXOR($WS_POPUPWINDOW, $WS_BORDER), $WS_EX_TOOLWINDOW + $WS_EX_TOPMOST, $Form)
$oIE = _IECreateEmbedded()
GUICtrlCreateObj($oIE, -2, -2, 644, 484)
_IENavigate($oIE, 'http://www.autoitx.com/?fromuid=7632375', 0)
#Region ### START Koda GUI section ### Form=
$Form = GUICreate("灌水机 by LionGodMien", 450, 95, -1, @DesktopHeight * 0.7, $GUI_SS_DEFAULT_GUI, $WS_EX_TOPMOST)
GUISetFont(9, 400, 0, "Times New Roman")
GUICtrlCreateLabel("地址：", 15, 12, 36, 16)
$Input1 = GUICtrlCreateInput("http://", 55, 10, 377, 23)
GUICtrlCreateGroup("程序控制", 16, 37, 281, 49)
$Checkbox1 = GUICtrlCreateCheckbox("显示页面", 200, 58, 67, 15)
GUICtrlSetState($Checkbox1, $GUI_CHECKED)
GUICtrlCreateLabel("灌水间隔", 30, 59, 52, 19)
GUICtrlCreateLabel("秒", 131, 59, 16, 19)
$Input2 = GUICtrlCreateInput("19", 83, 55, 43, 23, $ES_READONLY)
GUICtrlCreateUpdown($Input2)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Button1 = GUICtrlCreateButton("开始", 352, 48, 81, 33, 0)
GUICtrlSetColor($Button1, 0x0000FF)
GUICtrlSetCursor($Button1, 0)
GUICtrlSetState($Button1, $GUI_FOCUS)
GUISetState(@SW_SHOW, $Form1)
GUISetState(@SW_SHOW, $Form)
#EndRegion ### END Koda GUI section ###
GUISetOnEvent($GUI_EVENT_MINIMIZE, 'SHOWORHIDE', $Form)
GUISetOnEvent($GUI_EVENT_CLOSE, '_GUICLOSE', $Form)
Dim $Form_Acceler[1][2] = [["{ENTER}", $Button1]]
GUISetAccelerators($Form_Acceler)
GUICtrlSetOnEvent($Button1, '_CheckKey')
GUICtrlSetOnEvent($Checkbox1, '_CheckKey')

Global $show = 1, $PAUSE = 1, $HTML, $CLICK, $oFORM, $i = 0, $R, $oINPUT, $Link, $T[6]

RunAndStop()
AdlibEnable('RunAndStop', 300)
MAINSUBMIT()


Func _CheckKey()
        Switch @GUI_CtrlId                
                Case $Checkbox1
                        If GUICtrlRead($Checkbox1) = $GUI_CHECKED Then
                                GUISetState(@SW_SHOW, $Form1)
                                GUISetState(@SW_RESTORE, $Form)
                        Else
                                GUISetState(@SW_HIDE, $Form1)
                        EndIf
                        
                Case $Button1
                        $PAUSE = Not $PAUSE
                        If $PAUSE = 1 Then
                                GUICtrlSetData($Button1, '开始', '')
                                GUICtrlSetColor($Button1, 0x0000FF)
                        Else
                                GUICtrlSetData($Button1, '暂停', '')
                                GUICtrlsetColor($Button1, 0xFF0000)
                        EndIf
                        
        EndSwitch
EndFunc


Func SHOWORHIDE()
        $show = Not $show
        If $show = 0 Then
                GUISetState(@SW_HIDE, $Form1)
                GUISetState(@SW_MINIMIZE, $Form1)
                GUISetState(@SW_MINIMIZE, $Form)
                GUISetState(@SW_HIDE, $Form)
        Else
                GUISetState(@SW_SHOW, $Form1)
                GUISetState(@SW_RESTORE, $Form1)
                GUISetState(@SW_SHOW, $Form)
                GUISetState(@SW_RESTORE, $Form)
        EndIf
EndFunc

Func _GUICLOSE()
        Exit
EndFunc

Func CheckForOK()
        $T[3] = TimerInit()
        Do
                $HTML = _IEDocReadHTML($oIE)
                If StringInStr($HTML, '按钮，尝试其他链接。') <> 0 Or StringInStr($HTML, '帖子ID非法') <> 0 Then MAINSUBMIT()
                If StringInStr($HTML, '网页已经过期') <> 0 Or StringInStr($HTML, 'ERROR') <> 0 Then MAINSUBMIT()
                If StringInStr($HTML, '灌水预防机制') <> 0 Or StringInStr($HTML, '请勿连续发表相同') <> 0 Then
                        _IEAction($oIE, 'back')
                        _IELoadWait($oIE, 200)
                EndIf
                $T[4] = TimerDiff($T[3])
                If $T[4] >= 120000 Then MAINSUBMIT()
                Sleep(100)
        Until StringInStr($HTML, '按 Ctrl+Enter 直接提交') <> 0
EndFunc

Func MAINSUBMIT()
        _IENavigate($oIE, GUICtrlRead($Input1), 1)
        CheckForOK()
        $Link = StringRegExp($HTML, '(?U)>(灌水链接的文字)<', 1, 1)
        _IELinkClickByText($oIE, $Link[0], 0, 1)
        CheckForOK()
        Do
                $T[5] += 1
                If $T[5] = 100 Then
                        $T[5] = 0
                        _ReduceMemory()
                EndIf
                $i += 1
                $R = FileReadLine('gs.txt', $i)
                If @error = -1 Then
                        $i = 1
                        ContinueLoop
                EndIf
                $oFORM = _IEFormGetObjByName($oIE, 'FORM')
                $oINPUT = _IEFormElementGetObjByName($oFORM, 'atc_content')
                _IEFormElementSetValue($oINPUT, $R)
                $CLICK = _IEGetObjByName($oIE, 'Submit')
                _IEAction($CLICK, 'click')
                $T[1] = TimerInit()
                _IELoadWait($oIE, 200)
                CheckForOK()
                Do
                        Sleep(100)
                        $T[2] = TimerDiff($T[1])
                        $T[0] = GUICtrlRead($Input2) * 1000
                Until $T[2] >= $T[0]
        Until 0
EndFunc

Func RunAndStop()
        Do
                Sleep(100)
        Until $PAUSE = 0
EndFunc

Func _ReduceMemory()
        Local $ai_Handle = DllCall("kernel32.dll", 'int', 'OpenProcess', 'int', 0x1f0fff, 'int', False, 'int', @AutoItPID)
        Local $ai_Return = DllCall("psapi.dll", 'int', 'EmptyWorkingSet', 'long', $ai_Handle[0])
        DllCall('kernel32.dll', 'int', 'CloseHandle', 'int', $ai_Handle[0])
EndFunc

[ 本帖最后由 liongodmien 于 2008-10-30 09:31 编辑 ]

liongodmien

不要在这灌水啊！

cnmini

谢谢，研究下先