求助：关于TreeView主项次项的图标设置问题（已解决）

cqboyqx

我想TreeView在读取数据库的值后主项和次项的图标分开，如下图一样，该怎么写呢，求助

Func treexm()
        _GUICtrlTreeView_DeleteAll($TreeView1)
         Local $hQuery, $aRow, $sName = '',$hQuerya, $aRowa, $sNamea = '', $iImage,$b
        _SQLite_Open($SQLite_Data_Path)
        _SQLite_Query(-1, "SELECT * FROM " & $Tablexm & ';', $hQuery)        
                   While _SQLite_FetchData($hQuery, $aRow) = $SQLITE_OK
                        GUICtrlSetImage($TreeView1, @ScriptDir & "\icon\12.ico") ;图标
            $generalitem = GUICtrlCreateTreeViewItem($aRow[0],$TreeView1)
                           _SQLite_Open($SQLite_Data_Path)
                   _SQLite_Query(-1, "SELECT * FROM " & $aRow[0] & ";", $hQuerya)                        
                           While _SQLite_FetchData($hQuerya, $aRowa) = $SQLITE_OK
                                GUICtrlSetImage($TreeView1, @ScriptDir & "\icon\101.ico") ;图标
                                $aboutitem = GUICtrlCreateTreeViewItem($aRowa[0], $generalitem)
                        WEnd
                WEnd
        _SQLite_Close ()
EndFunc

kk_lee69

回复 1# cqboyqx

#include <GuiConstantsEx.au3>
#include <GuiTreeView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查被传递给函数的类名, 设置为 True, 并使用另一个控件句柄, 查看它的工作

_Main()

Func _Main()

    Local $hItem[10], $hImage, $iImage, $iSImage, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("树视图(TreeView) UDF 函数演示", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($hTreeView, $hImage)

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 5
        $hItem[$x] = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] 主项", $x), $x, $x)
        For $y = 1 To Random(2, 10, 1)
            $iImage = Random(0, 5, 1)
            $iSImage = Random(0, 5, 1)
            _GUICtrlTreeView_AddChild($hTreeView, $hItem[$x], StringFormat("[%02d] 子项", $y), $iImage, $iSImage)
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    _GUICtrlTreeView_SelectItem($hTreeView, $hItem[2])
    MsgBox(4160, "信息", StringFormat("项目索引 2 选中状态的图像索引？ %d", _GUICtrlTreeView_GetSelectedImageIndex($hTreeView, $hItem[2])))
    _GUICtrlTreeView_SetSelectedImageIndex($hTreeView, $hItem[2], 1)
    MsgBox(4160, "信息", StringFormat("项目索引 2 选中状态的图像索引？ %d", _GUICtrlTreeView_GetSelectedImageIndex($hTreeView, $hItem[2])))
    _GUICtrlTreeView_SelectItem($hTreeView, $hItem[2])

    ; 循环到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main