找回密码
 加入
搜索
AUTOIT CN»论坛 › AU3交流 › 『 提问交流 』 › 已解决问题区 › [已解决]给窗口添加滚动条后调整控件位置出错的问题，求 ...
12下一页
返回列表 发新帖
查看: 5777|回复: 19

[AU3基础] [已解决]给窗口添加滚动条后调整控件位置出错的问题，求解！

[复制链接]
水木子
发表于 2018-8-7 11:35:14 | 显示全部楼层 |阅读模式
本帖最后由 水木子 于 2018-8-7 15:08 编辑

我先说明下情况：
给窗口添加滚动条，滑动滚动条，点击 Button2 调整 Button1 的位置，不难发现 Button1 的位置出错。
经过我反复测试发现应该是 _GUIScrollBars_ScrollWindow 滚动指定窗口客户区这个函数造成的，请问该如何解决？谢谢！
测试代码如下：

#include <GuiScrollBars.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGui1 = GUICreate('', 400, 300)
GUISetBkColor(0x88AABB)
$Button1 = GUICtrlCreateButton('Button1', 80, 100, 100, 30)
$Button2 = GUICtrlCreateButton('Button2', 250, 100, 100, 30)

GUIRegisterMsg($WM_VSCROLL, 'WM_VSCROLL')
GUIRegisterMsg($WM_MOUSEWHEEL, 'WM_MOUSEWHEEL')
GUISetState()

_GUIScrollBars_Init($hGui1)
_GUIScrollBars_SetScrollRange($hGui1, $SB_VERT, 0, 50)

While 1
        $hGUIMsg = GUIGetMsg()

        Switch $hGUIMsg
                Case -3
                        Exit
                        
                Case $Button1                        
                        
                Case $Button2
;~                         $iPos = _GUIScrollBars_GetScrollInfoPos($hGui1, $SB_VERT)
                        GUICtrlSetPos($Button1, Default, 100)
        EndSwitch
WEnd

Func WM_VSCROLL($hWnd, $iMsg, $wParam, $lParam) ;垂直滚动
        #forceref $iMsg, $wParam, $lParam
        Local $iScrollCode = BitAND($wParam, 0x0000FFFF)
        Local $iIndex = -1, $iCharY, $iPosY
        Local $iMin, $iMax, $iPage, $iPos, $iTrackPos

        For $x = 0 To UBound($__g_aSB_WindowInfo) - 1
                If $__g_aSB_WindowInfo[$x][0] = $hWnd Then
                        $iIndex = $x
                        $iCharY = $__g_aSB_WindowInfo[$iIndex][3]
                        ExitLoop
                EndIf
        Next
        If $iIndex = -1 Then Return 0

        ; 获取垂直滚动条所有信息
        Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_VERT)
        $iMin = DllStructGetData($tSCROLLINFO, 'nMin')
        $iMax = DllStructGetData($tSCROLLINFO, 'nMax')
        $iPage = DllStructGetData($tSCROLLINFO, 'nPage')
        ; 保存位置以后进行比较
        $iPosY = DllStructGetData($tSCROLLINFO, 'nPos')
        $iPos = $iPosY
        $iTrackPos = DllStructGetData($tSCROLLINFO, 'nTrackPos')

        Switch $iScrollCode
                Case $SB_TOP ; 用户点击键盘 HOME 键
                        DllStructSetData($tSCROLLINFO, 'nPos', $iMin)

                Case $SB_BOTTOM ; 用户点击键盘 END 键
                        DllStructSetData($tSCROLLINFO, 'nPos', $iMax)

                Case $SB_LINEUP ; 用户点击向上箭头
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos - 1)

                Case $SB_LINEDOWN ; 用户点击底部向下箭头
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos + 1)

                Case $SB_PAGEUP ; 用户点击滚动框内滚动条的上面
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos - $iPage)

                Case $SB_PAGEDOWN ; 用户点击滚动框内滚动条的下面
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos + $iPage)

                Case $SB_THUMBTRACK ; 用户拖动滚动条
                        DllStructSetData($tSCROLLINFO, 'nPos', $iTrackPos)
        EndSwitch

        ; // 设置的位置，然后检索它,
        ; //   因 Windows 的原因,设定值可能不相同.

        DllStructSetData($tSCROLLINFO, 'fMask', $SIF_POS)
        _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        _GUIScrollBars_GetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        ;// 如果位置发生了变化, 则滚动窗口并更新
        $iPos = DllStructGetData($tSCROLLINFO, 'nPos')

        If ($iPos <> $iPosY) Then
                _GUIScrollBars_ScrollWindow($hWnd, 0, $iCharY * ($iPosY - $iPos))
                $iPosY = $iPos
        EndIf

        Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_VSCROLL

