请教如何让GUICtrlCreateEdit编辑框填充内容右侧滚动条自动下移？

smooth

在默认的情况下，往GUICtrlCreateEdit动态的填充内容时，右侧的滚动条会往上走，强行用鼠标按住下拉都拉不动它，有没有办法让它往下走？这样的目的是可以看到最新的填充内容。或者让它别自己动，让用户自己去拖动滚动条来查看编辑框中的内容。谢谢！

afan

2# 禁言一周，下次永久禁言。

lanfengc

回复 1# smooth


    如下代码: (主要是函数 _GUICtrlEdit_AppendText 的应用)

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiEdit.au3>
Opt("GUIOnEventMode", 1)
Global $start=False
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Edit显示例子", 365, 532, 192, 114)
GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
$Edit1 = GUICtrlCreateEdit("", 8, 8, 353, 409)
$Button1 = GUICtrlCreateButton("Start", 96, 448, 153, 49)
GUICtrlSetOnEvent(-1, "Button1Click")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
        Sleep(500)
        If $start Then _GUICtrlEdit_AppendText($Edit1,"my test text"&Random()&@CRLF)
WEnd

Func Button1Click()
        $start=Not $start
        If $start Then
                GUICtrlSetData($Button1,"Stop")
        Else
                GUICtrlSetData($Button1,"Start")
        EndIf
EndFunc

Func Form1Close()
        Exit
EndFunc

smooth

回复 4# lanfengc

兄弟，谢谢！要的就是这样的效果。我再仔细研究研究，不懂再请教你，希望你别嫌我烦。^^

chzj589

回复 4# lanfengc
谢谢，学习了