send按键问题

傻娃 · 发表于 2008-11-13 19:50:49

用send('^v')在游戏里连续粘贴的时候会失效，不粘贴。
在按键精灵里看到有个硬件模式，问一下AU3能不能实现硬件模式模拟按键？

如果用DLL 好心的大哥给发一下学习学习！

傻娃 · 发表于 2008-11-14 20:52:18

顶下

傻娃 · 发表于 2008-11-15 18:58:35

没有人回答么

liongodmien · 发表于 2008-11-16 15:05:27

尝试：SendKeepActive

jiangzhanye · 发表于 2008-11-16 15:11:25

实现自动按键的方法驱动级模拟(硬件模拟)

有些游戏直接用au3里面的模拟点击/按键都是无效的,包括qq2007也是无法实现,下面是一个解决方法,具体实现方法(vb的),想改成au3的,还没成功,有兴趣的朋友也来试试.
驱动级模拟

   如果上面的方法你都试过了，可是你发现目标程序却仍然顽固的不接受你模拟的消息，寒~~~~~~~~~还好，我还剩下最后一招，这就是驱动级模拟：直接读写键盘的硬件端口！
   有一些使用DirectX接口的游戏程序，它们在读取键盘操作时绕过了windows的消息机制，而使用DirectInput.这是因为有些游戏对实时性控制的要求比较高，比如赛车游戏，要求以最快速度响应键盘输入。而windows消息由于是队列形式的，消息在传递时会有不少延迟，有时1秒钟也就传递十几条消息，这个速度达不到游戏的要求。而DirectInput则绕过了windows消息，直接与键盘驱动程序打交道，效率当然提高了不少。因此也就造成，对这样的程序无论用PostMessage或者是keybd_event都不会有反应，因为这些函数都在较高层。对于这样的程序，只好用直接读写键盘端口的方法来模拟硬件事件了。要用这个方法来模拟键盘，需要先了解一下键盘编程的相关知识。
   在DOS时代，当用户按下或者放开一个键时，就会产生一个键盘中断(如果键盘中断是允许的)，这样程序会跳转到BIOS中的键盘中断处理程序去执行。打开windows的设备管理器，可以查看到键盘控制器由两个端口控制。其中&H60是数据端口，可以读出键盘数据，而&H64是控制端口，用来发出控制信号。也就是，从&H60号端口可以读此键盘的按键信息，当从这个端口读取一个字节，该字节的低7位就是按键的扫描码，而高1位则表示是按下键还是释放键。当按下键时，最高位为0，称为通码，当释放键时，最高位为1，称为断码。既然从这个端口读数据可以获得按键信息，那么向这个端口写入数据就可以模拟按键了！用过QbASIC4.5的朋友可能知道，QB中有个OUT命令可以向指定端口写入数据，而INP函数可以读取指定端口的数据。那我们先看看如果用QB该怎么写代码：