Func WM_MOUSEWHEEL($hWnd, $iMsg, $wParam, $lParam) ;设置滚动条鼠标滑轮
        #forceref $hWnd, $iMsg, $lParam
        Local $updown = BitShift($wParam, 16)
        $updown = $updown / 120
        Local $iIndex = -1, $iCharY, $iPosY
        Local $iMin, $iMax, $iPage, $iPos, $iTrackPos
        For $x = 0 To UBound($__g_aSB_WindowInfo) - 1
                If $__g_aSB_WindowInfo[$x][0] = $hWnd Then
                        $iIndex = $x
                        $iCharY = $__g_aSB_WindowInfo[$iIndex][3]
                        ExitLoop
                EndIf
        Next
        If $iIndex = -1 Then Return 0
        Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_VERT)
        $iMin = DllStructGetData($tSCROLLINFO, 'nMin')
        $iMax = DllStructGetData($tSCROLLINFO, 'nMax')
        $iPage = DllStructGetData($tSCROLLINFO, 'nPage')
        $iPosY = DllStructGetData($tSCROLLINFO, 'nPos')
        $iPos = $iPosY
        $iTrackPos = DllStructGetData($tSCROLLINFO, 'nTrackPos')
        DllStructSetData($tSCROLLINFO, 'nPos', $iPos - $updown)
        DllStructSetData($tSCROLLINFO, 'fMask', $SIF_POS)
        _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        _GUIScrollBars_GetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        $iPos = DllStructGetData($tSCROLLINFO, 'nPos')
        If ($iPos <> $iPosY) Then
                _GUIScrollBars_ScrollWindow($hWnd, 0, $iCharY * ($iPosY - $iPos))
                $iPosY = $iPos
        EndIf
        Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_MOUSEWHEEL

回复

举报

Au3代码高亮发贴标签： [AU3] 你的代码 [/AU3]                   支持论坛的发展，请添加此》》网址导航《《为您的主页          
水木子
 楼主| 发表于 2018-8-7 11:49:47 | 显示全部楼层
已经变相解决了。
谁有解决方法，欢迎指教，谢谢！
回复

举报

afan
发表于 2018-8-7 13:05:19 | 显示全部楼层
_GUIScrollBars_Init() 初始化之后就会影响控件的相对坐标
可以在创建窗口前加 Opt('GUIResizeMode', 802) 试试~

评分

参与人数 1金钱 +100 收起 理由
水木子 + 100 学到了。

查看全部评分

回复

举报

chzj589
发表于 2018-8-7 14:44:48 | 显示全部楼层
是不是这样子

#include <GuiScrollBars.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGui1 = GUICreate('', 400, 300)
GUISetBkColor(0x88AABB)
$Button1 = GUICtrlCreateButton('Button1', 80, 100, 100, 30)
$Button2 = GUICtrlCreateButton('Button2', 250, 100, 100, 30)
GUIRegisterMsg($WM_SIZE, "WM_SIZE")
GUIRegisterMsg($WM_HSCROLL, "WM_HSCROLL")
GUIRegisterMsg($WM_VSCROLL, 'WM_VSCROLL')
GUIRegisterMsg($WM_MOUSEWHEEL, 'WM_MOUSEWHEEL')
GUISetState()

_GUIScrollBars_Init($hGui1)
_GUIScrollBars_SetScrollRange($hGui1, $SB_VERT, 0, 50)
_GUIScrollBars_SetScrollRange($hGui1, $SB_HORZ, 0, 50) ;设置水平滚动条参数
While 1
        $hGUIMsg = GUIGetMsg()

        Switch $hGUIMsg
                Case -3
                        Exit

                Case $Button1
                        GUICtrlSetPos($Button2, Default, 100)
                Case $Button2
;~                         $iPos = _GUIScrollBars_GetScrollInfoPos($hGui1, $SB_VERT)
                        GUICtrlSetPos($Button1, Default, 100)
        EndSwitch
WEnd

