treeview删除子项后前面加号不能自动清除的问题如何解决？[已解决]

cashiba

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
        Local $hItem, $hImage, $iImage, $idTreeView
        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

        GUICreate("TreeView Delete All", 400, 300)

        $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        $hImage = _GUIImageList_Create(16, 16, 5, 3)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
        _GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        For $x = 1 To 2
                $iImage = Random(0, 5, 1)
                $hItem = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x), $iImage, $iImage)
                For $y = 1 To 3
                        $iImage = Random(0, 5, 1)
                        _GUICtrlTreeView_AddChild($idTreeView, $hItem, StringFormat("[%02d] New Child", $y), $iImage, $iImage)
                Next
        Next
        _GUICtrlTreeView_EndUpdate($idTreeView)

        _GUICtrlTreeView_Expand($idTreeView)

        MsgBox($MB_SYSTEMMODAL, "Information", "Delete Children")
        _GUICtrlTreeView_DeleteChildren($idTreeView, $hItem)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>Example

treeview删除所有子项后，为什么项的前面还是有一个加号？
这个帖子里A大说删除后加一句 _GUICtrlTreeView_SetChildren($hTreeView, $hItem, 0)就可以解决了
但是试了下，没有效果。

看了下原码里已经添加了_GUICtrlTreeView_SetChildren。如下：

Func _GUICtrlTreeView_DeleteChildren($hWnd, $hItem)
        Local $bResult
        If IsHWnd($hWnd) Then
                $bResult = _SendMessage($hWnd, $TVM_EXPAND, BitOR($TVE_COLLAPSE, $TVE_COLLAPSERESET), $hItem, 0, "wparam", "handle")
        Else
                $bResult = GUICtrlSendMsg($hWnd, $TVM_EXPAND, BitOR($TVE_COLLAPSE, $TVE_COLLAPSERESET), $hItem)
        EndIf

        If $bResult Then _GUICtrlTreeView_SetChildren($hWnd, $hItem, False)

        Return $bResult
EndFunc   ;==>_GUICtrlTreeView_DeleteChildren

不知道问题出在哪里...

cashiba

Func _GUICtrlTreeView_SetChildren($hWnd, $hItem, $bFlag = True)
        ;Local $iCount = _GUICtrlTreeView_GetChildCount($hWnd, $hItem)
        ;If $iCount = -1 And $bFlag Then Return False
        ;If $iCount And Not $bFlag Then Return False

        If Not IsHWnd($hItem) Then $hItem = _GUICtrlTreeView_GetItemHandle($hWnd, $hItem)

        Local $tItem = $__g_tTVItemEx
        DllStructSetData($tItem, "Mask", BitOR($TVIF_HANDLE, $TVIF_CHILDREN))
        DllStructSetData($tItem, "hItem", $hItem)
        DllStructSetData($tItem, "Children", $bFlag)

        Return __GUICtrlTreeView_SetItem($hWnd, $tItem)
EndFunc   ;==>_GUICtrlTreeView_SetChildren

经过调试，发现把上述函数的前3行注释掉就可以了。
看样子是函数写得有点问题....
另外发现_GUICtrlTreeView_DeleteChildren($hWnd, $hItem)的返回值总是0/FALSE

cashiba

不知道现在用的autox是不是旧版本。也许是版本太旧了，新版本应该没问题吧

afan

cashiba 发表于 2024-1-17 15:53
不知道现在用的autox是不是旧版本。也许是版本太旧了，新版本应该没问题吧
...

应该是你用的太新了 _ _||
我测试了下 3.3.16.1 之前的版本都添加一行 _GUICtrlTreeView_SetChildren 就行

cashiba

Func _GUICtrlTreeView_DeleteChildren($hWnd, $hItem)
        Local $bResult
        If IsHWnd($hWnd) Then
                $bResult = _SendMessage($hWnd, $TVM_EXPAND, BitOR($TVE_COLLAPSE, $TVE_COLLAPSERESET), $hItem, 0, "wparam", "handle")
        Else
                $bResult = GUICtrlSendMsg($hWnd, $TVM_EXPAND, BitOR($TVE_COLLAPSE, $TVE_COLLAPSERESET), $hItem)
        EndIf

        If $bResult Then _GUICtrlTreeView_SetChildren($hWnd, $hItem, False)

        Return $bResult
EndFunc   ;==>_GUICtrlTreeView_DeleteChildren

Func _GUICtrlTreeView_SetChildren($hWnd, $hItem, $bFlag = True)
        ;Local $iCount = _GUICtrlTreeView_GetChildCount($hWnd, $hItem)
        ;If $iCount = -1 And $bFlag Then Return False
        ;If $iCount And Not $bFlag Then Return False

        If Not IsHWnd($hItem) Then $hItem = _GUICtrlTreeView_GetItemHandle($hWnd, $hItem)

        Local $tItem = $__g_tTVItemEx
        DllStructSetData($tItem, "Mask", BitOR($TVIF_HANDLE, $TVIF_CHILDREN))
        DllStructSetData($tItem, "hItem", $hItem)
        DllStructSetData($tItem, "Children", $bFlag)

        Return __GUICtrlTreeView_SetItem($hWnd, $tItem)
EndFunc   ;==>_GUICtrlTreeView_SetChildren

这样的话，问题应该出在上面注释掉的部分，最可能是
_GUICtrlTreeView_GetChildCount($hWnd, $hItem)
的返回值不对

或者
If $bResult Then _GUICtrlTreeView_SetChildren($hWnd, $hItem, False)
这行里的$bResult 非真，导致
_GUICtrlTreeView_SetChildren($hWnd, $hItem, False)
没执行...

afan

cashiba 发表于 2024-1-17 21:49
这样的话，问题应该出在上面注释掉的部分，最可能是
_GUICtrlTreeView_GetChildCount($hWnd, $hItem)
的返 ...

不要注释那三行，那样会有其它问题。
不过该函数确实有错误，将第三行的
If $iCount And Not $bFlag Then Return False
改为
If $iCount > 0 And Not $bFlag Then Return False
即可

cashiba

afan 发表于 2024-1-17 23:07
不要注释那三行，那样会有其它问题。
不过该函数确实有错误，将第三行的
If $iCount And Not $bFlag Then ...

谢谢A大解答!
另外，测试发现_GUICtrlTreeView_DeleteChildren($hWnd, $hItem)的返回值总是0/FALSE
不知道是不是个例，也许是自己的系统问题？有机会换个电脑试试看

afan

cashiba 发表于 2024-1-17 23:14
谢谢A大解答!
另外，测试发现_GUICtrlTreeView_DeleteChildren($hWnd, $hItem)的返回值总是0/FALSE
不知 ...

这个我昨天用 3.3.16.1 测试时就注意了，是 True，也就是会正常执行后面的 _GUICtrlTreeView_SetChildren (3.3.16.1 在 _GUICtrlTreeView_DeleteChildren 内添加了 _GUICtrlTreeView_SetChildren，而之前的版本都没有，需要自行调用)