假如你想模拟按下一个键，这个键的扫描码为&H50，那就这样
OUT &H64,&HD2 '把数据&HD2发送到&H64端口。这是一个KBC指令，表示将要向键盘写入数据
OUT &H60,&H50 '把扫描码&H50发送到&H60端口，表示模拟按下扫描码为&H50的这个键
那么要释放这个键呢？像这样，发送该键的断码：
OUT &H64,&HD2 '把数据&HD2发送到&H64端口。这是一个KBC指令，表示将要向键盘写入数据
OUT &H60,(&H50 OR &H80) '把扫描码&H50与数据&H80进行或运算，可以把它的高位置1，得到断码，表示释放这个键
2007-4-19 02:08 wyh1983
好了，现在的问题就是在VB中如何向端口写入数据了。因为在windows中，普通应用程序是无权操作端口的，于是我们就需要一个驱动程序来帮助我们实现。在这里我们可以使用一个组件WINIO来完成读写端口操作。什么是WINIO？WINIO是一个全免费的、无需注册的、含源程序的WINDOWS2000端口操作驱动程序组件(可以到http://www.internals.com/上去下载)。它不仅可以操作端口，还可以操作内存；不仅能在VB下用，还可以在DELPHI、VC等其它环境下使用，性能特别优异。下载该组件，解压缩后可以看到几个文件夹，其中Release文件夹下的3个文件就是我们需要的，这3个文件是WinIo.sys(用于win xp下的驱动程序)，WINIO.VXD(用于win 98下的驱动程序)，WinIo.dll(封装函数的动态链接库)，我们只需要调用WinIo.dll中的函数，然后WinIo.dll就会安装并调用驱动程序来完成相应的功能。值得一提的是这个组件完全是绿色的，无需安装，你只需要把这3个文件复制到与你的程序相同的文件夹下就可以使用了。用法很简单，先用里面的InitializeWinIo函数安装驱动程序，然后就可以用GetPortVal来读取端口或者用SetPortVal来写入端口了。好，让我们来做一个驱动级的键盘模拟吧。先把winio的3个文件拷贝到你的程序的文件夹下，然后在VB中新建一个工程，添加一个模块，在模块中加入下面的winio函数声明eclare Function MapPhysToLin Lib "WinIo.dll" (ByVal PhysAddr As Long, ByVal PhysSize As Long, ByRef PhysMemHandle) As Long
Declare Function UnmapPhysicalMemory Lib "WinIo.dll" (ByVal PhysMemHandle, ByVal LinAddr) As Boolean
Declare Function GetPhysLong Lib "WinIo.dll" (ByVal PhysAddr As Long, ByRef PhysVal As Long) As Boolean
Declare Function SetPhysLong Lib "WinIo.dll" (ByVal PhysAddr As Long, ByVal PhysVal As Long) As Boolean
Declare Function GetPortVal Lib "WinIo.dll" (ByVal PortAddr As Integer, ByRef PortVal As Long, ByVal bSize As Byte) As Boolean
Declare Function SetPortVal Lib "WinIo.dll" (ByVal PortAddr As Integer, ByVal PortVal As Long, ByVal bSize As Byte) As Boolean
Declare Function InitializeWinIo Lib "WinIo.dll" () As Boolean
Declare Function ShutdownWinIo Lib "WinIo.dll" () As Boolean
Declare Function InstallWinIoDriver Lib "WinIo.dll" (ByVal DriverPath As String, ByVal Mode As Integer) As Boolean
Declare Function RemoveWinIoDriver Lib "WinIo.dll" () As Boolean
' ------------------------------------以上是WINIO函数声明-------------------------------------------
Declare Function MapVirtualKey Lib "user32" Alias "MapVirtualKeyA" (ByVal wCode As Long, ByVal wMapType As Long) As Long
'-----------------------------------以上是WIN32 API函数声明-----------------------------------------
再添加下面这个过程：
Sub KBCWait4IBE() '等待键盘缓冲区为空
Dim dwVal As Long
Do
GetPortVal &H64, dwVal, 1
'这句表示从&H64端口读取一个字节并把读出的数据放到变量dwVal中
'GetPortVal函数的用法是GetPortVal 端口号,存放读出数据的变量,读入的长度
Loop While (dwVal And &H2)
End Sub
上面的是一个根据KBC规范写的过程，它的作用是在向键盘端口写入数据前等待一段时间，后面将会用到。
然后再添加如下过程，这2个过程用来模拟按键：
Public Const KBC_KEY_CMD = &H64    '键盘命令端口
Public Const KBC_KEY_DATA = &H60 '键盘数据端口
Sub MyKeyDown(ByVal vKeyCoad As Long)
'这个用来模拟按下键，参数vKeyCoad传入按键的虚拟码
Dim btScancode As Long
btScancode = MapVirtualKey(vKeyCoad, 0)

   KBCWait4IBE '发送数据前应该先等待键盘缓冲区为空
   SetPortVal KBC_KEY_CMD, &HD2, 1    '发送键盘写入命令
'SetPortVal函数用于向端口写入数据，它的用法是SetPortVal 端口号,欲写入的数据，写入数据的长度
   KBCWait4IBE
   SetPortVal KBC_KEY_DATA, btScancode, 1 '写入按键信息,按下键

End Sub
Sub MyKeyUp(ByVal vKeyCoad As Long)
'这个用来模拟释放键，参数vKeyCoad传入按键的虚拟码
Dim btScancode As Long
btScancode = MapVirtualKey(vKeyCoad, 0)

   KBCWait4IBE '等待键盘缓冲区为空
   SetPortVal KBC_KEY_CMD, &HD2, 1 '发送键盘写入命令
   KBCWait4IBE
   SetPortVal KBC_KEY_DATA, (btScancode Or &H80), 1 '写入按键信息，释放键
End Sub

定义了上面的过程后，就可以用它来模拟键盘输入了。在窗体模块中添加一个定时器控件，然后加入以下代码：

Private Sub Form_Load()
If InitializeWinIo = False Then
'用InitializeWinIo函数加载驱动程序，如果成功会返回true，否则返回false
   MsgBox "驱动程序加载失败!"
   Unload Me
End If
Timer1.Interval=3000
Timer1.Enabled=True
End Sub
Private Sub Form_Unload(Cancel As Integer)
ShutdownWinIo '程序结束时记得用ShutdownWinIo函数卸载驱动程序
End Sub
Private Sub Timer1_Timer()
Dim VK_A as Long = &H41
MyKeyDown VK_A
MyKeyUp VK_A    '模拟按下并释放A键
End Sub
[/quote]
运行上面的程序，就会每隔3秒钟模拟按下一次A键，试试看，怎么样，是不是对所有程序都有效果了？
需要注意的问题：
要在VB的调试模式下使用WINIO，需要把那3个文件拷贝到VB的安装目录中。
键盘上有些键属于扩展键(比如键盘上的方向键就是扩展键)，对于扩展键不应该用上面的MyKeyDown和MyKeyUp过程来模拟，可以使用下面的2个过程来准确模拟扩展键：

QUOTE:
Sub MyKeyDownEx(ByVal vKeyCoad As Long) '模拟扩展键按下，参数vKeyCoad是扩展键的虚拟码
Dim btScancode As Long
btScancode = MapVirtualKey(vKeyCoad, 0)
   KBCWait4IBE '等待键盘缓冲区为空
   SetPortVal KBC_KEY_CMD, &HD2, 1    '发送键盘写入命令
   KBCWait4IBE
   SetPortVal KBC_KEY_DATA, &HE0, 1 '写入扩展键标志信息

   KBCWait4IBE '等待键盘缓冲区为空
   SetPortVal KBC_KEY_CMD, &HD2, 1    '发送键盘写入命令
   KBCWait4IBE
   SetPortVal KBC_KEY_DATA, btScancode, 1 '写入按键信息,按下键

End Sub

Sub MyKeyUpEx(ByVal vKeyCoad As Long) '模拟扩展键弹起
Dim btScancode As Long
btScancode = MapVirtualKey(vKeyCoad, 0)
   KBCWait4IBE '等待键盘缓冲区为空
   SetPortVal KBC_KEY_CMD, &HD2, 1    '发送键盘写入命令
   KBCWait4IBE
   SetPortVal KBC_KEY_DATA, &HE0, 1 '写入扩展键标志信息

   KBCWait4IBE '等待键盘缓冲区为空
   SetPortVal KBC_KEY_CMD, &HD2, 1    '发送键盘写入命令
   KBCWait4IBE
   SetPortVal KBC_KEY_DATA, (btScancode Or &H80), 1 '写入按键信息，释放键

End Sub
还应该注意的是，如果要从扩展键转换到普通键，那么普通键的KeyDown事件应该发送两次。也就是说，如果我想模拟先按下一个扩展键，再按下一个普通键，那么就应该向端口发送两次该普通键被按下的信息。比如，我想模拟先按下左方向键，再按下空格键这个事件，由于左方向键是扩展键，空格键是普通键，那么流程就应该是这样的：
[quote]MyKeyDownEx VK_LEFT '按下左方向键
Sleep 200             '延时200毫秒
MyKeyUpEx VK_LEFT    '释放左方向键
Sleep 500
MyKeyDown VK_SPACE '按下空格键，注意要发送两次
MyKeyDown VK_SPACE
Sleep 200
MyKeyUp VK_SPACE    '释放空格键

好了，相信到这里，你的模拟按键程序也就差不多了，测试一下，是不是很有效呢，嘿嘿~~~~
WINIO组件的下载地址(官方)：http://www.internals.com/utilities/winio.zip

zhs800 · 发表于 2009-10-7 11:00:31

驱动级模拟InitializeWinIo()加载驱动不成功

$hdll = DllOpen("winio.dll")

If $hdll = -1 Then

        MsgBox(0, "错误", "打开winio.dll文件出错")

EndIf

$return = DllCall($hdll, "int", "InitializeWinIo")

If @error <> 0 Then

        MsgBox(0, "错误", "安装winio.sys文件出错" & @error)

EndIf

If Not $return[0] Then

        MsgBox(0, "错误", "InitializeWinIo()加载驱动不成功")

EndIf

复制代码winio的三个文件我都就在了程序文件夹中了，可就是InitializeWinIo()加载驱动不成功。
有没有高手可以指点一二？

ainizm · 发表于 2009-10-7 12:02:43

这个问题我也一直没搞明白，高手出来放点水，普度一下大众

sunafter · 发表于 2009-10-7 12:45:47

同学习学习

ZEROBOYS · 发表于 2009-10-9 04:53:53

也好奇此文章...但願能學到東西

		自动登录	找回密码
密码			加入

send按键问题

相关帖子