Func WM_VSCROLL($hWnd, $iMsg, $wParam, $lParam) ;垂直滚动
        #forceref $iMsg, $wParam, $lParam
        Local $iScrollCode = BitAND($wParam, 0x0000FFFF)
        Local $iIndex = -1, $iCharY, $iPosY
        Local $iMin, $iMax, $iPage, $iPos, $iTrackPos

        For $x = 0 To UBound($__g_aSB_WindowInfo) - 1
                If $__g_aSB_WindowInfo[$x][0] = $hWnd Then
                        $iIndex = $x
                        $iCharY = $__g_aSB_WindowInfo[$iIndex][3]
                        ExitLoop
                EndIf
        Next
        If $iIndex = -1 Then Return 0

        ; 获取垂直滚动条所有信息
        Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_VERT)
        $iMin = DllStructGetData($tSCROLLINFO, 'nMin')
        $iMax = DllStructGetData($tSCROLLINFO, 'nMax')
        $iPage = DllStructGetData($tSCROLLINFO, 'nPage')
        ; 保存位置以后进行比较
        $iPosY = DllStructGetData($tSCROLLINFO, 'nPos')
        $iPos = $iPosY
        $iTrackPos = DllStructGetData($tSCROLLINFO, 'nTrackPos')

        Switch $iScrollCode
                Case $SB_TOP ; 用户点击键盘 HOME 键
                        DllStructSetData($tSCROLLINFO, 'nPos', $iMin)

                Case $SB_BOTTOM ; 用户点击键盘 END 键
                        DllStructSetData($tSCROLLINFO, 'nPos', $iMax)

                Case $SB_LINEUP ; 用户点击向上箭头
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos - 1)

                Case $SB_LINEDOWN ; 用户点击底部向下箭头
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos + 1)

                Case $SB_PAGEUP ; 用户点击滚动框内滚动条的上面
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos - $iPage)

                Case $SB_PAGEDOWN ; 用户点击滚动框内滚动条的下面
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos + $iPage)

                Case $SB_THUMBTRACK ; 用户拖动滚动条
                        DllStructSetData($tSCROLLINFO, 'nPos', $iTrackPos)
        EndSwitch

        ; // 设置的位置，然后检索它,
        ; //   因 Windows 的原因,设定值可能不相同.

        DllStructSetData($tSCROLLINFO, 'fMask', $SIF_POS)
        _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        _GUIScrollBars_GetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        ;// 如果位置发生了变化, 则滚动窗口并更新
        $iPos = DllStructGetData($tSCROLLINFO, 'nPos')

        If ($iPos <> $iPosY) Then
                _GUIScrollBars_ScrollWindow($hWnd, 0, $iCharY * ($iPosY - $iPos))
                $iPosY = $iPos
        EndIf

        Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_VSCROLL
Func WM_SIZE($hWnd, $iMsg, $wParam, $lParam)
        #forceref $iMsg, $wParam
        Local $iIndex = -1, $iCharY, $iCharX, $iClientMaxX, $iClientX, $iClientY, $iMax
        For $x = 0 To UBound($__g_aSB_WindowInfo) - 1
                If $__g_aSB_WindowInfo[$x][0] = $hWnd Then
                        $iIndex = $x
                        $iClientMaxX = $__g_aSB_WindowInfo[$iIndex][1]
                        $iCharX = $__g_aSB_WindowInfo[$iIndex][2]
                        $iCharY = $__g_aSB_WindowInfo[$iIndex][3]
                        $iMax = $__g_aSB_WindowInfo[$iIndex][7]
                        ExitLoop
                EndIf
        Next
        If $iIndex = -1 Then Return 0

        Local $tSCROLLINFO = DllStructCreate($tagSCROLLINFO)

        ; 检索客户区尺寸.
        $iClientX = BitAND($lParam, 0x0000FFFF)
        $iClientY = BitShift($lParam, 16)
        $__g_aSB_WindowInfo[$iIndex][4] = $iClientX
        $__g_aSB_WindowInfo[$iIndex][5] = $iClientY

        ; 设置垂直滚动范围和页面大小
        DllStructSetData($tSCROLLINFO, "fMask", BitOR($SIF_RANGE, $SIF_PAGE))
        DllStructSetData($tSCROLLINFO, "nMin", 0)
        DllStructSetData($tSCROLLINFO, "nMax", $iMax)
        DllStructSetData($tSCROLLINFO, "nPage", $iClientY / $iCharY)
        _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)

        ; 设置水平滚动范围和页面大小
        DllStructSetData($tSCROLLINFO, "fMask", BitOR($SIF_RANGE, $SIF_PAGE))
        DllStructSetData($tSCROLLINFO, "nMin", 0)
        DllStructSetData($tSCROLLINFO, "nMax", 2 + $iClientMaxX / $iCharX)
        DllStructSetData($tSCROLLINFO, "nPage", $iClientX / $iCharX)
        _GUIScrollBars_SetScrollInfo($hWnd, $SB_HORZ, $tSCROLLINFO)

        Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_SIZE
