虚拟屏幕键盘的问题[已解决]

rhci

如题，开头一张图
简明扼要；
主要功能，点击左边区域的数字，出现在右边输入框中，点击配置文件生成写入指定路径中的文件。
可惜，思路正确，但是菜鸟一个，不会写关联代码，只能画个GUI了，哪位大神能帮忙完善下。

floor6ggg

纯体力活……………………
49行 更改为：$Input=GUICtrlCreateInput("", 384, 112, 225, 83)

初步的部分代码如下，还需要自己调整和完善

While 1
        $nMsg = GUIGetMsg()
        $Data=GUICtrlRead($Input)
        Switch $nMsg
                Case $GUI_EVENT_CLOSE
                        Exit

                Case $NUM9
                        GUICtrlSetData($Input,$Data &'9')
                Case $NUM8
                        GUICtrlSetData($Input,$Data &'8')
                ;类似的体力活..............
                Case $Button2;退格
                        GUICtrlSetData($Input,StringTrimRight($Data,1))
                Case $Button3;去除
                        GUICtrlSetData($Input,'')
                Case $Button1;
                        $INI = @ScriptDir & "\posid.ini"
                        IniWrite($INI, "字段", "关键字", $Data)

                Case $ook


        EndSwitch
WEnd

rhci

嗯嗯，感谢，抱得大腿，已编译投入使用中，源码稍后公开。

haijie1223

rhci 发表于 2020-7-1 23:34
源码来了。收费是对大神的尊重。

#NoTrayIcon
#PRE_UseX64=n
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=POSID.kxf
$POSID = GUICreate("POSID", 615, 437, 192, 124)
GUISetBkColor(0xABABAB)
Global $BtnNum[0xC], $Caption = ''
For $i = 1 To 0xC
        $Caption = 10 - $i
        If $i = 0xA Then $Caption = 'C'
        If $i = 0xB Then $Caption = 0
        If $i = 0xC Then $Caption = 'Back'
        $BtnNum[0xC - $i] = GUICtrlCreateButton($Caption, (48 + Mod($i - 1, 3) * 112), (48 + Floor(($i - 1) / 3) * 88), 81, 49)
        GUICtrlSetFont(-1, 16, 800, 0, "微软雅黑")
        GUICtrlSetColor(-1, 0x00FF00)
        GUICtrlSetCursor(-1, 0)
Next
$input = GUICtrlCreateInput("", 384, 96, 225, 83)
GUICtrlSetFont(-1, 42, 400, 0, "微软雅黑")
$ook = GUICtrlCreateLabel("请确认收银工号", 392, 64, 212, 20)
GUICtrlSetFont(-1, 12, 400, 0, "黑体")
$Button1 = GUICtrlCreateButton("配置文件生成", 408, 256, 169, 81)
GUICtrlSetFont(-1, 16, 800, 0, "微软雅黑")
GUICtrlSetColor(-1, 0xFF0000)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
                Case $GUI_EVENT_CLOSE
                        Exit
                Case $BtnNum[0xB] To $BtnNum[0]
                        GUICtrlSetData($input, StringIsDigit(GUICtrlRead($nMsg)) ? GUICtrlRead($input) & GUICtrlRead($nMsg) : ($nMsg  = $BtnNum[2] ? "" : StringTrimRight(GUICtrlRead($input), 1)))
                Case $Button1
                        IniWrite("路径", "项目", "关键字", GUICtrlRead($input))
                        MsgBox("64", "提醒", "配置文件已生成", 3)
        EndSwitch
WEnd

floor6ggg

haijie1223大神，厉害！

想到了0-9写入button的数组可以简化代码，没有想到另外的按键可以通过0xA-0xc的方式写入……………………
34行的代码，绝！
真没有想到一个简单的体力活可以玩出那么多的花样，膜拜！佩服！

rhci

牛P，我就删除源码了，采用大神的吧