求合并_GUICtrlComboBox_Create与_GUICtrlComboBoxEx_Create的WM_NOTIFY消息

afan

chzj589 发表于 2020-8-23 21:24
用以下代码试试

不要搞得那么复杂，精简代码是解决问题的第一步
功能达到了再去优化，关键还是设计思路
列表临时出现一个下拉控件并处理交互，可以很简单

1. #include <GUIListView.au3>
   
2. 
   
3. Global $hListView1, $aItem, $iCombo
   
4. Global $sDefCombo1 = '11|22', $sDefCombo2 = 'abc|ZZZ'
   
5. _GUICreate()
   
6. While GUIGetMsg() <> -3
   
7. WEnd
   
8. 
   
9. Func _GUICreate()
   
10.         Local $hGUI = GUICreate('')
    
11.         Dim $iCombo = GUICtrlCreateCombo('', -100, -100)
    
12.         Local $ListView1 = GUICtrlCreateListView('编号|可双击下拉1　　|xxx|可双击下拉2　　|fff', 2, 30, 396, 250)
    
13.         Dim $hListView1 = GUICtrlGetHandle(-1)
    
14.         GUICtrlSetFont(-1, 11, 400, 0, '微软雅黑')
    
15.         _GUICtrlListView_SetExtendedListViewStyle($ListView1, $LVS_EX_GRIDLINES + $LVS_EX_FULLROWSELECT)
    
16.         For $ii = 1 To 8
    
17.                 GUICtrlCreateListViewItem(StringFormat('%s|aaa-%s|BBB_%s|333.%s|ddd~%s', $ii, $ii, $ii, $ii, $ii), $ListView1)
    
18.         Next
    
19.         GUISetState()
    
20.         GUIRegisterMsg(0x004E, '_WM_NOTIFY') ;$WM_NOTIFY = 0x004E
    
21. EndFunc   ;==>_GUICreate
    
22. 
    
23. Func _WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    
24.         #forceref $hWnd, $iMsg, $iwParam
    
25.         Local $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    
26.         Local $hWndFrom = HWnd(DllStructGetData($tNMHDR, 'hWndFrom'))
    
27.         Local $iCode = DllStructGetData($tNMHDR, 'Code')
    
28.         Switch $hWndFrom
    
29.                 Case $hListView1
    
30.                         Switch $iCode
    
31.                                 Case -2 ;$NM_CLICK = -2
    
32.                                         If IsArray($aItem) Then
    
33.                                                 _GUICtrlListView_SetItemText($hListView1, $aItem[0], GUICtrlRead($iCombo), $aItem[1])
    
34.                                                 GUICtrlSetPos($iCombo, -1000, -100)
    
35.                                                 Dim $aItem = 0
    
36.                                         EndIf
    
37.                                 Case -3 ;$NM_DBLCLK = -3
    
38.                                         Local $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
    
39.                                         Local $iIndex = DllStructGetData($tInfo, 'Index')
    
40.                                         Local $iSub = DllStructGetData($tInfo, 'SubItem')
    
41.                                         Dim $aItem = 0
    
42.                                         If Not StringRegExp($iSub, "^(1|3)$") Then Return 'GUI_RUNDEFMSG'
    
43.                                         Local $aRect = _GUICtrlListView_GetSubItemRect($hListView1, $iIndex, $iSub)
    
44.                                         Dim $aItem[2] = [$iIndex, $iSub]
    
45.                                         Local $sDef = $sDefCombo1
    
46.                                         If $iSub = 3 Then $sDef = $sDefCombo2
    
47.                                         Local $sData = _GUICtrlListView_GetItemText($hListView1, $iIndex, $iSub)
    
48.                                         GUICtrlSetPos($iCombo, $aRect[0] + 4, $aRect[1] + 32, $aRect[2] - $aRect[0])
    
49.                                         GUICtrlSetData($iCombo, '|' & $sData & '|' & $sDef, $sData)
    
50.                                         GUICtrlSetState($iCombo, 256)
    
51. 
    
52.                         EndSwitch
    
53.         EndSwitch
    
54.         Return 'GUI_RUNDEFMSG'
    
55. EndFunc   ;==>_WM_NOTIFY
    

复制代码

又被吃代码了，还好自己复制测试发现了问题。

chzj589

afan 发表于 2020-8-24 15:12
不要搞得那么复杂，精简代码是解决问题的第一步
功能达到了再去优化，关键还是设计思路
列表临时出现一 ...

谢谢!打开了思路。

chzj589

afan 发表于 2020-8-24 15:12
不要搞得那么复杂，精简代码是解决问题的第一步
功能达到了再去优化，关键还是设计思路
列表临时出现一 ...

请教：
鼠标左鍵单击=-2
鼠标左鍵双击=-3
为什么？
那鼠标右键单击= ？
代码受益非浅!
主要是这一行： GUICtrlSetData($iCombo, '|' & $sData & '|' & $sDef, $sData)
还有：
If IsArray($aItem) Then
_GUICtrlListView_SetItemText($hListView1, $aItem[0], GUICtrlRead($iCombo), $aItem[1])
GUICtrlSetPos($iCombo, -1000, -100)
Dim $aItem = 0
EndIf

afan

chzj589 发表于 2020-8-25 15:45
请教：
鼠标左鍵单击=-2
鼠标左鍵双击=-3

这是 Windows 消息常量，固定值，在 WindowsConstants.au3 中：

Global Const $NM_FIRST = 0
Global Const $NM_OUTOFMEMORY = $NM_FIRST - 1
Global Const $NM_CLICK = $NM_FIRST - 2
Global Const $NM_DBLCLK = $NM_FIRST - 3
Global Const $NM_RETURN = $NM_FIRST - 4
Global Const $NM_RCLICK = $NM_FIRST - 5
Global Const $NM_RDBLCLK = $NM_FIRST - 6

afan

chzj589 发表于 2020-8-25 15:45
请教：
鼠标左鍵单击=-2
鼠标左鍵双击=-3

不管临时控件或是浮窗交互，首先显示原有数据这是必须的，然后再可以编辑或取消。
这都是关乎用户体验及方便数据交互的问题。

chzj589

afan 发表于 2020-8-25 15:49
这是 Windows 消息常量，固定值，在 WindowsConstants.au3 中：

Global Const $NM_FIRST = 0

谢谢!要学习的知识还很多。

afan

chzj589 发表于 2020-8-25 16:09
谢谢!要学习的知识还很多。

常量值的问题，可以使用我的工具，常量询捕 https://www.autoitx.com/thread-71517-1-1.html
值是多少，出自哪里，一目了然。

chzj589

afan 发表于 2020-8-25 22:30
常量值的问题，可以使用我的工具，常量询捕 https://www.autoitx.com/thread-71517-1-1.html
值是多少， ...

感谢!方便多了