Func WM_HSCROLL($hWnd, $iMsg, $wParam, $lParam)
        #forceref $iMsg, $lParam
        Local $iScrollCode = BitAND($wParam, 0x0000FFFF)

        Local $iIndex = -1, $iCharX, $iPosX
        Local $iMin, $iMax, $iPage, $iPos, $iTrackPos

        For $x = 0 To UBound($__g_aSB_WindowInfo) - 1
                If $__g_aSB_WindowInfo[$x][0] = $hWnd Then
                        $iIndex = $x
                        $iCharX = $__g_aSB_WindowInfo[$iIndex][2]
                        ExitLoop
                EndIf
        Next
        If $iIndex = -1 Then Return 0

        ; ; 获取所有的水平滚动条信息
        Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_HORZ)
        $iMin = DllStructGetData($tSCROLLINFO, "nMin")
        $iMax = DllStructGetData($tSCROLLINFO, "nMax")
        $iPage = DllStructGetData($tSCROLLINFO, "nPage")
        ; 保存位置以后进行比较
        $iPosX = DllStructGetData($tSCROLLINFO, "nPos")
        $iPos = $iPosX
        $iTrackPos = DllStructGetData($tSCROLLINFO, "nTrackPos")
        #forceref $iMin, $iMax
        Switch $iScrollCode

                Case $SB_LINELEFT ; 用户点击向左箭头
                        DllStructSetData($tSCROLLINFO, "nPos", $iPos - 1)

                Case $SB_LINERIGHT ; 用户点击向右箭头
                        DllStructSetData($tSCROLLINFO, "nPos", $iPos + 1)

                Case $SB_PAGELEFT ; 用户单击滚动条轴左侧
                        DllStructSetData($tSCROLLINFO, "nPos", $iPos - $iPage)

                Case $SB_PAGERIGHT ; 用户单击滚动条轴右侧
                        DllStructSetData($tSCROLLINFO, "nPos", $iPos + $iPage)

                Case $SB_THUMBTRACK ; 用户拖动滚动条
                        DllStructSetData($tSCROLLINFO, "nPos", $iTrackPos)
        EndSwitch

        ; // 设置的位置，然后检索它,
        ; //   因 Windows 的原因,设定值可能不相同.

        DllStructSetData($tSCROLLINFO, "fMask", $SIF_POS)
        _GUIScrollBars_SetScrollInfo($hWnd, $SB_HORZ, $tSCROLLINFO)
        _GUIScrollBars_GetScrollInfo($hWnd, $SB_HORZ, $tSCROLLINFO)
        ;// 如果位置发生了变化, 则滚动窗口并更新
        $iPos = DllStructGetData($tSCROLLINFO, "nPos")
        If ($iPos <> $iPosX) Then _GUIScrollBars_ScrollWindow($hWnd, $iCharX * ($iPosX - $iPos), 0)
        Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_HSCROLL
Func WM_MOUSEWHEEL($hWnd, $iMsg, $wParam, $lParam) ;设置滚动条鼠标滑轮
        #forceref $hWnd, $iMsg, $lParam
        Local $updown = BitShift($wParam, 16)
        $updown = $updown / 120
        Local $iIndex = -1, $iCharY, $iPosY
        Local $iMin, $iMax, $iPage, $iPos, $iTrackPos
        For $x = 0 To UBound($__g_aSB_WindowInfo) - 1
                If $__g_aSB_WindowInfo[$x][0] = $hWnd Then
                        $iIndex = $x
                        $iCharY = $__g_aSB_WindowInfo[$iIndex][3]
                        ExitLoop
                EndIf
        Next
        If $iIndex = -1 Then Return 0
        Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_VERT)
        $iMin = DllStructGetData($tSCROLLINFO, 'nMin')
        $iMax = DllStructGetData($tSCROLLINFO, 'nMax')
        $iPage = DllStructGetData($tSCROLLINFO, 'nPage')
        $iPosY = DllStructGetData($tSCROLLINFO, 'nPos')
        $iPos = $iPosY
        $iTrackPos = DllStructGetData($tSCROLLINFO, 'nTrackPos')
        DllStructSetData($tSCROLLINFO, 'nPos', $iPos - $updown)
        DllStructSetData($tSCROLLINFO, 'fMask', $SIF_POS)
        _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        _GUIScrollBars_GetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        $iPos = DllStructGetData($tSCROLLINFO, 'nPos')
        If ($iPos <> $iPosY) Then
                _GUIScrollBars_ScrollWindow($hWnd, 0, $iCharY * ($iPosY - $iPos))
                $iPosY = $iPos
        EndIf
        Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_MOUSEWHEEL

