IE 抓取銀行匯率 問題 如何將網頁資料變成數組[已解決]

kk_lee69

網址如下:
https://www.bankchb.com/frontend/G0100_query.jsp

如何將上面的銀行匯率 變成數組....

實在搞不懂網頁的操作.....

floor6ggg

#include <Array.au3>
#include <IE.au3>
$oIE = _IEAttach("https://www.bankchb.com/frontend/G0100_query.jsp","url")
Local $oTable = _IETableGetCollection($oIE, 0)
$aTableData = _IETableWriteToArray($oTable, True)
_ArrayDisplay($aTableData,'Debug~~~')

chamlien

页面接口，直接返回json数据，不用解析页面
https://www.bankchb.com/frontend/jsp/getG0100_query.jsp

kk_lee69

chamlien 发表于 2022-1-19 12:10
页面接口，直接返回json数据，不用解析页面
https://www.bankchb.com/frontend/jsp/getG0100_query.jsp

高手 你這段網址怎麼抓出來的....?? 如何應用 JSON

kk_lee69

floor6ggg 发表于 2022-1-19 08:17

這個方法過不了 抓不到資料ㄟ

kevinch

写个例子给你

#include <array.au3>
$url = "https://www.bankchb.com/frontend/jsp/getG0100_query.jsp"
$xmlhttp = ObjCreate("msxml2.xmlhttp")
With $xmlhttp
        .open("GET", $url, False)
        .send
        If .status = 200 Then
                $str = .responsetext
        EndIf
EndWith
If $str <> "" Then
        Dim $arr[3] = ["curname", "buy", "sell"]
        $hf = ObjCreate("htmlfile")
        $hf.write("<script></script>")
        With $hf.parentwindow
                .eval("var json=" & $str)
                $n = .eval("json.datas.length")
                If $n > 0 Then
                        Dim $result[$n][3]
                        For $i = 0 To $n - 1
                                For $t = 0 To UBound($arr) - 1
                                        $result[$i][$t] = .eval("json.datas[" & $i & "]." & $arr[$t])
                                Next
                        Next
                        _ArrayDisplay($result,Default,Default,Default,Default,"curname|buy|sell")
                EndIf
        EndWith
EndIf

chenxiaooo

学习啊，学习下~

kk_lee69

kevinch 发表于 2022-1-23 12:43
写个例子给你

感謝幫忙  我們公司最近 換 ERP 系統.... 所以...忙到沒時間上線.....不好意思

也就是 換 ERP 系統~~  所以 有這個匯率轉換 需求 增加了~~~

感謝 幫忙  ~~