[已解决]创建一个显示有 IE地址栏 的窗口求助高手帮解决

ningzhonghui

创建一个显示有 IE地址栏 的窗口求助高手帮解决

#include<ie.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
$oIE = _IECreate()
GUICreate("", 660, 580, -1, -1)
$GUIActiveX = GUICtrlCreateObj($oIE, 0, 0, 660, 580)
GUISetState()
_IENavigate($oIE, "http://www.autobatch.org/")
While 1
        $msg = GUIGetMsg()
        Select
                        Case $msg = $GUI_EVENT_CLOSE
                                Exit
        EndSelect
WEnd

ajian55

稍微改动了下官方帮助里的例子，多看帮助！！！

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <IE.au3>

_IEErrorHandlerRegister ()

$oIE = _IECreateEmbedded ()
GUICreate("Embedded Web control Test", 640, 580, _
(@DesktopWidth - 640) / 2, (@DesktopHeight - 580) / 2, _
        $WS_OVERLAPPEDWINDOW + $WS_VISIBLE + $WS_CLIPSIBLINGS + $WS_CLIPCHILDREN)
$GUIActiveX = GUICtrlCreateObj($oIE, 10, 40, 600, 360)
$GUI_Input = GUICtrlCreateInput("http://www.baidu.com",20,420,400,20)
$GUI_Button_Go = GUICtrlCreateButton("Go", 430, 420, 50, 20)
$GUI_Button_Back = GUICtrlCreateButton("Back", 10, 470, 100, 30)
$GUI_Button_Forward = GUICtrlCreateButton("Forward", 120, 470, 100, 30)
$GUI_Button_Home = GUICtrlCreateButton("Home", 230, 470, 100, 30)
$GUI_Button_Stop = GUICtrlCreateButton("Stop", 340, 470, 100, 30)




GUISetState()       ;Show GUI

_IENavigate ($oIE, "http://www.baidu.com")

; Waiting for user to close the window
While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $GUI_Button_Home
            _IENavigate ($oIE, "http://www.baidu.com")
        Case $msg = $GUI_Button_Back
            _IEAction ($oIE, "back")
        Case $msg = $GUI_Button_Forward
            _IEAction ($oIE, "forward")
        Case $msg = $GUI_Button_Stop
            _IEAction ($oIE, "stop")
                Case $msg = $GUI_Button_Go
                        _IENavigate ($oIE, GUICtrlRead($GUI_Input))
    EndSelect
WEnd

GUIDelete()

Exit

ningzhonghui

回复 2# ajian55


  可能是我没细心看，谢谢拉我会慢慢看研究去  随意在地址栏输入网址，打不开，有时打得开也好慢啊，这是为什么？