评分

参与人数 1金钱 +50 收起 理由
水木子 + 50 谢谢！

查看全部评分

回复

举报

水木子
 楼主| 发表于 2018-8-7 15:05:31 | 显示全部楼层
chzj589 发表于 2018-8-7 14:44
是不是这样子

谢谢你的回复，不过你可能没有明白我的意思。
你没发现滑动滚动条以后，再调整控件位置，控件位置不对吗？
回复

举报

水木子
 楼主| 发表于 2018-8-7 15:07:13 | 显示全部楼层
afan 发表于 2018-8-7 13:05
_GUIScrollBars_Init() 初始化之后就会影响控件的相对坐标
可以在创建窗口前加 Opt('GUIResizeMode', 802) ...

我晕哦！原来这么简单啊！感谢afan前辈的指点。
回复

举报

水木子
 楼主| 发表于 2018-8-7 15:08:58 | 显示全部楼层
本帖最后由 水木子 于 2018-8-7 15:15 编辑

问题已解决。我的解决方法如下：
#include <GuiScrollBars.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

;~ Opt('GUIResizeMode', 802)
Global $iYAmount

$hGui1 = GUICreate('', 400, 300)
GUISetBkColor(0x88AABB)
$Button1 = GUICtrlCreateButton('Button1', 80, 100, 100, 30)
$Button2 = GUICtrlCreateButton('Button2', 250, 100, 100, 30)

GUIRegisterMsg($WM_VSCROLL, 'WM_VSCROLL')
GUIRegisterMsg($WM_MOUSEWHEEL, 'WM_MOUSEWHEEL')
GUISetState()

_GUIScrollBars_Init($hGui1)
;~ _GUIScrollBars_SetScrollInfoPage($hGui1, $SB_VERT, 20)
_GUIScrollBars_SetScrollRange($hGui1, $SB_VERT, 0, 100)

$aPos = ControlGetPos($hGui1, '', $Button1)

While 1
        $hGUIMsg = GUIGetMsg()

        Switch $hGUIMsg
                Case -3
                        Exit
                        
                Case $Button1
                        
                        
                Case $Button2
                        $iPos = _GUIScrollBars_GetScrollInfoPos($hGui1, $SB_VERT)
                        GUICtrlSetPos($Button1, Default, $aPos[1] - $iPos * 16)
        EndSwitch
WEnd

Func WM_VSCROLL($hWnd, $iMsg, $wParam, $lParam) ;垂直滚动
        #forceref $iMsg, $wParam, $lParam
        Local $iScrollCode = BitAND($wParam, 0x0000FFFF)
        Local $iIndex = -1, $iCharY, $iPosY
        Local $iMin, $iMax, $iPage, $iPos, $iTrackPos

        For $x = 0 To UBound($__g_aSB_WindowInfo) - 1
                If $__g_aSB_WindowInfo[$x][0] = $hWnd Then
                        $iIndex = $x
                        $iCharY = $__g_aSB_WindowInfo[$iIndex][3]
                        ExitLoop
                EndIf
        Next
        If $iIndex = -1 Then Return 0

        ; 获取垂直滚动条所有信息
        Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_VERT)
        $iMin = DllStructGetData($tSCROLLINFO, 'nMin')
        $iMax = DllStructGetData($tSCROLLINFO, 'nMax')
        $iPage = DllStructGetData($tSCROLLINFO, 'nPage')
        ; 保存位置以后进行比较
        $iPosY = DllStructGetData($tSCROLLINFO, 'nPos')
        $iPos = $iPosY
        $iTrackPos = DllStructGetData($tSCROLLINFO, 'nTrackPos')

        Switch $iScrollCode
                Case $SB_TOP ; 用户点击键盘 HOME 键
                        DllStructSetData($tSCROLLINFO, 'nPos', $iMin)

                Case $SB_BOTTOM ; 用户点击键盘 END 键
                        DllStructSetData($tSCROLLINFO, 'nPos', $iMax)

                Case $SB_LINEUP ; 用户点击向上箭头
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos - 1)

                Case $SB_LINEDOWN ; 用户点击底部向下箭头
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos + 1)

                Case $SB_PAGEUP ; 用户点击滚动框内滚动条的上面
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos - $iPage)

                Case $SB_PAGEDOWN ; 用户点击滚动框内滚动条的下面
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos + $iPage)

                Case $SB_THUMBTRACK ; 用户拖动滚动条
                        DllStructSetData($tSCROLLINFO, 'nPos', $iTrackPos)
        EndSwitch

        ; // 设置的位置，然后检索它,
        ; //   因 Windows 的原因,设定值可能不相同.

        DllStructSetData($tSCROLLINFO, 'fMask', $SIF_POS)
        _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        _GUIScrollBars_GetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        ;// 如果位置发生了变化, 则滚动窗口并更新
        $iPos = DllStructGetData($tSCROLLINFO, 'nPos')

        If ($iPos <> $iPosY) Then
                _GUIScrollBars_ScrollWindow($hWnd, 0, $iCharY * ($iPosY - $iPos))
                $iPosY = $iPos
        EndIf

        Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_VSCROLL

