如何使listview里面的项变成灰色,也就是不可用状态【已解决】

binshiwo

回复 15# pusofalse


是的。当ITEM是灰色的时候。是不能选中的。

pusofalse

[au3]#include <WinAPI.au3>
#include <GUIListView.au3>
#include <WindowsConstants.au3>

Const $tagDRAW_ITEM = "uint CtlType;uint CtlId;uint ItemId;uint ItemAction;uint ItemState;hWnd HWndItem;hWnd hDC;long Left;long Top;long Right;long Bottom;ulong_ptr ItemData"

$hGUI = GUICreate("Test", 400, 300)

$iStyle = BitOR($LVS_REPORT, $LVS_SINGLESEL, $LVS_SHOWSELALWAYS, $LVS_OWNERDRAWFIXED)
$iExStyle = BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_DOUBLEBUFFER)
$hListView = _GUICtrlListView_Create($hGUI, "Test", 5, 5, 390, 290, $iStyle, $WS_EX_CLIENTEDGE)
_GUICtrlListView_SetExtendedListViewStyle($hListView, $iExStyle)

_GUICtrlListView_AddItem($hListView, "Item 1", -1, 1) ; Disabled
_GUICtrlListView_AddItem($hListView, "Item 2", -1, 1) ; Disabled
_GUICtrlListView_AddItem($hListView, "Item 3", -1, 0) ; Enable
_GUICtrlListView_AddItem($hListView, "Item 4", -1, 0) ; Enable

$hSelected = _WinAPI_GetSysColorBrush(13)
$hDeselected = _WinAPI_CreateSolidBrush(0xFFFFFF)

GUIRegisterMsg($WM_DRAWITEM, "WM_DRAWITEM")
GUISetState()

While GUIGetMsg() <> -3
WEnd
GUIDelete($hGUI)
_WinAPI_DeleteObject($hSelected)
_WinAPI_DeleteObject($hDeselected)

Func WM_DRAWITEM($hWnd, $iMsg, $iwParam, $ilParam)
        Local $tDrawItem = DllStructCreate($tagDRAW_ITEM, $ilParam)
        Local $hDC = DllStructGetData($tDrawItem, "hDC")
        Local $hListView = DllStructGetData($tDrawItem, "HWndItem")
        Local $iIndex = DllStructGetData($tDrawItem, "ItemId")
        Local $iState = DllStructGetData($tDrawItem, "ItemState")
        Local $tRect = DllStructCreate($tagRECT)

        DllStructSetData($tRect, "Left", DllStructGetData($tDrawItem, "Left") + 5)
        DllStructSetData($tRect, "Top", DllStructGetData($tDrawItem, "Top"))
        DllStructSetData($tRect, "Right", DllStructGetData($tDrawItem, "Right"))
        DllStructSetData($tRect, "Bottom", DllStructGetData($tDrawItem, "Bottom"))

        If DllStructGetData($tDrawItem, "ItemData") Then
                _WinAPI_SetTextColor($hDC, 0xC0C0C0)
        Else
                If BitAnd($iState, 1) Then
                        _WinAPI_FillRect($hDC, DllStructGetPtr($tDrawItem, "Left"), $hSelected)
                        _DrawFocusRect($hDC, DllStructGetPtr($tDrawItem, "Left"))
                Else
                        _WinAPI_FillRect($hDC, DllStructGetPtr($tDrawItem, "Left"), $hDeselected)
                EndIf
                _WinAPI_SetTextColor($hDC, 0)
        EndIf

        _WinAPI_DrawText($hDC, _GUICtrlListView_GetItemText($hListView, $iIndex), $tRect, 0)
EndFunc        ;==>WM_DRAWITEM

Func _DrawFocusRect($hDC, $pRect)
        Local $iResult = DllCall("User32.dll", "bool", "DrawFocusRect", "hwnd", $hDC, "ptr", $pRect)
        Return $iResult[0]
EndFunc        ;==>_DrawFocusRect[/au3]

binshiwo

pusofalse 发表于 2011-2-26 11:26

就是这样子效果。多谢pusofalse版主！非常感谢！

mo_shaojie

是不是disable的效果了?即是关闭了

sunkiss

子项目不显示~！

1. #include <WinAPI.au3>
   
2. #include <GUIListView.au3>
   
3. #include <WindowsConstants.au3>
   
4. 
   
