[已解决]学习GUIRegisterMsg和window消息代码管理的时候 遇到困难 求助

cumtljj

Global Const $WA_ACTIVE = 1
Global Const $WA_CLICKACTIVE = 2
Global Const $WA_INACTIVE = 0
Global $k = 0
$Gui = GUICreate("WM_ACTIVATE", 550, 140)
GUICtrlCreateLabel('活动窗口发生 WM_ACTIVATE 消息 (最小化, 其它窗口激活).', 5, 5, 360, 130)
GUISetState()
GUIRegisterMsg(0x0006, "WM_ACTIVATE")
Do
Until GUIGetMsg() = -3
Func WM_ACTIVATE($hWnd, $Msg, $wParam, $lParam)
    Local $Active, $Minimized
    $Active = BitAND($wParam, 0xFFFF) ; _WinAPI_LoWord 低位字
    $Minimized = BitShift($wParam, 16) ; _WinAPI_HiWord 高位字
    $k += 1
    If $Minimized Then
        ToolTip('最小化 = ' & $lParam, Default, Default, '最小化', 1, 4 + 1)
    Else
        ToolTip('')
    EndIf
    WinSetTitle($Gui, '', '调用次数: ' & $k & '  标志: 激活 = ' & $Active & ', 最小化 = ' & $Minimized)
EndFunc

第十一行的四个参数中$wParam, $lParam 应该是由
WM_ACTIVATE 这一个系统消息获得的 但是前两个是怎么获得的呢 在整个代码中也没有为其赋值 它就怎么知道我操作的就是哪一个窗口了呢？

cumtljj

自己顶上去啊

seniors

WM_ACTIVATE($hWnd, $Msg, $wParam, $lParam)是由GUIRegisterMsg(0x0006, "WM_ACTIVATE")注册的
所以
1、$hWnd必定是你的程序中的窗体句柄，如果你的程序中有多个窗体，你应该在函数中加以判断
2、$Msg一定等于0x0006，因为GUIRegisterMsg(0x0006, "WM_ACTIVATE")就是当有0x0006消息时，让WM_ACTIVATE函数处理

cumtljj

回复 3# seniors


    你这么一说我恍然大悟 但是对于你是的第一点中的多窗口的话那如何进行判断呢？谢谢

seniors

Global Const $WA_ACTIVE = 1
Global Const $WA_CLICKACTIVE = 2
Global Const $WA_INACTIVE = 0
Global $k = 0, $j = 0
$Gui = GUICreate("WM_ACTIVATE", 550, 140, 200, 100)
GUICtrlCreateLabel('活动窗口发生 WM_ACTIVATE 消息 (最小化, 其它窗口激活).', 5, 5, 360, 130)
GUISetState()
$Gui2 = GUICreate("WM_ACTIVATE2", 550, 140, 200, 300)
GUICtrlCreateLabel('活动窗口发生 WM_ACTIVATE 消息 (最小化, 其它窗口激活).', 5, 5, 360, 130)
GUISetState()
GUIRegisterMsg(0x0006, "WM_ACTIVATE")
Do
Until GUIGetMsg() = -3
Func WM_ACTIVATE($hWnd, $Msg, $wParam, $lParam)
    Local $Active, $Minimized
    $Active = BitAND($wParam, 0xFFFF) ; _WinAPI_LoWord 低位字
    $Minimized = BitShift($wParam, 16) ; _WinAPI_HiWord 高位字
        Switch $Active
                Case $WA_ACTIVE
                        $out = " 通过鼠标以外的工具（如键盘）激活了该窗口"
                Case $WA_CLICKACTIVE
                        $out = " 鼠标激活窗口"
                Case  $WA_INACTIVE
                        $out = " 取消窗口激活"
        EndSwitch
        
    If $hWnd = $Gui Then 
                $k += 1
                WinSetTitle($Gui, '', '窗口一调用次数: ' & $k & $out)
        EndIf
        If $hWnd = $Gui2 Then 
                $j += 1
                WinSetTitle($Gui2, '', '窗口二调用次数: ' & $j & $out)
        EndIf
EndFunc

cumtljj

回复 3# seniors
你好 我现在又有了一个问题，希望你能再帮我看看， 如果按你说的 $hWnd 和$lParam 的返回值都应该是窗口句柄 只不过$lParam是由WM_ACTIVATE系统消息获得的，我测试了一下 这两个值为什么不一样呢？实际测试的时候$lParam每次都会变的 这又是为什么呢？

测试代码如下：

Global Const $WA_ACTIVE = 1
Global Const $WA_CLICKACTIVE = 2
Global Const $WA_INACTIVE = 0
Global $k = 0
$Gui = GUICreate("WM_ACTIVATE", 550, 140)
GUICtrlCreateLabel('活动窗口发生 WM_ACTIVATE 消息 (最小化, 其它窗口激活).', 5, 5, 360, 130)
GUISetState()
GUIRegisterMsg(163, "WM_ACTIVATE")
Do
Until GUIGetMsg() = -3
Func WM_ACTIVATE($hWnd, $Msg, $wParam, $lParam)
   MsgBox(0,"",$hWnd&@CRLF&$lParam)
EndFunc

163——表示的是点击窗口非客户区

seniors

163——表示的是双击非客户区
一般这样写GUIRegisterMsg(163, "WM_NCLBUTTONDBLCLK")
WM_NCLBUTTONDBLCLK消息的$lParam是鼠标双击时的屏幕坐标，不是窗口句柄了

cumtljj

回复 7# seniors


    即使是WM_ACTIVATE 这个系统消息的话如果点最小化 $hWnd和$lParam也不一样啊 $lParam这个在帮助里解释的是窗口句柄的啊

seniors

找到原因，WM_ACTIVATE消息的lPARAM值，如果你的程序是单窗口的话，lPARAM是空
如果是多窗口的则：
如果wPARAM值为$WA_INACTIVE；则lPARAM值是要激活窗口的句柄
如果wPARAM值为$WA_ACTIVE或$WA_CLICKACTIVE；则lPARAM值是要取消激活窗口的句柄

cumtljj

回复 9# seniors


   谢谢指点