Func WM_MOUSEWHEEL($hWnd, $iMsg, $wParam, $lParam) ;设置滚动条鼠标滑轮
        #forceref $hWnd, $iMsg, $lParam
        Local $updown = BitShift($wParam, 16)
        $updown = $updown / 120
        Local $iIndex = -1, $iCharY, $iPosY
        Local $iMin, $iMax, $iPage, $iPos, $iTrackPos
        For $x = 0 To UBound($__g_aSB_WindowInfo) - 1
                If $__g_aSB_WindowInfo[$x][0] = $hWnd Then
                        $iIndex = $x
                        $iCharY = $__g_aSB_WindowInfo[$iIndex][3]
                        ExitLoop
                EndIf
        Next
        If $iIndex = -1 Then Return 0
        Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_VERT)
        $iMin = DllStructGetData($tSCROLLINFO, 'nMin')
        $iMax = DllStructGetData($tSCROLLINFO, 'nMax')
        $iPage = DllStructGetData($tSCROLLINFO, 'nPage')
        $iPosY = DllStructGetData($tSCROLLINFO, 'nPos')
        $iPos = $iPosY
        $iTrackPos = DllStructGetData($tSCROLLINFO, 'nTrackPos')
        DllStructSetData($tSCROLLINFO, 'nPos', $iPos - $updown)
        DllStructSetData($tSCROLLINFO, 'fMask', $SIF_POS)
        _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        _GUIScrollBars_GetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        $iPos = DllStructGetData($tSCROLLINFO, 'nPos')
        If ($iPos <> $iPosY) Then
                _GUIScrollBars_ScrollWindow($hWnd, 0, $iCharY * ($iPosY - $iPos))
                $iPosY = $iPos
        EndIf
        Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_MOUSEWHEEL


回复

举报

水木子
 楼主| 发表于 2018-8-7 15:18:42 | 显示全部楼层
afan 发表于 2018-8-7 13:05
_GUIScrollBars_Init() 初始化之后就会影响控件的相对坐标
可以在创建窗口前加 Opt('GUIResizeMode', 802) ...

afan 老师，你这个方法我测试了，控件较少的时候，确实可以。
但是我在测试了大量空间的时候，还是会有问题。不知道什么原因。
用我在7楼的代码就没问题。
回复

举报

afan
发表于 2018-8-7 15:47:00 | 显示全部楼层
水木子 发表于 2018-8-7 15:18
afan 老师，你这个方法我测试了，控件较少的时候，确实可以。
但是我在测试了大量空间的时候，还是会有 ...

木子才是老师。不要闹~！
我是简单测试了一下，无实际代码测试，不知道大量控件的影响情况。其实适合自己用途的代码才是最优的，比如7#的。只是，由于我不知道你的实际情况，仅按解决代码看，既然没有移动位置，那是不是 GUICtrlSetPos($Button1, Default, Default) 就好了？
回复

举报

水木子
 楼主| 发表于 2018-8-7 16:15:03 | 显示全部楼层