5. Const $tagDRAW_ITEM = "uint CtlType;uint CtlId;uint ItemId;uint ItemAction;uint ItemState;hWnd HWndItem;hWnd hDC;long Left;long Top;long Right;long Bottom;ulong_ptr ItemData"
   
6. 
   
7. $hGUI = GUICreate("Test", 400, 300)
   
8. 
   
9. $iStyle = BitOR($LVS_REPORT, $LVS_SINGLESEL, $LVS_SHOWSELALWAYS, $LVS_OWNERDRAWFIXED)
   
10. $iExStyle = BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_DOUBLEBUFFER)
    
11. $hListView = _GUICtrlListView_Create($hGUI, "Test", 5, 5, 390, 290, $iStyle, $WS_EX_CLIENTEDGE)
    
12. _GUICtrlListView_SetExtendedListViewStyle($hListView, $iExStyle)
    
13. 
    
14. _GUICtrlListView_AddItem($hListView, "Item 1", -1, 1) ; Disabled
    
15. _GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 2", 1, 1)
    
16. _GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 3", 2, 2)
    
17. _GUICtrlListView_AddItem($hListView, "Item 2", -1, 1) ; Disabled
    
18. _GUICtrlListView_AddItem($hListView, "Item 3", -1, 0) ; Enable
    
19. _GUICtrlListView_AddItem($hListView, "Item 4", -1, 0) ; Enable
    
20. 
    
21. $hSelected = _WinAPI_GetSysColorBrush(13)
    
22. $hDeselected = _WinAPI_CreateSolidBrush(0xFFFFFF)
    
23. 
    
24. GUIRegisterMsg($WM_DRAWITEM, "WM_DRAWITEM")
    
25. GUISetState()
    
26. 
    
27. While GUIGetMsg() <> -3
    
28. WEnd
    
29. GUIDelete($hGUI)
    
30. _WinAPI_DeleteObject($hSelected)
    
31. _WinAPI_DeleteObject($hDeselected)
    
32. 
    
33. Func WM_DRAWITEM($hWnd, $iMsg, $iwParam, $ilParam)
    
34.         Local $tDrawItem = DllStructCreate($tagDRAW_ITEM, $ilParam)
    
35.         Local $hDC = DllStructGetData($tDrawItem, "hDC")
    
36.         Local $hListView = DllStructGetData($tDrawItem, "HWndItem")
    
37.         Local $iIndex = DllStructGetData($tDrawItem, "ItemId")
    
38.         Local $iState = DllStructGetData($tDrawItem, "ItemState")
    
39.         Local $tRect = DllStructCreate($tagRECT)
    
40. 
    
41.         DllStructSetData($tRect, "Left", DllStructGetData($tDrawItem, "Left") + 5)
    
42.         DllStructSetData($tRect, "Top", DllStructGetData($tDrawItem, "Top"))
    
43.         DllStructSetData($tRect, "Right", DllStructGetData($tDrawItem, "Right"))
    
44.         DllStructSetData($tRect, "Bottom", DllStructGetData($tDrawItem, "Bottom"))
    
45. 
    
46.         If DllStructGetData($tDrawItem, "ItemData") Then
    
47.                 _WinAPI_SetTextColor($hDC, 0xC0C0C0)
    
48.         Else
    
49.                 If BitAnd($iState, 1) Then
    
50.                         _WinAPI_FillRect($hDC, DllStructGetPtr($tDrawItem, "Left"), $hSelected)
    
51.                         _DrawFocusRect($hDC, DllStructGetPtr($tDrawItem, "Left"))
    
52.                 Else
    
53.                         _WinAPI_FillRect($hDC, DllStructGetPtr($tDrawItem, "Left"), $hDeselected)
    
54.                 EndIf
    
55.                 _WinAPI_SetTextColor($hDC, 0)
    
56.         EndIf
    
57. 
    
58.         _WinAPI_DrawText($hDC, _GUICtrlListView_GetItemText($hListView, $iIndex), $tRect, 0)
    
59. EndFunc ;==>WM_DRAWITEM
    
60. 
    
61. Func _DrawFocusRect($hDC, $pRect)
    
62.         Local $iResult = DllCall("User32.dll", "bool", "DrawFocusRect", "hwnd", $hDC, "ptr", $pRect)
    
63.         Return $iResult[0]
    
64. EndFunc ;==>_DrawFocusRect

复制代码