【已解决】关于获取DLL内部图标数量

chenronting

上面那个函数是用来选择ICO图标的，现在想请教一个问题：
不知道能不能得到Dll的内部图标数量？
在论坛里搜索了下没有发现这方面的东西
希望知道的能来回答到， 谢谢

谢谢下面几位回答者。

最完美的答案在 9#，

smartzbs

参考下这段代码:
Func _ChooseIcon($sDll_File = "\shell32.dll")
    $sDll_File = @SystemDir & $sDll_File
    If Not FileExists($sDll_File) Then
        SetError(1)
        Return -1
    EndIf
    Local $sscInt = DllStructCreate("int")
    Local $sscString = DllStructCreate("wchar[260]")
    Local $sstructsize = DllStructGetSize($sscString) / 2
    DllStructSetData($sscString, 1, $sDll_File)
    DllCall("shell32.dll", "none", 62, "hwnd", 0, "ptr", DllStructGetPtr($sscString), "int", $sstructsize, "ptr", DllStructGetPtr($sscInt))
    If @error Then
        SetError(2)
        Return -1
    EndIf
    Local $nIconIndex = DllStructGetData($sscInt, 1)
    If @error <> 0 Then
        SetError(3)
        Return -1
    EndIf
    Return $nIconIndex
EndFunc   ;==>_ChooseIcon

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
Global $iIconIndex

; Example:

$iIconIndex = _ChooseIcon("\shell32.dll") ; Loads the DLL file: [@SystemDir]\shell32.dll

MsgBox(64, "_ChooseIcon Example", "Icon ID: " & $iIconIndex)

haijie1223

不错 学习了。。。。

chenronting

回复 2# smartzbs


    这个还真看不太懂，不知道在这里面如何得到数量？帮助我吧。谢谢

pusofalse

把标题改了就告诉你。

smartzbs

有个笨办法:
#Include <WinAPI.au3>

$sIcon = @SystemDir & '\shell32.dll'
$iIndex = 0
While 1
        $Ret = DllCall('shell32.dll', 'int', 'SHExtractIconsW', 'wstr', $sIcon, 'int', $iIndex, 'int', 0, 'int', 0, 'ptr*', 0, 'ptr*', 0, 'int', 1, 'int', 0)
        If (@error) Or ($Ret[0] = 0) Or ($Ret[5] = Ptr(0)) Then
                ;$iIndex -= 1
                ExitLoop
        EndIf
        _WinAPI_DestroyIcon($Ret[5])
        $iIndex += 1
WEnd
ConsoleWrite("总数:"&$iIndex&",范围:0-"&$iIndex-1&@CRLF)

阿福

不针对问题,只针对上一楼的代码,改为折半效率高.

Local $aNum[6], $sIcon, $t

$sIcon = @SystemDir & '\shell32.dll'

$aNum[0] = 0
$aNum[1] = 0xffffff ; $iIndex: int type
$aNum[2] = Ceiling(($aNum[1]+$aNum[0])/2)

$t=TimerInit()

While 1
        $Ret = DllCall('shell32.dll', 'int', 'SHExtractIconsW', 'wstr', $sIcon, 'int', $aNum[2], 'int', 0, 'int', 0, 'ptr*', 0, 'ptr*', 0, 'int', 1, 'int', 0)
        If (@error) Or ($Ret[0] = 0) Or ($Ret[5] = Ptr(0)) Then
                $aNum = _TwoValue($aNum, False)
        Else
                DllCall("user32.dll", "bool", "DestroyIcon", "handle", $Ret[5]);_WinAPI_DestroyIcon($Ret[5])
                $aNum = _TwoValue($aNum, True)
        EndIf
        If $aNum[5] Then ExitLoop
WEnd;
$t=TimerDiff($t)
If IsNumber($aNum[4]) Then 
        ConsoleWrite("总数:" & $aNum[4]-$aNum[3]+1 & ",范围:" & $aNum[3] & "-" & $aNum[4] & ",用时" & $t &@CRLF)
Else
        ConsoleWrite("没有Icon" & @CRLF)
EndIf

Func _TwoValue($aNum, $bCon = True)
        Select
        Case $bCon;中值结果为True
                If Not IsNumber($aNum[3]) Then $aNum[3]=$aNum[0];记录最小有效
                If $aNum[1] = $aNum[2] Then
                        $aNum[4] = $aNum[2];结束,成功,$aNum[4] IsNumber
                        $aNum[5] = True
                        Return $aNum
                EndIf
                $aNum[0] = $aNum[2];记录当前最小
        Case Else
                If $aNum[1] = $aNum[0] Then
                        $aNum[5] = True;结束,全没有,$aNum[4] Not IsNumber
                        Return $aNum
                EndIf
                If $aNum[1] = $aNum[2] Then
                        $aNum[1] = $aNum[0]
                Else
                        $aNum[1] = $aNum[2];记录当前最大
                EndIf
        EndSelect
        $aNum[2] = Ceiling(($aNum[1]+$aNum[0])/2)
        Return $aNum
EndFunc

chenronting

回复 7# 阿福


    使用是的测试法？呵呵， 感谢回答

chenronting

回复 6# smartzbs


      使用是的测试法？呵呵， 感谢回答

pusofalse

$iTotalNumber = DllCall("Shell32.dll", "long", "ExtractIcon", "ptr", 0, "str", "Shell32.dll", "int", -1)
MsgBox(0, "", $iTotalNumber[0])

chenronting

回复 10# pusofalse


    感谢P版的帮助 。呵呵， 同样感谢前面两位童鞋。。。