afan 发表于 2018-8-7 15:47
木子才是老师。不要闹~！
我是简单测试了一下，无实际代码测试，不知道大量控件的影响情况。其实适合自 ...

前辈不好意思，怪我没把问题讲清楚，实际上是这样的。
我想要在有滚动条的窗口中交换多个控件的位置。代码如下：
#include <GuiScrollBars.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUICoordMode", 1)
Opt('GUIResizeMode', 802)

$hGui1 = GUICreate('', 400, 300)
GUISetBkColor(0x88AABB)
$Button1 = GUICtrlCreateButton('Button1', 80, 100, 100, 30)
$Button2 = GUICtrlCreateButton('Button2', 80, 350, 100, 30)
$Button3 = GUICtrlCreateButton('Button3', 250, 100, 100, 30)

GUIRegisterMsg($WM_VSCROLL, 'WM_VSCROLL')
GUIRegisterMsg($WM_MOUSEWHEEL, 'WM_MOUSEWHEEL')
GUISetState()

_GUIScrollBars_Init($hGui1)
_GUIScrollBars_SetScrollRange($hGui1, $SB_VERT, 0, 50)

;~ $aPos1 = ControlGetPos($hGui1, '', $Button1)
;~ $aPos2 = ControlGetPos($hGui1, '', $Button2)

While 1
        $hGUIMsg = GUIGetMsg()

        Switch $hGUIMsg
                Case -3
                        Exit
                        
                Case $Button1
                        
                        
                Case $Button3
;~                         $iPos = _GUIScrollBars_GetScrollInfoPos($hGui1, $SB_VERT)
                        GUICtrlSetPos($Button1, Default, 350)
                        GUICtrlSetPos($Button2, Default, 100)
        EndSwitch
WEnd

Func WM_VSCROLL($hWnd, $iMsg, $wParam, $lParam) ;垂直滚动
        #forceref $iMsg, $wParam, $lParam
        Local $iScrollCode = BitAND($wParam, 0x0000FFFF)
        Local $iIndex = -1, $iCharY, $iPosY
        Local $iMin, $iMax, $iPage, $iPos, $iTrackPos

        For $x = 0 To UBound($__g_aSB_WindowInfo) - 1
                If $__g_aSB_WindowInfo[$x][0] = $hWnd Then
                        $iIndex = $x
                        $iCharY = $__g_aSB_WindowInfo[$iIndex][3]
                        ExitLoop
                EndIf
        Next
        If $iIndex = -1 Then Return 0

        ; 获取垂直滚动条所有信息
        Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_VERT)
        $iMin = DllStructGetData($tSCROLLINFO, 'nMin')
        $iMax = DllStructGetData($tSCROLLINFO, 'nMax')
        $iPage = DllStructGetData($tSCROLLINFO, 'nPage')
        ; 保存位置以后进行比较
        $iPosY = DllStructGetData($tSCROLLINFO, 'nPos')
        $iPos = $iPosY
        $iTrackPos = DllStructGetData($tSCROLLINFO, 'nTrackPos')

        Switch $iScrollCode
                Case $SB_TOP ; 用户点击键盘 HOME 键
                        DllStructSetData($tSCROLLINFO, 'nPos', $iMin)

                Case $SB_BOTTOM ; 用户点击键盘 END 键
                        DllStructSetData($tSCROLLINFO, 'nPos', $iMax)

                Case $SB_LINEUP ; 用户点击向上箭头
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos - 1)

                Case $SB_LINEDOWN ; 用户点击底部向下箭头
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos + 1)

                Case $SB_PAGEUP ; 用户点击滚动框内滚动条的上面
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos - $iPage)

                Case $SB_PAGEDOWN ; 用户点击滚动框内滚动条的下面
                        DllStructSetData($tSCROLLINFO, 'nPos', $iPos + $iPage)

                Case $SB_THUMBTRACK ; 用户拖动滚动条
                        DllStructSetData($tSCROLLINFO, 'nPos', $iTrackPos)
        EndSwitch

        ; // 设置的位置，然后检索它,
        ; //   因 Windows 的原因,设定值可能不相同.

        DllStructSetData($tSCROLLINFO, 'fMask', $SIF_POS)
        _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        _GUIScrollBars_GetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        ;// 如果位置发生了变化, 则滚动窗口并更新
        $iPos = DllStructGetData($tSCROLLINFO, 'nPos')

        If ($iPos <> $iPosY) Then
                _GUIScrollBars_ScrollWindow($hWnd, 0, $iCharY * ($iPosY - $iPos))
                $iPosY = $iPos
        EndIf

        Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_VSCROLL

Func WM_MOUSEWHEEL($hWnd, $iMsg, $wParam, $lParam) ;设置滚动条鼠标滑轮
        #forceref $hWnd, $iMsg, $lParam
        Local $updown = BitShift($wParam, 16)
        $updown = $updown / 120
        Local $iIndex = -1, $iCharY, $iPosY
        Local $iMin, $iMax, $iPage, $iPos, $iTrackPos
        For $x = 0 To UBound($__g_aSB_WindowInfo) - 1
                If $__g_aSB_WindowInfo[$x][0] = $hWnd Then
                        $iIndex = $x
                        $iCharY = $__g_aSB_WindowInfo[$iIndex][3]
                        ExitLoop
                EndIf
        Next
        If $iIndex = -1 Then Return 0
        Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_VERT)
        $iMin = DllStructGetData($tSCROLLINFO, 'nMin')
        $iMax = DllStructGetData($tSCROLLINFO, 'nMax')
        $iPage = DllStructGetData($tSCROLLINFO, 'nPage')
        $iPosY = DllStructGetData($tSCROLLINFO, 'nPos')
        $iPos = $iPosY
        $iTrackPos = DllStructGetData($tSCROLLINFO, 'nTrackPos')
        DllStructSetData($tSCROLLINFO, 'nPos', $iPos - $updown)
        DllStructSetData($tSCROLLINFO, 'fMask', $SIF_POS)
        _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        _GUIScrollBars_GetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
        $iPos = DllStructGetData($tSCROLLINFO, 'nPos')
        If ($iPos <> $iPosY) Then
                _GUIScrollBars_ScrollWindow($hWnd, 0, $iCharY * ($iPosY - $iPos))
                $iPosY = $iPos
        EndIf
        Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_MOUSEWHEEL
回复

举报

afan
发表于 2018-8-7 16:28:50 | 显示全部楼层
水木子 发表于 2018-8-7 16:15
前辈不好意思，怪我没把问题讲清楚，实际上是这样的。
我想要在有滚动条的窗口中交换多个控件的位置。代 ...

交换不是这样吗？
$aPos1 = ControlGetPos($hGui1, '', $Button1)
$aPos2 = ControlGetPos($hGui1, '', $Button2)
GUICtrlSetPos($Button1, Default, $aPos2[1])
GUICtrlSetPos($Button2, Default, $aPos1[1])
回复

举报

水木子
 楼主| 发表于 2018-8-7 16:32:59 | 显示全部楼层
afan 发表于 2018-8-7 16:28
交换不是这样吗？
$aPos1 = ControlGetPos($hGui1, '', $Button1)
$aPos2 = ControlGetPos($hGui1, '', ...

对呀！但是你把滚动条往下拉点，再交换试试。
回复

举报

afan
发表于 2018-8-7 16:46:19 | 显示全部楼层
水木子 发表于 2018-8-7 16:32
对呀！但是你把滚动条往下拉点，再交换试试。

往下拉试了， 10#的是错位的。但是11#正常啊~
回复

举报

水木子
 楼主| 发表于 2018-8-7 16:50:10 | 显示全部楼层
afan 发表于 2018-8-7 16:46
往下拉试了， 10#的是错位的。但是11#正常啊~

我测试了 11#的方法，同样是错位的。
我想应该是 _GUIScrollBars_ScrollWindow 这个函数重新定义了窗口的客户区坐标。
回复

举报

afan
发表于 2018-8-7 17:05:19 | 显示全部楼层
水木子 发表于 2018-8-7 16:50
我测试了 11#的方法，同样是错位的。
我想应该是 _GUIScrollBars_ScrollWindow 这个函数重新定义了窗口 ...

除非你的代码不是这样，GetPos 之后进行了滚动操作~  如果GetPos、SetPos是连续的，客户区坐标不管怎么变， GetPos 获取的已经是改变后的，SetPos 应该就是正常的。
回复

举报

下一页 »
12下一页
返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 加入

本版积分规则

QQ|手机版|小黑屋|AUTOIT CN ( 鲁ICP备19019924号-1 )谷歌 百度

GMT+8, 2024-12-24 01:11 , Processed in 0.083259 second(s), 20 queries .

Powered by Discuz! X3.5 Licensed

© 2001-2024 Discuz! Team.

快速回复 返回顶部 返回列表